Cannot make the sprite move

[ht93]

Hi,

I am trying to build a moving slide for volume. After following the code in https://github.com/Bodmer/TFT_eSPI/blob/master/examples/Sprite/Sprite_scroll_16bit/Sprite_scroll_16bit.ino , I came out with following code. But I found the slide cannot move as the "vol" input change (I checked the value by serial print). May I know what's wrong with my code?

void drawSlide(int32_t x, int32_t y, int32_t vol, TFT_eSprite bar, bool flag_refresh = true)
{
    uint8_t width = 25;
    uint8_t height = 105;
    uint8_t vol_max = 100;
    uint8_t slide_center_w = 2;
    if (flag_refresh)
    {
        bar.setColorDepth(16);  
        bar.createSprite(width, height); 
    }
    bar.fillSprite(TFT_BLACK);
    bar.fillRect(12, 0, slide_center_w, height, 0x632F);
    bar.fillRect(0, vol_max - vol, width, 5, 0x6C7F);
    bar.pushSprite(x, y);
}

Thanks a lot!

[Bodmer]

Seems to work for me, here is the test code:

#include <TFT_eSPI.h>                 // Include the graphics library (this includes the sprite functions)

TFT_eSPI    tft = TFT_eSPI();         // Declare object "tft"

TFT_eSprite spr = TFT_eSprite(&tft);  // Declare Sprite object "spr" with pointer to "tft" object

void drawSlide(int32_t x, int32_t y, int32_t vol, TFT_eSprite bar, bool flag_refresh = true);

void setup()
{
  // Initialise the TFT registers
  tft.init();

  // Clear the TFT screen to blue
  tft.fillScreen(TFT_BLUE);

  while (1) {
    for (int vol = 0; vol < 100; vol++) {
      drawSlide(0, 0, vol, spr);
      delay(50);
    }
  }
}

void loop(void)
{

}

void drawSlide(int32_t x, int32_t y, int32_t vol, TFT_eSprite bar, bool flag_refresh)
{
  uint8_t width = 25;
  uint8_t height = 105;
  uint8_t vol_max = 100;
  uint8_t slide_center_w = 2;
  if (flag_refresh)
  {
    bar.setColorDepth(16);
    bar.createSprite(width, height);
  }
  bar.fillSprite(TFT_BLACK);
  bar.fillRect(12, 0, slide_center_w, height, 0x632F);
  bar.fillRect(0, vol_max - vol, width, 5, 0x6C7F);
  bar.pushSprite(x, y);
}

[Bodmer]

P.S. It will not work with flag refresh "false" because the created sprite goes out of scope when the function ends (just like the old variable values are lost) and is therefore deleted.

[ht93]

Thanks a lot for the quick reply! Yeah, I pass the flag_refresh as false during update.
I tried two method and both worked:

1. remove the TFT_eSprite bar from function input, and make it as a global variable. As long as I don't need to change the size of sprite, it works.

void drawSlide(int32_t x, int32_t y, int32_t vol, bool flag_refresh = false)
{
    uint8_t width = 25;
    uint8_t height = 105;
    uint8_t vol_max = 100;
    uint8_t slide_center_w = 2;
    if (flag_refresh) {
        bar.createSprite(width, height);
    }
    bar.fillSprite(TFT_BLACK);
    bar.fillRect(12, 0, slide_center_w, height, 0x632F);
    bar.fillRect(0, vol_max - vol, width, 5, 0x6C7F);
    bar.pushSprite(x, y);
}

2. remove the flag_refresh

void drawSlide(int32_t x, int32_t y, int32_t vol, TFT_eSprite bar)
{
    uint8_t width = 25;
    uint8_t height = 105;
    uint8_t vol_max = 100;
    uint8_t slide_center_w = 2;
    bar.createSprite(width, height);
    bar.fillSprite(TFT_BLACK);
    bar.fillRect(12, 0, slide_center_w, height, 0x632F);
    bar.fillRect(0, vol_max - vol, width, 5, 0x6C7F);
    bar.pushSprite(x, y);
}

May I know which one would you recommend?
p.s. I removed the bar.setColorDepth(16); since it is default value.

[Bodmer]

The approach depends on whether you want the sprite to persist or be recreated every time the function is called. Sprite creation is fast and automatic deletion recovers the memory. If you want the sprite to persist for the function then you could use static variables so it is only created once and stays in scope for sole use of the function, for example:

void drawSlide(int32_t x, int32_t y, int32_t vol)
{
  uint8_t width = 25;
  uint8_t height = 105;
  uint8_t vol_max = 100;
  uint8_t slide_center_w = 2;

  static TFT_eSprite bar = TFT_eSprite(&tft);
  static bool create = true;

  if (create)
  {
    bar.createSprite(width, height);
    create = false;
  }

  bar.fillSprite(TFT_BLACK);
  bar.fillRect(12, 0, slide_center_w, height, 0x632F);
  bar.fillRect(0, vol_max - vol, width, 5, 0x6C7F);
  bar.pushSprite(x, y);
}