Rework the 'Should_Use_Codepeer_Target' to return true iff there is only the codepeer target available

Author: HugoGGuerrier

lkql_checker/src/gnatcheck-compiler.adb

@@ -4,6 +4,8 @@
 --
 
 with Ada.Characters.Handling; use Ada.Characters.Handling;
+with Ada.Characters.Latin_1;
+with Ada.Containers;
 with Ada.Directories;         use Ada.Directories;
 with Ada.Strings;             use Ada.Strings;
 with Ada.Strings.Fixed;       use Ada.Strings.Fixed;
@@ -80,6 +82,88 @@ package body Gnatcheck.Compiler is
    --  This function treats the provided path as case-insensitive on Windows
    --  systems.
 
+   ---------------------------------
+   -- Target information fetching --
+   ---------------------------------
+
+   function Get_Available_Targets return String_Sets.Set;
+   --  Call the ``gprconfig`` tool to list all currently available targets. If
+   --  you want the list of available targets when GNATcheck has been started,
+   --  use the ``Available_Targets`` global to avoid useless calls.
+
+   function Get_Available_Targets return String_Sets.Set is
+      Res                 : String_Sets.Set;
+      GPRConfig_Exec      : String_Access := Locate_Exec_On_Path ("gprconfig");
+      Args                : Argument_List (1 .. 2);
+      Return_Code         : Integer := -1;
+      Output_File         : File_Descriptor;
+      Output_File_Name    : String_Access;
+      Output_File_Content : String_Access;
+      Split_Content       : String_Vector;
+   begin
+      --  If no regular "gprconfig" has been found, look for the gnatsas one
+      if GPRConfig_Exec = null then
+         GPRConfig_Exec := Locate_Exec_On_Path ("gnatsas-gprconfig");
+
+         --  If the gnatsas "gprconfig" is not available, look for the codepeer
+         --  one (for retro-compatibility purposes).
+         if GPRConfig_Exec = null then
+            GPRConfig_Exec := Locate_Exec_On_Path ("codepeer-gprconfig");
+
+            --  If the result is still null, raise a fatal error. We cannot
+            --  continue the analysis execution.
+            if GPRConfig_Exec = null then
+               Error ("cannot locate gprconfig executable");
+               raise Fatal_Error;
+            end if;
+         end if;
+      end if;
+
+      --  Create the temporary file to get the "gprbuild" output
+      Create_Temp_Output_File (Output_File, Output_File_Name);
+
+      --  Prepare the argument list
+      Args (1) := new String'("--show-targets");
+      Args (2) := new String'("--config=Ada");
+
+      --  Spawn "gprconfig" to fetch the list of available targets
+      Spawn
+        (Program_Name           => GPRConfig_Exec.all,
+         Args                   => Args,
+         Output_File_Descriptor => Output_File,
+         Return_Code            => Return_Code,
+         Err_To_Out             => False);
+
+      --  Parse the output to fill the result
+      Output_File_Content := Read_File (Output_File_Name.all);
+      Split_Content :=
+        Split
+          (Output_File_Content.all,
+           Ada.Characters.Latin_1.LF,
+           Trim_Elems => True);
+      for I in Split_Content.First_Index + 1 .. Split_Content.Last_Index loop
+         if Split_Content (I) /= "" then
+            Res.Include (Split_Content (I));
+         end if;
+      end loop;
+
+      --  Release allocated resources and delete the temporary file
+      Close (Output_File);
+      Delete_File (Output_File_Name.all);
+      Free (GPRConfig_Exec);
+      Free (Output_File_Name);
+      Free (Output_File_Content);
+      for I in Args'Range loop
+         Free (Args (I));
+      end loop;
+
+      --  Finally return the set of available targets
+      return Res;
+   end Get_Available_Targets;
+
+   Available_Targets : constant String_Sets.Set := Get_Available_Targets;
+   --  Cache containing all available targets when GNATcheck has been started.
+
    ---------------------------------------------------------
    -- Data structures and routines for restriction checks --
    ---------------------------------------------------------
@@ -1552,26 +1636,12 @@ package body Gnatcheck.Compiler is
    --------------------------------
 
    function Should_Use_Codepeer_Target return Boolean is
-      Regular_Gnatls : String_Access := Locate_Exec_On_Path ("gnatls");
+      use Ada.Containers;
    begin
-      --  If we could find a regular gnatls, it means there is a native
-      --  toolchain, that takes precedence over a potential codepeer toolchain.
-      if Regular_Gnatls /= null then
-         Free (Regular_Gnatls);
-         return False;
-      end if;
-
-      --  If we couldn't, look for a codepeer toolchain.
-      declare
-         Gnatls : String_Access := Locate_Exec_On_Path ("codepeer-gnatls");
-      begin
-         if Gnatls /= null then
-            Free (Gnatls);
-            return True;
-         end if;
-      end;
-
-      return False;
+      return
+        Available_Targets.Length = 1
+        and then (Available_Targets.Contains ("codepeer")
+                  or else Available_Targets.Contains ("gnatsas"));
    end Should_Use_Codepeer_Target;
 
    -------------------

lkql_checker/src/gnatcheck-compiler.ads

@@ -19,9 +19,9 @@ package Gnatcheck.Compiler is
    ---------------------
 
    function Should_Use_Codepeer_Target return Boolean;
-   --  Returns whether the current gnatcheck process should use the codepeer
-   --  tools. This function tests if the `codepeer-gnatls` executable can be
-   --  accessed when no other regular toolchain can be found.
+   --  Returns whether the current gnatcheck process should set the "codepeer"
+   --  target as the default one. This function returns ``True`` if the
+   --  "codepeer" target is the only available one.
 
    function GPRbuild_Exec return String;
    --  Return the executable name to use in order to spawn a GPRBuild process