Detecting when a sprite is not created due to available RAM shortage

[MYCAMEL222]

I am working with a ESP32-2432S028 display. I have a 8 bit, 240x240 sprite that I've used on Pico 2040 with no issues. With this display, I get a "0" displayed in the upper right hand corner (0,0) of the TFT (tft is rotated to 320x240) . This is in an area outside of the sprite.

It only happens when I go into that mode the first time after boot. When I come back to that mode from elsewhere in the program, the "0" is gone.

The "0" is displayed in the last used font and color used in the sprite code just before it gets pushed.

Frankly, I've been working on this one little error for days....Any easy ideas?

[MYCAMEL222]

After further investigation, the "0" is actually the last character, of the last string printed to the sprite before PUSH.

It's almost like what ever is last printed to the sprite is also getting printed to TFT at 0,0

[MYCAMEL222]

After more work, this only happens when using smooth fonts. Free fonts only render to the sprite with no extra characters on the TFT.

[Bodmer]

Provide a complete sketch that demonstrates the problem.

[MYCAMEL222]

My original sketch is 3000 lines so modified your example Font_Demo_3_Array.ino to show what I am getting. This example is set at setColorDepth(16), but shows what happens when you exceed memory...

I've figured out that if I reduced the size of my sprite slightly, the error went away. Because I needed 240x240 for my dial sprite and I needed 8 bit depth, I was not going to make it work. I've given up on the 240x240 and changed my design to use smaller sprites.

I was just surprised that the sprite would render and leave extra character outside of the sprite.

Consider this solved....

`#include "NotoSansBold15.h"
#include "NotoSansBold36.h"
#include "NotoSansMonoSCB20.h"

// The font names are arrays references, thus must NOT be in quotes ""
#define AA_FONT_SMALL NotoSansBold15
#define AA_FONT_LARGE NotoSansBold36
#define AA_FONT_MONO NotoSansMonoSCB20 // NotoSansMono-SemiCondensedBold 20pt

#include <SPI.h>
#include <TFT_eSPI.h> // Hardware-specific library

TFT_eSPI tft = TFT_eSPI();
TFT_eSprite spr = TFT_eSprite(&tft); // Sprite class needs to be invoked

void setup(void) {

Serial.begin(250000);

tft.begin();

tft.setRotation(3);

spr.setColorDepth(16); // 16 bit colour needed to show antialiased fonts
pinMode(21, OUTPUT); // TFT backlight
digitalWrite(21, HIGH);
tft.fillScreen(TFT_DARKGREY);
}

void loop() {

spr.loadFont(AA_FONT_LARGE); // Load another different font into the sprite instance
spr.createSprite(240, 200); // Create a sprite 240 x 200
spr.fillSprite(TFT_BLUE);
spr.setTextColor(TFT_YELLOW, TFT_DARKGREY); // Set the sprite font colour and the background colour
spr.setTextDatum(MC_DATUM); // Middle Centre datum
spr.drawString("A0.0", 120, 120); // Coords of middle
spr.pushSprite(40, 0, TFT_BLUE); // Push to TFT screen, TFT_BLUE is transparent
spr.unloadFont(); // Remove the font from sprite class to recover memory used
spr.deleteSprite();
delay(5000);

tft.fillScreen(TFT_DARKGREY);
spr.loadFont(AA_FONT_LARGE); // Load another different font into the sprite instance
spr.createSprite(240, 240); // Create a sprite 240 x 240
spr.fillSprite(TFT_BLUE);
spr.setTextColor(TFT_YELLOW, TFT_DARKGREY); // Set the sprite font colour and the background colour
spr.setTextDatum(MC_DATUM); // Middle Centre datum
spr.drawString("A0.0", 120, 120); // Coords of middle
spr.pushSprite(40, 0, TFT_BLUE); // Push to TFT screen, TFT_BLUE is transparent
spr.unloadFont(); // Remove the font from sprite class to recover memory used
spr.deleteSprite();
delay(5000);

tft.fillScreen(TFT_DARKGREY);
}`

[Bodmer]

If there is insufficient memory for a sprite to be created then the subsequent behaviour will most likely be wrong. In this case the sprite does not exist, the library creates a sprite for you to contain each character and plots each one to the screen at the cursor position (default is 0,0). In this case the 0 is the last character and the remains of the "A" can also be seen.

The amount of memory available varies as a program runs. The simplest approach during program development and when swapping processors (that have different available RAM pools) is to trap whether the sprite is created and/or print available memory to ensure the program has a generous margin in all circumstances. This helps to avoid the problem of memory fragmentation which changes the free memory block size as the program runs. The simplest debug approach is to print a message:

  if (spr.createSprite(240, 240) == nullptr)  Serial.println("Error: sprite not created, not enough free RAM!");
  else Serial.println("Yahoo, success, sprite created!");

[MYCAMEL222]

Thanks for the reply.....

I'll do that from now on.

I got a nice 2 day lesson.