Convenience function for clip Rect ?

[CanadianHusky]

Is there already, or in the future, can there be a convenience/helper function for calculation 'clip' Rect in getPixmap ?

GetPixmap(Matrix matrix: Identity, int dpi: 0, string colorSpace: "RGB", Rect clip: null, bool alpha: false, bool annots: true)

From
https://mupdfnet.readthedocs.io/en/latest/classes/Page.html#Page.GetPixmap

• clip (IRect) – restrict rendering to the intersection of this area with the page’s rectangle

I searched the docs and utils at https://mupdfnet.readthedocs.io/en/latest/glossary/Utils.html

The cliprectangle must be in the page coordinate space - makes sense.
However that coordinate space can be nasty for humans, with non-normalized rectangles, negative cropbox origins, and page rotation (0,90,180,270).

If someone wants to extract a partial corner image (as pixmap) from any pdf, the way it is displayed in a viewer, calculating the proper clip coordinate Rect is quite an effort. For every possible page rotation the page cropbox x0,y0 and x1,y1 coordinates need to be related to the clipsize (width/heigth) depending on rotation.

Could there be a convenience function on the Page object like
Rect cornerclip = Page.GetCornerClip(CornerEnum C, SizeF Cornersize);

CornerEnum: NE, NW, SE, SW, C (the 4 corners as shown in a any viewer plus 'C' for Center)
Cornersize: desired clip region, width (horizontal) and heigth (vertical)
Returns: cornerclip Rect with proper coordinates calculated based on Page cropbox and rotation.

and even better, with an overload to offset that clip on viewer X,Y axis coordinate space.

If cropbox origin is at 0,0 and page rotation = 0 it is easy...anything else gets tricky
Rect clip = Rect(cropbox.X1 - clipsize.Width, cropbox.Y1 - clipsize.Height, cropbox.X1, cropbox.Y1);

Working in Page coordinate space is of course mandatory for the low level library, but humans work better with coordinate systems that they can see visually.

Best Regards

[MaksymTkachuk]

@CanadianHusky
Thank you for the detailed explanation and suggestion. It makes a lot of sense.
We understand the complexity this introduces for common tasks like extracting a visible corner of a page.
And, will try to improve the API for real-world usability.
Thanks again for the suggestion!
Maksym

[CanadianHusky]

I have part of the function ready, for page.rotation = 0 it works.
I could not figure out the required matrix transformation for 90, 180, 270

Public Function GetClipRectForCorner(page As Page, corner As Corner, clipSize As SizeF) As Rect
        Dim cropbox As Rect = page.CropBox
        cropbox.Normalize()

        Dim xMin As Single = cropbox.X0
        Dim xMax As Single = cropbox.X1
        Dim yMin As Single = cropbox.Y0
        Dim yMax As Single = cropbox.Y1

        ' Clip area in viewer-style top-left origin
        Dim clipX0 As Single
        Dim clipY0 As Single
        Dim clipX1 As Single
        Dim clipY1 As Single

        Select Case corner
            Case Corner.TopLeft 'ok
                clipX0 = 0
                clipX1 = clipSize.Width
                clipY0 = 0
                clipY1 = clipSize.Height
            Case Corner.TopRight 'ok
                clipX0 = xMax - clipSize.Width - xMin
                clipX1 = xMax - xMin
                clipY0 = 0
                clipY1 = clipSize.Height
            Case Corner.BottomLeft 'ok
                clipX0 = 0
                clipX1 = clipSize.Width
                clipY0 = yMax - clipSize.Height - yMin
                clipY1 = yMax - yMin
            Case Corner.BottomRight 'ok
                clipX0 = xMax - clipSize.Width - xMin
                clipX1 = xMax - xMin
                clipY0 = yMax - clipSize.Height - yMin
                clipY1 = yMax - yMin
        End Select

        Dim rect As New Rect(clipX0, clipY0, clipX1, clipY1)
        Debug.WriteLine(rect)
        'adjust for rotation
        Dim transform As New Matrix(1, 0, 0, 1, 0, 0)

        ' Apply rotation transformation (counter-clockwise) - SOMETHING WRONG HERE
        Select Case page.Rotation
            Case 90
                transform = New Matrix(0, 1, -1, 0, cropbox.Width, 0)
            Case 180
                transform = New Matrix(-1, 0, 0, -1, cropbox.Width, cropbox.Height)
            Case 270
                transform = New Matrix(0, -1, 1, 0, 0, cropbox.Height) 
        End Select

        Dim rotatedRect As Rect = rect.Transform(transform)
        Debug.WriteLine(rotatedRect)
        Return rotatedRect

    End Function

The calling function

        Dim fn As String = "input.pdf"
        Dim dpi As Integer = 144
        Dim col As String = "rgb"
        Dim doc As New Document(fn)
        Dim page As Page = doc.LoadPage(0)
        Dim clipDpi As Integer = 144
        Dim clipSize As New SizeF(249 / 25.4 * 72, 229 / 25.4 * 72) ' Size in points (72 dpi)
        ''all 4 corners
        For Each corner As Corner In [Enum].GetValues(GetType(Corner))
            Dim clipRect As Rect = GetClipRectForCorner(page, corner, clipSize)
            Dim pix As Pixmap = page.GetPixmap(Nothing, clipDpi, "rgb", clipRect)
            pix.Save($"output_{corner.ToString.ToLower()}.jpg")
        Next

    Public Enum Corner
        TopLeft
        TopRight
        BottomLeft
        BottomRight
    End Enum

calling function gives error or returns wrong corner if input PDF has internal rotation. There must be a simple fix

when invalid rectangle coordinates are received, crash as expected. Probably tring to access pixels that do not exist.
Exception thrown: 'System.Runtime.InteropServices.SEHException' in MuPDF.NET.dll
An unhandled exception of type 'System.Runtime.InteropServices.SEHException' occurred in MuPDF.NET.dll

[CanadianHusky]

fixed it...there probably is a shorter way to do this, but below works for all rotations, and all corners, and all cropbox offsets, positive or negative. The build in functions for .RotationMatrix and .Transform are great. I had to work over the unrotated corners first and apply rotation at last step

Public Function GetClipRectForCorner(page As Page, corner As Corner, clipSize As SizeF) As Rect
        Dim cropbox As Rect = page.CropBox
        cropbox.Normalize()
        '
        Dim xMin As Single = cropbox.X0
        Dim xMax As Single = cropbox.X1
        Dim yMin As Single = cropbox.Y0
        Dim yMax As Single = cropbox.Y1
        ' Clip area in viewer-style top-left origin
        Dim clipX0 As Single
        Dim clipY0 As Single
        Dim clipX1 As Single
        Dim clipY1 As Single
        Dim rotated_corner As Corner
        'find rotated corner based on unrotated page
        Select Case page.Rotation
            Case 0
                rotated_corner = corner
            Case 90 'ok
                Select Case corner
                    Case Corner.TopLeft
                        rotated_corner = Corner.BottomLeft
                    Case Corner.TopRight
                        rotated_corner = Corner.TopLeft
                    Case Corner.BottomLeft
                        rotated_corner = Corner.BottomRight
                    Case Corner.BottomRight
                        rotated_corner = Corner.TopRight
                End Select
            Case 180
                Select Case corner
                    Case Corner.TopLeft
                        rotated_corner = Corner.BottomRight
                    Case Corner.TopRight
                        rotated_corner = Corner.BottomLeft
                    Case Corner.BottomRight
                        rotated_corner = Corner.TopLeft
                    Case Corner.BottomLeft
                        rotated_corner = Corner.TopRight
                End Select
            Case 270 'ok
                Select Case corner
                    Case Corner.TopLeft
                        rotated_corner = Corner.TopRight
                    Case Corner.TopRight
                        rotated_corner = Corner.BottomRight
                    Case Corner.BottomRight
                        rotated_corner = Corner.BottomLeft
                    Case Corner.BottomLeft
                        rotated_corner = Corner.TopLeft
                End Select
        End Select
        'get clip position based on rotated corner
        Select Case rotated_corner
            Case Corner.TopLeft 'ok
                clipX0 = 0
                clipX1 = clipSize.Width
                clipY0 = 0
                clipY1 = clipSize.Height
            Case Corner.TopRight 'ok
                clipX0 = xMax - clipSize.Width - xMin
                clipX1 = xMax - xMin
                clipY0 = 0
                clipY1 = clipSize.Height
            Case Corner.BottomLeft 'ok
                clipX0 = 0
                clipX1 = clipSize.Width
                clipY0 = yMax - clipSize.Height - yMin
                clipY1 = yMax - yMin
            Case Corner.BottomRight 'ok
                clipX0 = xMax - clipSize.Width - xMin
                clipX1 = xMax - xMin
                clipY0 = yMax - clipSize.Height - yMin
                clipY1 = yMax - yMin
        End Select
        'get unrotated clip rect
        Dim rect As New Rect(clipX0, clipY0, clipX1, clipY1)
        Debug.WriteLine(rect)
        'adjust clip for rotation
        If page.Rotation <> 0 Then
            Dim pagerot As Matrix = page.RotationMatrix
            Dim rotatedRect As Rect = rect.Transform(pagerot)
            Debug.WriteLine(rotatedRect)
            Return rotatedRect
        Else
            Return rect
        End If

    End Function