Replace hardcoded SPIFFS by Parameter

[hasenradball]

    Sorry again for the Stupid Question....

In the file Smooth_font.h there you will fin a hardcoded part with SPIFFS.
See line 45ff.

#ifdef FONT_FS_AVAILABLE
  fs::File fontFile;
  fs::FS   &fontFS  = SPIFFS;
  bool     spiffs   = true;
  bool     fs_font = false;    // For ESP32/8266 use smooth font file or FLASH (PROGMEM) array

#else
  bool     fontFile = true;
#endif

Do I have to change here when I use the LittleFS?

And additionally in line 106.

Originally posted by @hasenradball in #2028 (comment)

[hasenradball]

What about the idea to use an #define in the User_Setup.h and do it like this:

#ifdef ESP8266
  #include "LittleFS.h"
  #define FILESYSTEM LittleFS
  void listDir(void);
#endif

And use the FILESYSTEM in all other files.
So you are able to select the filesystem by the user settings.
Just replaced the hardcoded SPIFFS by FILESYSTEM and you are finished!

[hasenradball]

I use such an preprocessor define in my own spiffs function to select automatically the filesystem depending by the controller.

[TangerineDreamer]

Hi,it's a handy way to use the filesystems :) ,
but i have trouble with the LittleFS on pico boards,i have errors like :FS.h not found,and its seems the library
updated to 2.05 and the name is "lfs",no more LittleFS,but can you clear it to me,or someone else?

[hasenradball]

@copyCATandpasteDOG
Hi can you paste you code part which makes trouble?
And which Controller? ESP32?

[hasenradball]

My fiels look like this:
The header file:

#ifndef _FS_FUNCTIONS_H_
#define _FS_FUNCTIONS_H_
#include <Arduino.h>

#ifdef ESP8266
  #include "LittleFS.h"
  #define FILESYSTEM LittleFS
  void listDir(void);
#endif

#ifdef ESP32
  #define FORMAT_SPIFFS_IF_FAILED true
  #include "FS.h"
  #include "SPIFFS.h"
  #define FILESYSTEM SPIFFS
  void listDir(fs::FS &fs, const char * dirname = "/", uint8_t levels = 0);
#endif

#endif

And the cpp:

#include "FS_functions.h"
#include "DBG_Print.h"

bool FS_isMount = false;

#ifdef ESP8266
void listDir() {
  DBG__PRINT(F(">>> Starte Filesystem..."));
  if (FILESYSTEM.begin()) {
    FS_isMount = true;
    DBG__PRINT(F("\tfilesystem mounted successfully!\n"));

    Dir dir = FILESYSTEM.openDir("/");
    unsigned int total{0}, fsize{0};
    while (dir.next()) {
      DBG__PRINT("\tFILE: ", dir.fileName(), " -");
      if (dir.fileSize()) {
        File fh = dir.openFile("r");
        fsize = fh.size();
        total += fsize;
        DBG__PRINT("", fsize / 1000.0F, " kB\n");
      }
      else {
        DBG__PRINT("0 kB\n");
      }
    }
    DBG__PRINT("Total size: ", total / 1000.0F, " kB\n");
  }
  else DBG__PRINT(F("\tERROR: filesystem mounted failed!\n\n"));
}
#endif


#ifdef ESP32
void listDir(fs::FS &fs, const char * dirname, uint8_t levels) {
  DBG__PRINT(">>> Starte Filesystem...");
  if (FILESYSTEM.begin(FORMAT_SPIFFS_IF_FAILED)) {
    FS_isMount = true;
    DBG__PRINT("\tfilesystem mounted successfully!\n");
    DBG__PRINT("\tListing directory: ", dirname, "\r\n");

    File root = fs.open(dirname);
    if (!root) {
      DBG__PRINT("- failed to open directory");
      return;
    }
    if (!root.isDirectory()) {
      DBG__PRINT("- not a directory");
      return;
    }

    File file = root.openNextFile();
    unsigned int total{0}, fsize{0};
    while (file) {
      if (file.isDirectory()) {
        DBG__PRINT("DIR : ", file.name());
        if (levels) {
          listDir(fs, file.name(), levels - 1);
        }
      } else {
        fsize = file.size();
        total += fsize;
        DBG__PRINT("\tFILE: ", file.name());
        DBG__PRINT("- ", fsize / 1000.0F, "kB\n");
      }
      file = root.openNextFile();
    }
    DBG__PRINT("Total size: ", total / 1000.0F, "kB\n");
  }
  else DBG__PRINT("\tERROR: filesystem mounted failed!");
}
#endif

[TangerineDreamer]

Thanks for your help :)
Here it is,my code trouble comes from a littlefs definition to store the calibration data for a PI PICO RP2040 & a TFT touch,
and the error shows: FS.h, no such file...Here is the code:

//------------------------------------------------------------------------

/**
Title: Raspberry Pi Pico Touch Macro Keyboard Demo
Author: Dustin Watts
Date: 17-05-2021
A simple 4 by 3 matrix of buttons. To show you how to create a custom marco keyboard. Each button can have it's
own function. The button presses are handled in buttonpress().
Using Earle Philhower's 'arduino-pico': https://github.com/earlephilhower/arduino-pico . This core comes with LittleFS and a Keyboard library.
Make sure to flash your Pico with at least 64KB for the filesystem!
This example is based on the examples that come with the TFT_eSPI library. Which includes the Adafruit GFX button handling class.
These libraries need to be installed:

• TFT_eSPI (available through the Library Manager)
  ! Don't forget to configure User_Setup.h in the TFT_eSPI library!

  TFT_MISO 0
  TFT_MOSI 3
  TFT_SCLK 2
  TFT_CS 20
  TFT_DC 22
  TFT_RST 21
  TOUCH_CS 14
  */

#include <FS.h>
#include <LittleFS.h>
#include <Keyboard.h>
#include <SPI.h>
#include <TFT_eSPI.h>

// Name of the Touch calibration file
#define CALIBRATION_FILE "/TouchCalData2"

// Define our filesystem
#define FILESYSTEM LittleFS

// Set to tru if you want the calibration to run on each boot
#define REPEAT_CAL false

// Keypad start position, key sizes and spacing
#define KEY_W 95 // Key width
#define KEY_H 95 // Key height
#define KEY_SPACING_X 20 // X gap
#define KEY_SPACING_Y 10 // Y gap

#define KEY_X (KEY_W/2) + KEY_SPACING_X // X-axis centre of the first key
#define KEY_Y (KEY_H/2) + KEY_SPACING_Y // Y-axis centre of the first key

#define KEY_TEXTSIZE 3 // Font size multiplier

// Choose the font you are using
#define LABEL1_FONT &FreeSansOblique12pt7b // Key label font

// Adding a delay between keypressing to give our OS time to respond
uint8_t keydelay = 100;

// Create the screen object
TFT_eSPI tft = TFT_eSPI();

// Creating the labels for the buttons
// [][<number-of-chars-per-label]
// The number of chars per label should include the termination \0.
char keyLabel[12][3] = {"1", "2", "3", "4", "5", "6", "7", "8", "9", "10", "11", "12"};

// Setting the colour for each button
// You can use the colours defined in TFT_eSPI.h
uint16_t keyColor[12] = {TFT_BLUE, TFT_RED, TFT_GREEN, TFT_NAVY,
TFT_MAROON, TFT_MAGENTA, TFT_ORANGE, TFT_SKYBLUE,
TFT_PURPLE, TFT_CYAN, TFT_PINK, TFT_DARKCYAN
};

// Create 12 'keys' to use later
TFT_eSPI_Button key[12];

void setup() {

Serial.begin(115200);
Serial.println("");

// Initialise the TFT screen
tft.init();

// Set the rotation before we calibrate
tft.setRotation(1);

touch_calibrate();

// Clear the screen
tft.fillScreen(TFT_BLACK);

// Begin the Keyboard
Keyboard.begin();

// Draw the keys ( 3 times 4 loops to create 12)
for (uint8_t row = 0; row < 3; row++) { // 3 rows
for (uint8_t col = 0; col < 4; col++) { // of 4 buttons

  uint8_t b = col + row * 4; // The button number is the column we are on added to the row we are on 
                             // multiplied by the number of buttons per row. C++ uses the Order of operations
                             // you are used to so first the row is multiplied by 4 and then the col is added.
                             // The first button is 0.
                             // Example. col = 2 (third column), row = 1 (second row), becomes: 1 * 4 = 4 --> 4 + 2 = 6. This is the 7th button.

  key[b].initButton(&tft, KEY_X + col * (KEY_W + KEY_SPACING_X),
                    KEY_Y + row * (KEY_H + KEY_SPACING_Y), // x, y, w, h, outline, fill, text
                    KEY_W, KEY_H, TFT_WHITE, keyColor[b], TFT_WHITE,
                    keyLabel[b], KEY_TEXTSIZE);
  key[b].drawButton();
}

}

}

void loop() {

uint16_t t_x = 0, t_y = 0; // To store the touch coordinates

// Pressed will be set true is there is a valid touch on the screen
bool pressed = tft.getTouch(&t_x, &t_y);

// Check if any key coordinate boxes contain the touch coordinates
for (uint8_t b = 0; b < 12; b++) {
if (pressed && key[b].contains(t_x, t_y)) {
key[b].press(true); // tell the button it is pressed
} else {
key[b].press(false); // tell the button it is NOT pressed
}
}

// Check if any key has changed state
for (uint8_t b = 0; b < 12; b++) {

if (key[b].justReleased()) key[b].drawButton(); // draw normal again

if (key[b].justPressed()) 
{
  key[b].drawButton(true);  // draw invert (background becomes text colour and text becomes background colour
  buttonpress(b); // Call the button press function and pass the button number
}

}

}

void buttonpress(int button)
{
//Handle a button press. Buttons are 0 indexed, meaning that the first button is button 0.
switch(button){
case 0:
// Sending a combination of CTRL, ALT and a Function key.
Serial.println("Button 1 pressed");
Keyboard.press(KEY_LEFT_CTRL);
delay(keydelay);
Keyboard.press(KEY_LEFT_ALT);
delay(keydelay);
Keyboard.press(KEY_F1);
delay(keydelay);
Keyboard.releaseAll();
break;
case 1:
// Sending a combination of CTRL, ALT and a Function key.
Serial.println("Button 2 pressed");
Keyboard.press(KEY_LEFT_CTRL);
delay(keydelay);
Keyboard.press(KEY_LEFT_ALT);
delay(keydelay);
Keyboard.press(KEY_F2);
delay(keydelay);
Keyboard.releaseAll();
break;
case 2:
// Sending a combination of CTRL, ALT and a Function key.
Serial.println("Button 3 pressed");
Keyboard.press(KEY_LEFT_CTRL);
delay(keydelay);
Keyboard.press(KEY_LEFT_ALT);
delay(keydelay);
Keyboard.press(KEY_F3);
delay(keydelay);
Keyboard.releaseAll();
break;
case 3:
Serial.println("Button 4 pressed");
// Typing something in the active window
Keyboard.print("Can you type as fast as this?");
break;
case 4:
Serial.println("Button 5 pressed");
// Using the GUI key + R to start an application
Keyboard.press(KEY_LEFT_GUI); // GUI is WIN on windows, CMD on MacOs and GUI on Linux
delay(keydelay);
Keyboard.print("r");
delay(keydelay);
Keyboard.releaseAll();
delay(keydelay);
Keyboard.print("cmd");
delay(keydelay);
Keyboard.write(KEY_RETURN);
break;
case 5:
Serial.println("Button 6 pressed");
// println() presses RETURN at the end of printing characters
Keyboard.println("Can you type as fast as this?");
break;
case 6:
Serial.println("Button 7 pressed");
// Using println() we can skip a seperate RETURN press
Keyboard.press(KEY_LEFT_GUI);
delay(keydelay);
Keyboard.print("r");
delay(keydelay);
Keyboard.releaseAll();
delay(keydelay);
Keyboard.println("cmd");
break;
case 7:
Serial.println("Button 8 pressed");
// ALT + TAB
Keyboard.press(KEY_LEFT_ALT);
delay(keydelay);
Keyboard.write(KEY_TAB);
Keyboard.releaseAll();
break;
case 8:
Serial.println("Button 9 pressed");
// Open an URL. Typing an URL in WIN + R (run) will use your default browser to open an URL
Keyboard.press(KEY_LEFT_GUI);
delay(keydelay);
Keyboard.print("r");
delay(keydelay);
Keyboard.releaseAll();
delay(keydelay);
Keyboard.println("https://www.youtube.com/dustinwatts");
break;
case 9:
Serial.println("Button 10 pressed");
// Nothing for now
break;
case 10:
Serial.println("Button 11 pressed");
// Nothing for now
break;
case 11:
Serial.println("Button 12 pressed");
// Nothing for now
break;
}
}

void touch_calibrate()
{
uint16_t calData[5];
uint8_t calDataOK = 0;

// check file system exists
if (!FILESYSTEM.begin()) {
Serial.println("Formating file system");
FILESYSTEM.format();
FILESYSTEM.begin();
}

// check if calibration file exists and size is correct
if (FILESYSTEM.exists(CALIBRATION_FILE)) {
if (REPEAT_CAL)
{
// Delete if we want to re-calibrate
FILESYSTEM.remove(CALIBRATION_FILE);
}
else
{
File f = FILESYSTEM.open(CALIBRATION_FILE, "r");
if (f) {
if (f.readBytes((char *)calData, 14) == 14)
calDataOK = 1;
f.close();
}
}
}

if (calDataOK && !REPEAT_CAL) {
// calibration data valid
tft.setTouch(calData);
} else {
// data not valid so recalibrate
tft.fillScreen(TFT_BLACK);
tft.setCursor(20, 0);
tft.setTextFont(2);
tft.setTextSize(1);
tft.setTextColor(TFT_WHITE, TFT_BLACK);

tft.println("Touch corners as indicated");

tft.setTextFont(1);
tft.println();

if (REPEAT_CAL) {
  tft.setTextColor(TFT_RED, TFT_BLACK);
  tft.println("Set REPEAT_CAL to false to stop this running again!");
}

tft.calibrateTouch(calData, TFT_MAGENTA, TFT_BLACK, 15);

tft.setTextColor(TFT_GREEN, TFT_BLACK);
tft.println("Calibration complete!");

// store data
File f = FILESYSTEM.open(CALIBRATION_FILE, "w");
if (f) {
  f.write((const unsigned char *)calData, 14);
  f.close();
}

}
}

//---------------------------------------------------------------------------------------

If you have a PICO around maybe you can try it and see if you have some compiling error
https://github.com/earlephilhower/arduino-pico

[hasenradball]

can you please strip your code to an minimal example!
Thanks.

[TangerineDreamer]

My error comes from here:
//--------------------------------------------
#include <FS.h>
#include <LittleFS.h>
#include <Keyboard.h>
#include <SPI.h>
#include <TFT_eSPI.h>

// Name of the Touch calibration file
#define CALIBRATION_FILE "/TouchCalData2"

// Define our filesystem
#define FILESYSTEM LittleFS

//---------------------------------------------
compiling error:

ResolveLibrary(FS.h)
#include "FS.h"
^~~~~~
-> candidates: []
compilation terminated.
exit status 1
FS.h: No such file or directory

//--------------------------------------------------------
Maybe you can see what's going on

[hasenradball]

Hi on the PI Pico I haven't actually no expirience.
Sorry

[TangerineDreamer]

That's sad,anyway, thanks for help :)

[hasenradball]

have you tried to comment the line:

#include <FS.h>

?

[TangerineDreamer]

You can't,it's the most importante part of the filesystem,if you comment it,it must be called in the littlefs.h or cpp and that
do an error

[TangerineDreamer]

Got it working!
I uploaded the last core package from https://github.com/earlephilhower/arduino-pico/ and the littlefs stuff
was complete for pi pico

[Bodmer]

I do not understand the issue. If you are getting errors with the examples then please explain fully the errors and your setup.

If you want to use SPIFFS for the font files then base the code on these examples which are in the SPIFFS examples submenu.

If you want to use LittleFS for the font files then base the code on these examples which are in the LittleFS examples submenu.

As far as I can see there is no need to add further complexity.

[hasenradball]

Hi I don't want to add not needed complexity.

I just want to understand why in the Smooth_Font.h file (See line 45ff.) the Spiffs is hardcoded there.
Does it not conflict when you set the filesystem in main.ino to LittleFS and in the Smooth_Font.h it is hardcoded to Spiffs?

In the User_Setup.h line 314 there is a define SMOOTH_FONT, dependent on this define there is included the file Extensions/Smooth_Fonts.h in the TFT_eSPI.h line 986.
And in the Extensions/Smooth_Fonts.h there ist the hard coded SPIFFS filesystem loaded.

Does this not conflict, when you load the LittleFS in the main.ino file?

[Bodmer]

OK, I can see you did not understand my previous answers.

1. SPIFFS is NOT hard coded because the FS variable fontFS can be modified at runtime.
2. SPIFFS is set as the default for the variable fontFS, just in the same way you might declare a numeric variable as 0 initially so it is not undefined.
3. By setting fontFS by default to equal SPIFFS allows legacy scketches (those implemented by users before LittleFS was added to a board pacjkage) and the use of historic board packages that did not support LittleFS. Some users do not upgrade to the latest board package due to bugs or configuration management reasons. Clearly, setting fontFS by default to LittleFS would break those sketches.
4. A function is provided to set the FS, viz tft.loadFont(AA_FONT_SMALL, LittleFS);, this is why SPIFFS and LittleFS examples are slightly different. Equally you could use tft.loadFont(AA_FONT_SMALL, SPIFFS);

Please only raise issues for real problems with the library. Raise a pull request for inprovement suggestions and the discussions for general questions.