WT32-SC01 using TFT_eSPI Issue with Reprinting Screen and White Screen Error

[CSEEEE]

I am having the issue where after the enterSecurityCode() function has been completed (ie. the security code is correct) the screen will not reprint for the new enterPhoneNumber() function. The screen flashes to white and does not change once the correct security code is entered, but the loop continues to the enterPhoneNumber() function. When entering a correct phone, the screen will just stay white and the loop will begin again. Where am I going wrong here and how can I ensure the screen clears and reprints for each new function?

Another question I had is how am I able to print the numbers on the screen as they are entered from the keypad?

Thanks for all your assistance!

Here is the sample .INO code 😄

// ZEUS

bool format = true; // true for formatting ZEUS memory, use once, then make false and reflash

#include <SPI.h>
#include <TFT_eSPI.h>
#include <Wire.h>
#include <Arduino.h>
#include <Keypad.h>

//////Keypad////////

#define ROW_NUM     4 // four rows
#define COLUMN_NUM  3 // three columns

char keys[ROW_NUM][COLUMN_NUM] = {
  {'1', '2', '3'},
  {'4', '5', '6'},
  {'7', '8', '9'},
  {'*', '0', '#'}
};

byte pin_rows[ROW_NUM] = {4, 2, 0, 5}; // GIOP18, GIOP5, GIOP17, GIOP16 connect to the row pins
byte pin_column[COLUMN_NUM] = {25, 26, 21};  // GIOP4, GIOP0, GIOP2 connect to the column pins

Keypad keypad = Keypad( makeKeymap(keys), pin_rows, pin_column, ROW_NUM, COLUMN_NUM );

const String securityPassword = "12345"; // change your password here
String input_securityPassword;

// variable for the phone number
String phoneNumber = "";

TFT_eSPI tft = TFT_eSPI();

/////////////////////////////////////
////////////////SETUP////////////////
/////////////////////////////////////

void setup()  
{  
  
  tft.init();
  tft.setRotation(1);
  tft.invertDisplay(false);
  tft.fillScreen(TFT_BLACK);
  logo();
  Serial.begin(9600);
  delay(5000);
}

void logo()
{
  tft.fillScreen(TFT_BLACK);
  tft.setCursor(130, 100);
  tft.setTextSize(10);
  tft.setTextColor(TFT_PURPLE);
  tft.println("ZEUS");
}

/////////////////////////////////////

void loop()
{
  // Turn on machines
  Serial.println("Started loop()");
  securityCode();
  Serial.println("Completed securityCode()");
  delay(3000);
  enterPhoneNumber();///////Added
  Serial.println("Completed enterPhoneNumber()");
  delay(3000);
}

/////////////////////////////////////

bool debounce(unsigned long lastPress, unsigned long currentPress, int delay) {
  return ((currentPress - lastPress) >= delay);
}

void securityCode(){
  tft.fillScreen(TFT_BLACK);
  tft.setCursor(30, 70);
  tft.setTextSize(3);
  tft.setTextColor(TFT_WHITE);
  tft.println("* Enter Security Code *");
  Serial.println("securityCode() Called");
  int lastKey = -1;
  unsigned long lastPress = millis();
  bool correctCodeEntered = false;
  while(!correctCodeEntered){
    char key = keypad.getKey();
    if (key){
      if (debounce(lastPress, millis(), 100)) {
        lastPress = millis();
        lastKey = key;
        Serial.println(key);

        if(key == '*') {
          input_securityPassword = ""; // clear input password
          Serial.println("Password Cleared");
        } else if(key == '#') {
          if(securityPassword == input_securityPassword) {
            Serial.println("Password is Correct");
            correctCodeEntered = true;
          } else {
            Serial.println("Password is Incorrect, Try Again");
            input_securityPassword = ""; // clear input password
            Serial.println("Password Cleared");
          }
        } else {
          input_securityPassword += key; // append new character to input password string
        }
      }
    }
  }
  input_securityPassword = ""; // clear input password
  Serial.println("Password Cleared");
  return;
}

void enterPhoneNumber(){
  Serial.println("enterPhoneNumber() Function Called");
  tft.fillScreen(TFT_BLACK);
  tft.setCursor(50, 40);
  tft.setTextSize(3);
  tft.setTextColor(TFT_WHITE);
  tft.println("Enter your phone number");
  Serial.println("enterPhoneNumber() Printed");
  int lastKey = -1;
  unsigned long lastPress = millis();
  bool correctPhoneNumber = false;
  while(!correctPhoneNumber){
    char key = keypad.getKey();
    if (key){
      if (debounce(lastPress, millis(), 100)) {
        lastPress = millis();
        lastKey = key;
        Serial.println(key);

        if(key == '*') {
          phoneNumber = ""; // clear input password
          Serial.println("Clear Phone Number");
          Serial.println("Phone Number Cleared");
        } else if(key == '#') {
          if(phoneNumber.length() == 10) {
            Serial.println("Phone Number is Correct");
            correctPhoneNumber = true;
          } else {
            Serial.println("Phone Number is Incorrect, Try Again");
            phoneNumber = ""; // clear input password
            Serial.println("Phone Number Cleared");
          }
        } else {
          phoneNumber += key; // append new character to input password string
        }
      }
    }
  }
  phoneNumber = ""; // clear input password
  Serial.println("Phone Number Cleared");
  return;
}

[Bodmer]

I expect the watchdog is timing out. Add a line:
yield();

within each of the while loops.

Also you need to send the digits to the screen during the whilke loop. You can use tft.print for this.

[CSEEEE]

Thank you very much for your quick response! I was going to test it out with the yield(); but it seems as though the screen is now just going completely black and I am unable to see the logo() and enterSecurityCode() screens now. As I was able to before. I tried redownloading the TFT_eSPI library, but now I am even more confused because it was showing on the screen, and now it is not. Any suggestions or recommendations?

[CSEEEE]

In User)Setup was able to turn down the SPI_READ_FREQUENCY
// Optional reduced SPI frequency for reading TFT
#define SPI_READ_FREQUENCY 10000000

This make the logo() and enterSecurityCode() screens begin to show up again.

After including: yield(); between each while and char key, I am still presented with a white screen once the enterPhoneNumber() function is called and the serial monitor shows the screen is printed.

What is your take on this situation?

To my knowledge, none of my other code has this issue when displaying the TFT. It seems like the white screen appears, and stays white until unplugged, when switching functions after the while loop to read the keypad presses.

[Bodmer]

There is something wrong with the setup. I suggest you carefully follow the tutorial here and get the board working correctly with that code before trying to develop new code:
https://github.com/sowbug/WT32-SC01-Demo

[Bodmer]

Use the correct version of the touch library for that display as referenced in the link above, so pins are mapped correctly.
https://github.com/sowbug/Adafruit_FT6206_Library

[CSEEEE]

Your assistance on this mean so very much to me, I hope you know that!

Upon going through the recommended steps:
Using this library - https://github.com/sowbug/Adafruit_FT6206_Library
And this Directory - WT32-SC01-User_Setup.h

I also added to the code
#include <Adafruit_FT6206.h>
And
Adafruit_FT6206 ts = Adafruit_FT6206();

And in void setup() I added:
pinMode(TFT_BL, OUTPUT)
digitalWrite(TFT_BL, 128)

I noticed the pins within WT32-SC01-User_Setup.h
#define TFT_WIDTH 480
#define TFT_HEIGHT 320

#define DISPLAY_WIDTH 480
#define DISPLAY_HEIGHT 320

#define USE_HSPI_PORT 1
#define PIN_SDA 18
#define PIN_SCL 19
#define TFT_MISO 12
#define TFT_MOSI 13
#define TFT_SCLK 14
#define TFT_CS 15
#define TFT_DC 21
#define TFT_RST 22
#define TFT_BL 23

#define TOUCH_CS PIN_D2 // Chip select pin (T_CS) of touch screen

Pin 21 overlaps with my existing pin 21 on the keypad.
I tried using pin 34, 27, and 35 for the keypad, but those will not work since those are output only.
Because of that I tried switching the the pin for TFT_DC to:

34: The same blank white screen appears and stays on the screen but the code continues to run properly

27: The screen does not switch away from the enterSecurityCode() once it moves on to the enterPhoneNumber(). Although this time, when the phone number is entered, the screen will invert the colors of the enterSecurityCode() where the letters go black and the rest of the screen is white. After entering the security code again, the entire screen goes blank white again.

35: The same blank white screen appears and stays on the screen but the code continues to run properly.

Idk what to do at this point, but it seems like we are one step closer to resolving this.

Thank you again, as your assistance is so very much appreciated, more than you know!

I have been going at this for over a month now stuck on this white screen error that is occurring.

[Bodmer]

The TFT screen and touch controller are wired to certain GPIO pins by the circuit board so these must NOT be changed:
#define PIN_SDA 18
#define PIN_SCL 19
#define TFT_MISO 12
#define TFT_MOSI 13
#define TFT_SCLK 14
#define TFT_CS 15
#define TFT_DC 21
#define TFT_RST 22
#define TFT_BL 23

The TFT pins cannot be used for any other function.

You can delete this line:
#define TOUCH_CS PIN_D2 // Chip select pin (T_CS) of touch screen
which is not correctly defining an ESP32 GPIO pin anyway! (PIN_D2 is a pin definition for the ESP8266 only, it would map to GPIO 4 on an ESP32).

1. How is your keypad wired in? Post a picture of the connections and list all connections made to the board.
2. Do other TFT_eSPI library examples run OK?
3. Are you trying to use the touch screen at all? Have you tried that?

[CSEEEE]

Double booked pin 21, corrected this issue and we are off to the races! Thank you so very much for your kindness and assistance :) All three of these responses helped solve the issue.