|
| 1 | +------------------------------------------------------------------------------ |
| 2 | +-- Language Server Protocol -- |
| 3 | +-- -- |
| 4 | +-- Copyright (C) 2022-2025, AdaCore -- |
| 5 | +-- -- |
| 6 | +-- This is free software; you can redistribute it and/or modify it under -- |
| 7 | +-- terms of the GNU General Public License as published by the Free Soft- -- |
| 8 | +-- ware Foundation; either version 3, or (at your option) any later ver- -- |
| 9 | +-- sion. This software is distributed in the hope that it will be useful, -- |
| 10 | +-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- -- |
| 11 | +-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public -- |
| 12 | +-- License for more details. You should have received a copy of the GNU -- |
| 13 | +-- General Public License distributed with this software; see file -- |
| 14 | +-- COPYING3. If not, go to http://www.gnu.org/licenses for a complete copy -- |
| 15 | +-- of the license. -- |
| 16 | +------------------------------------------------------------------------------ |
| 17 | + |
| 18 | +with Langkit_Support.Slocs; |
| 19 | + |
| 20 | +with Libadalang.Analysis; |
| 21 | + |
| 22 | +with LAL_Refactor.Delete_Entity; |
| 23 | + |
| 24 | +with VSS.JSON.Streams; |
| 25 | + |
| 26 | +with LSP.Enumerations; |
| 27 | +with LSP.Structures.LSPAny_Vectors; use LSP.Structures.LSPAny_Vectors; |
| 28 | + |
| 29 | +package body LSP.Ada_Handlers.Refactor.Delete_Entity is |
| 30 | + |
| 31 | + ------------------------ |
| 32 | + -- Append_Code_Action -- |
| 33 | + ------------------------ |
| 34 | + |
| 35 | + procedure Append_Code_Action |
| 36 | + (Self : in out Command; |
| 37 | + Context : LSP.Ada_Context_Sets.Context_Access; |
| 38 | + Commands_Vector : in out LSP.Structures.Command_Or_CodeAction_Vector; |
| 39 | + Where : LSP.Structures.Location) |
| 40 | + is |
| 41 | + Code_Action : LSP.Structures.CodeAction; |
| 42 | + |
| 43 | + begin |
| 44 | + Self.Initialize |
| 45 | + (Context => Context.all, |
| 46 | + Where => Where); |
| 47 | + |
| 48 | + Code_Action := |
| 49 | + (title => "Delete Entity and all references", |
| 50 | + kind => |
| 51 | + (Is_Set => True, |
| 52 | + Value => LSP.Enumerations.Refactor), |
| 53 | + diagnostics => <>, |
| 54 | + edit => (Is_Set => False), |
| 55 | + isPreferred => (Is_Set => False), |
| 56 | + disabled => (Is_Set => False), |
| 57 | + command => |
| 58 | + (Is_Set => True, |
| 59 | + Value => |
| 60 | + (title => <>, |
| 61 | + command => VSS.Strings.Conversions.To_Virtual_String |
| 62 | + (Command'External_Tag), |
| 63 | + arguments => Self.Write_Command)), |
| 64 | + data => <>); |
| 65 | + |
| 66 | + Commands_Vector.Append |
| 67 | + (LSP.Structures.Command_Or_CodeAction' |
| 68 | + (Is_Command => False, CodeAction => Code_Action)); |
| 69 | + end Append_Code_Action; |
| 70 | + |
| 71 | + ------------ |
| 72 | + -- Create -- |
| 73 | + ------------ |
| 74 | + |
| 75 | + overriding function Create |
| 76 | + (Any : not null access LSP.Structures.LSPAny_Vector) |
| 77 | + return Command |
| 78 | + is |
| 79 | + use VSS.JSON.Streams; |
| 80 | + use VSS.Strings; |
| 81 | + use LSP.Structures.JSON_Event_Vectors; |
| 82 | + |
| 83 | + C : Cursor := Any.First; |
| 84 | + begin |
| 85 | + return Self : Command do |
| 86 | + pragma Assert (Element (C).Kind = Start_Array); |
| 87 | + Next (C); |
| 88 | + pragma Assert (Element (C).Kind = Start_Object); |
| 89 | + Next (C); |
| 90 | + |
| 91 | + while Has_Element (C) |
| 92 | + and then Element (C).Kind /= End_Object |
| 93 | + loop |
| 94 | + pragma Assert (Element (C).Kind = Key_Name); |
| 95 | + declare |
| 96 | + Key : constant Virtual_String := Element (C).Key_Name; |
| 97 | + begin |
| 98 | + Next (C); |
| 99 | + |
| 100 | + if Key = "context" then |
| 101 | + Self.Context := Element (C).String_Value; |
| 102 | + |
| 103 | + elsif Key = "where" then |
| 104 | + Self.Where := From_Any (C); |
| 105 | + |
| 106 | + else |
| 107 | + Skip_Value (C); |
| 108 | + end if; |
| 109 | + end; |
| 110 | + |
| 111 | + Next (C); |
| 112 | + end loop; |
| 113 | + end return; |
| 114 | + end Create; |
| 115 | + |
| 116 | + -------------- |
| 117 | + -- Refactor -- |
| 118 | + -------------- |
| 119 | + |
| 120 | + overriding |
| 121 | + procedure Refactor |
| 122 | + (Self : Command; |
| 123 | + Handler : not null access LSP.Ada_Handlers.Message_Handler'Class; |
| 124 | + Edits : out LAL_Refactor.Refactoring_Edits) |
| 125 | + is |
| 126 | + use Langkit_Support.Slocs; |
| 127 | + use Libadalang.Analysis; |
| 128 | + use LAL_Refactor; |
| 129 | + use LAL_Refactor.Delete_Entity; |
| 130 | + |
| 131 | + Message_Handler : LSP.Ada_Handlers.Message_Handler renames |
| 132 | + LSP.Ada_Handlers.Message_Handler (Handler.all); |
| 133 | + Context : LSP.Ada_Contexts.Context renames |
| 134 | + Message_Handler.Contexts.Get (Self.Context).all; |
| 135 | + |
| 136 | + File : constant GNATCOLL.VFS.Virtual_File := |
| 137 | + Message_Handler.To_File (Self.Where.uri); |
| 138 | + |
| 139 | + Unit : constant Analysis_Unit := Context.Get_AU (File); |
| 140 | + |
| 141 | + Declaration_SLOC : constant Source_Location := |
| 142 | + (Langkit_Support.Slocs.Line_Number |
| 143 | + (Self.Where.a_range.start.line) + 1, |
| 144 | + Langkit_Support.Slocs.Column_Number |
| 145 | + (Self.Where.a_range.start.character) |
| 146 | + + 1); |
| 147 | + |
| 148 | + function Analysis_Units return Analysis_Unit_Array is |
| 149 | + (Context.Analysis_Units); |
| 150 | + -- Provides the Context Analysis_Unit_Array to the Deleteper |
| 151 | + |
| 152 | + Remover : constant Entity_Remover := |
| 153 | + Create_Entity_Deleter (Unit, Declaration_SLOC); |
| 154 | + |
| 155 | + begin |
| 156 | + Edits := Remover.Refactor (Analysis_Units'Access); |
| 157 | + |
| 158 | + if not Edits.Diagnostics.Is_Empty then |
| 159 | + -- If we have diagnostic then drop any action to make GS report err |
| 160 | + Edits.Text_Edits.Clear; |
| 161 | + Edits.File_Creations.Clear; |
| 162 | + Edits.File_Deletions.Clear; |
| 163 | + Edits.File_Renames.Clear; |
| 164 | + end if; |
| 165 | + end Refactor; |
| 166 | + |
| 167 | + ---------------- |
| 168 | + -- Initialize -- |
| 169 | + ---------------- |
| 170 | + |
| 171 | + procedure Initialize |
| 172 | + (Self : in out Command'Class; |
| 173 | + Context : LSP.Ada_Contexts.Context; |
| 174 | + Where : LSP.Structures.Location) is |
| 175 | + begin |
| 176 | + Self.Context := Context.Id; |
| 177 | + Self.Where := Where; |
| 178 | + end Initialize; |
| 179 | + |
| 180 | + ------------------- |
| 181 | + -- Write_Command -- |
| 182 | + ------------------- |
| 183 | + |
| 184 | + function Write_Command |
| 185 | + (Self : Command) return LSP.Structures.LSPAny_Vector |
| 186 | + is |
| 187 | + use VSS.JSON.Streams; |
| 188 | + |
| 189 | + Result : LSP.Structures.LSPAny_Vector; |
| 190 | + begin |
| 191 | + Result.Append (JSON_Stream_Element'(Kind => Start_Array)); |
| 192 | + Result.Append (JSON_Stream_Element'(Kind => Start_Object)); |
| 193 | + |
| 194 | + -- "context" |
| 195 | + Add_Key ("context", Result); |
| 196 | + To_Any (Self.Context, Result); |
| 197 | + |
| 198 | + -- "where" |
| 199 | + Add_Key ("where", Result); |
| 200 | + To_Any (Self.Where, Result); |
| 201 | + |
| 202 | + Result.Append (JSON_Stream_Element'(Kind => End_Object)); |
| 203 | + Result.Append (JSON_Stream_Element'(Kind => End_Array)); |
| 204 | + |
| 205 | + return Result; |
| 206 | + end Write_Command; |
| 207 | + |
| 208 | +end LSP.Ada_Handlers.Refactor.Delete_Entity; |
0 commit comments