PowerPoint_to_Sketch and Touch

[GeorgeIoak]

I downloaded this "project" and it appears that it will help me do what I want without trying to get GUIslice working (see other discussions about that).

It's mentioned that

Rounded rectangles will be turned into Adafruit buttons

and I see that Button4 (the SETUP button) is rounded so I wanted to experiment with adding touch capability. Would I just add code like the following like in the standard examples?

// Adjust press state of each key appropriately
  for (uint8_t b = 0; b < NUM_KEYS; b++)
  {
    if (pressed && key[b].contains(t_x, t_y))
      key[b].press(true); // tell the button it is pressed
    else
      key[b].press(false); // tell the button it is NOT pressed
  }

  // Check if any key has changed state
  for (uint8_t b = 0; b < NUM_KEYS; b++)
  {
    // If button was just pressed, redraw inverted button
    if (key[b].justPressed())
    {
      Serial.println("Button " + (String)b + " pressed");
      key[b].drawButton(true, "BUTTON " + (String)(b));
    }

    // If button was just released, redraw normal color button
    if (key[b].justReleased())
    {
      Serial.println("Button " + (String)b + " released");
      key[b].drawButton(false, "BUTTON " + (String)(b));
    }
  }

How would you add touch capability to a custom shape, like an up or down triangle/arrow? I'd like to add something like a temperature control so an up/down arrow with a circle displaying the set temperature you are changing.

[GeorgeIoak]

I took the Home_Automation_screen_test example sketch and extended it to include support for my capacitive touch screen that I'm using and this seems to work.

#include <TFT_eSPI_ext.h>
#include <FT6236.h>
//#include <Wire.h>

#define I2C_Freq 100000
#define I2C_SDA 33
#define I2C_SCL 27
#define TOUCH_THRESHOLD 80

TwoWire I2C_0 = TwoWire(0);
FT6236 ts = FT6236();
TFT_eSPI_ext tft = TFT_eSPI_ext();
TFT_eSPI_Button Button1;

// Initial LCD Backlight brightness
int ledBrightness = 200;

#include "screens.h" // Must include after any button instances have been created

void setup() {
  Serial.begin(115200);
  Serial.println(""); Serial.println("");
  Serial.println("TFT_eSPI_ext library test!");
//  I2C_0.begin(I2C_SDA, I2C_SCL, I2C_Freq);
  
  if (!ts.begin(TOUCH_THRESHOLD, I2C_SDA, I2C_SCL))
  {
    Serial.println("[INFO]: Capacitive touch FAILED to start");
  }
  else
    Serial.println("[INFO]: Capacitive touch started!");

  tft.init();
  Button1.initButton(&tft,400, 30, 141, 43, 0xFFFF, 0x2A54, 0xFFFF, "SETUP", 2);

  tft.setRotation(1);
  tft.fillScreen(TFT_GREEN);
  
  // Check for backlight pin if not connected to VCC
  #ifndef TFT_BL
    Serial.println("No TFT backlight pin defined");
  #else
    // Setup PWM channel, ledc is a LED Control Function
    ledcSetup(0, 5000, 8);
    ledcAttachPin(TFT_BL, 0);
    ledcWrite(0, ledBrightness); // Start @ initial Brightness
    //pinMode(TFT_BL, OUTPUT);
    //digitalWrite(TFT_BL, HIGH);
  #endif

  Screen2();
}

void loop(void) {

  // Some variables we need
  uint16_t t_x = 0, t_y = 0; // To store the touch coordinates
  uint16_t x, y;
  bool pressed = false; // Make sure we not use last loop's touch

  if (ts.touched())
  {
    // Retrieve a point
    TS_Point p = ts.getPoint();

    // Flip things around so it matches our screen rotation
    p.x = map(p.x, 0, 320, 320, 0);
    t_y = p.x;
    t_x = p.y;

    pressed = true;
  }
  
  // Adjust press state of each key appropriately

    if (pressed && Button1.contains(t_x, t_y))
      Button1.press(true); // tell the button it is pressed
    else
      Button1.press(false); // tell the button it is NOT pressed

  // Check if any key has changed state
    // If button was just pressed, redraw inverted button
    if (Button1.justPressed())
    {
      Serial.println("Button pressed");
      Button1.drawButton(true, "SETUP");
    }

    // If button was just released, redraw normal color button
    if (Button1.justReleased())
    {
      Serial.println("Button released");
      Button1.drawButton(false, "SETUP");
    }
}

This is using https://github.com/DustinWatts/FT6236 this touch screen driver.

[Bodmer]

Great, it is good to see someone use that PowerPoint approach. Yes, I have been a bit dissapointed with GUISlice, it seems that the library and tool development has stalled.