Day 05: Cafeteria

Author: ACSimon33

2025/apps/day05_cafeteria/.formatter.exs

@@ -0,0 +1,4 @@
+# Used by "mix format"
+[
+  inputs: ["{mix,.formatter}.exs", "{config,lib,test}/**/*.{ex,exs}"]
+]

2025/apps/day05_cafeteria/benchmarks/puzzle_benchmarks.exs

@@ -0,0 +1,24 @@
+defmodule Cafeteria.Benchmark do
+  def jobs do
+    input = File.read!(Path.join(__DIR__, "../input/puzzle_input.txt"))
+
+    %{
+      "day05.cafeteria.fresh_ingredients" => fn -> Cafeteria.fresh_ingredients(input) end,
+      "day05.cafeteria.all_fresh_ingredient_ids" => fn -> Cafeteria.all_fresh_ingredient_ids(input) end
+    }
+  end
+end
+
+if System.get_env("AOC_COMBINED_BENCHMARK") do
+  Cafeteria.Benchmark.jobs()
+else
+  Benchee.run(
+    Cafeteria.Benchmark.jobs(),
+    print: [fast_warning: false],
+    formatters: [{Benchee.Formatters.Console, extended_statistics: true}],
+    warmup: 1,
+    time: 2,
+    memory_time: 2,
+    reduction_time: 2
+  )
+end

2025/apps/day05_cafeteria/input/example_input.txt

@@ -0,0 +1,11 @@
+3-5
+10-14
+16-20
+12-18
+
+1
+5
+8
+11
+17
+32

2025/apps/day05_cafeteria/input/puzzle_input.txt

@@ -0,0 +1,62 @@
+defmodule Cafeteria do
+  @doc """
+  Check how many ingredient IDs are considered fresh based on the provided ranges.
+  """
+  def fresh_ingredients(input) do
+    [range_section, id_section] = input |> String.split(["\r\n\r\n", "\n\n"], trim: true)
+
+    id_ranges =
+      range_section
+      |> String.split(["\r\n", "\n"], trim: true)
+      |> Enum.map(fn range ->
+        [min, max] = range |> String.split("-", trim: true) |> Enum.map(&String.to_integer/1)
+        {min, max}
+      end)
+
+    ids =
+      id_section
+      |> String.split(["\r\n", "\n"], trim: true)
+      |> Enum.map(&String.to_integer/1)
+
+    Enum.filter(ids, fn id ->
+      Enum.any?(id_ranges, fn {min, max} -> id >= min and id <= max end)
+    end)
+    |> Enum.count()
+  end
+
+  @doc """
+  Calculate the total number of unique fresh ingredient IDs based on the provided ranges.
+  """
+  def all_fresh_ingredient_ids(input) do
+    [range_section, _] = input |> String.split(["\r\n\r\n", "\n\n"], trim: true)
+
+    id_ranges =
+      range_section
+      |> String.split(["\r\n", "\n"], trim: true)
+      |> Enum.map(fn range ->
+        [min, max] = range |> String.split("-", trim: true) |> Enum.map(&String.to_integer/1)
+        {min, max}
+      end)
+
+    merge_ranges(id_ranges)
+    |> Enum.reduce(0, fn {min, max}, acc -> acc + (max - min + 1) end)
+  end
+
+  # Merge all overlapping ranges
+  defp merge_ranges(ranges) do
+    ranges
+    |> Enum.sort_by(fn {min, _max} -> min end)
+    |> Enum.reduce([], fn
+      {min, max}, [] ->
+        [{min, max}]
+
+      {min, max}, [{last_min, last_max} | rest] ->
+        if min <= last_max do
+          new_max = max(last_max, max)
+          [{last_min, new_max} | rest]
+        else
+          [{min, max}, {last_min, last_max} | rest]
+        end
+    end)
+  end
+end

2025/apps/day05_cafeteria/lib/cafeteria.ex

@@ -0,0 +1,26 @@
+defmodule Cafeteria.CLI do
+  def main(args) do
+    args |> parse_args |> read_file |> run
+  end
+
+  defp parse_args(args) do
+    {options, _, _} =
+      OptionParser.parse(args, switches: [filename: :string], aliases: [f: :filename])
+
+    options[:filename]
+  end
+
+  defp read_file(nil) do
+    IO.puts("Usage: --filename <filename> or -f <filename>")
+    System.halt(1)
+  end
+
+  defp read_file(filename) do
+    File.read!(filename)
+  end
+
+  defp run(input) do
+    IO.puts("Number of fresh ingredients: #{Cafeteria.fresh_ingredients(input)}")
+    IO.puts("Number of all fresh ingredient IDs: #{Cafeteria.all_fresh_ingredient_ids(input)}")
+  end
+end

2025/apps/day05_cafeteria/lib/cli.ex

@@ -0,0 +1,51 @@
+defmodule Cafeteria.MixProject do
+  use Mix.Project
+
+  def project do
+    [
+      app: :day05_cafeteria,
+      version: "0.1.0",
+      build_path: "../../_build",
+      deps_path: "../../deps",
+      lockfile: "../../mix.lock",
+      elixir: "~> 1.19",
+      start_permanent: Mix.env() == :prod,
+      escript: [main_module: Cafeteria.CLI, path: "../../_build/bin/cafeteria"],
+      deps: deps(),
+      aliases: aliases()
+    ]
+  end
+
+  # Run "mix help compile.app" to learn about applications.
+  def application do
+    [
+      extra_applications: [:logger]
+    ]
+  end
+
+  # Run "mix help deps" to learn about dependencies.
+  defp deps do
+    [
+      {:benchee, "~> 1.0"},
+      {:benchee_html, "~> 1.0"},
+      {:junit_formatter, "~> 3.4", only: [:test]}
+    ]
+  end
+
+  defp aliases do
+    [
+      bench: "run #{__DIR__}/benchmarks/puzzle_benchmarks.exs",
+      exec: [&run_escript_with_args/1],
+      solve: ["escript.build", &run_escript/1]
+    ]
+  end
+
+  defp run_escript(_) do
+    Mix.shell().cmd("escript ../../_build/bin/cafeteria -f #{__DIR__}/input/puzzle_input.txt")
+  end
+
+  defp run_escript_with_args(_) do
+    args = System.argv() |> Enum.join(" ")
+    Mix.shell().cmd("escript ../../_build/bin/cafeteria #{args}")
+  end
+end

2025/apps/day05_cafeteria/mix.exs

@@ -0,0 +1,14 @@
+defmodule CafeteriaTest do
+  use ExUnit.Case
+  doctest Cafeteria
+
+  test "fresh_ingredients" do
+    input = File.read!("input/example_input.txt")
+    assert Cafeteria.fresh_ingredients(input) == 3
+  end
+
+  test "all_fresh_ingredient_ids" do
+    input = File.read!("input/example_input.txt")
+    assert Cafeteria.all_fresh_ingredient_ids(input) == 14
+  end
+end

2025/apps/day05_cafeteria/test/cafeteria_test.exs

@@ -0,0 +1,2 @@
+ExUnit.configure(formatters: [JUnitFormatter, ExUnit.CLIFormatter])
+ExUnit.start()