Odd display behaviour after OTA upload

[daveymg-nz]

I'm using an ESP-WROOM-32 chip with an ST7789 240x240 tft SPI display. There are two display layouts used, alternating between two or four lines of text, each display using a sprite for updating. The sprite is created and deleted at each update.

Uploading the code from Platformio via USB compiles and loads successfully and the display is rendered as expected.

Uploading the code using the ArduinoOTA library compiles and uploads successfully but the display rendering is changed. At each pushSprite the display changes colour, alternating between two colours, and the sprite appears to shift right one pixel, so both layouts slowly scroll to the right and wrap around.

The rest of the data gathering code is working correctly for both upload methods.

My guess is a memory issue of some sort, but I'm stuck on trying to figure out what things to try in order to resolve the issue. So far I have changed the ESP32 memory partition layout to use the min_spiffs layout which changed the ram usage from 68% down to 45% without any effect.

The setup code is:

tft.begin();  // initialize
  tft.setRotation(0);
  
  tft.fillScreen(TFT_BLACK);            // Clear screen

and the display code is:

  spr.createSprite(240,240);
  spr.setColorDepth(8);
 
    
  if (showMaxWindCtr-- > 0) { //show max wind speed value?
    spr.fillScreen(TFT_BLACK);            // Clear screen
    spr.setTextSize(2);
    spr.setTextFont(4);

    spr.setTextColor(TFT_YELLOW);
    spr.setCursor(5, 20); 
    spr.print("Max Wind");
    spr.setCursor(60,70);
    spr.print("Speed");
    spr.setCursor(80,120);
    spr.print(maxWindSpeed);
    spr.setCursor(80,170);
    spr.print("Kmh");
    spr.pushSprite(0,0);

  } else {
  
    spr.fillScreen(TFT_BLACK);            // Clear screen
    spr.setTextSize(3);
    spr.setTextFont(4);

    spr.setTextColor(TFT_GREEN);
    spr.setCursor(50, 50); 
    spr.print(avgWindSpeed);
    spr.setCursor(50,130);
    spr.print("Kmh");
    spr.pushSprite(0,0);

  }

  spr.deleteSprite();

[Bodmer]

Set the sprite colour depth before creating the sprite, otherwise a 16 bit sprite will be created first(requiring 115kbytes RAM!), then changed to 8 bit.

[daveymg-nz]

Thanks for your reply Bodmer. I've tried as suggested but no change. I've pared down my code to just the display parts and have listed it below. With the pared down code, the issue remains that the sprite appears to be shifted right at every push command. I'm only creating the sprite once and not deleting it. For the layout, the best I've achieved is using Colour depth 2 and only enabling Font 1 and using White text. The issue doesn't exist if I upload via USB. There are no code changes between uploads of USB or Wifi.

#include <Arduino.h>
#include <SPI.h>
#include <Wire.h>
#include <TFT_eSPI.h>
#include <WiFi.h>
#include <WiFiManager.h>
#include <ArduinoOTA.h>
#include <TaskScheduler.h>


WiFiManager wifiManager;
WiFiClient wifiClient;

TFT_eSPI tft = TFT_eSPI();           // TFT object
TFT_eSprite spr = TFT_eSprite(&tft); // Sprite object

//#define debugOutput //enable/disable debug serial print statements

#ifdef debugOutput
#define debugPrint(...) Serial.print(__VA_ARGS__)
#define debugPrintln(...) Serial.println(__VA_ARGS__)
#else
#define debugPrint(...)
#define debugPrintln(...)
#endif

int showMaxWindCtr = 0;

#define sensorSchedule  2000 //5 sec measurement interval
#define dataSchedule  30000 //300000 // 5 minute gust reporting

Scheduler runner;

//Forward declarations
void processSensor();

//Scheduler Tasks
Task doSensor(sensorSchedule, TASK_FOREVER, &processSensor);

void setup() {

  Serial.begin(115200);
  delay(500);
  

  wifiManager.setConfigPortalTimeout(120); // wait 120 secs for wifi setup then continue anyway
  wifiManager.setHostname("ESP32WallWx");
  wifiManager.autoConnect("WxDisplay-AutoconnectAP");

  ArduinoOTA.begin();

  tft.begin();  // initialize
  tft.setRotation(0);

  spr.setColorDepth(2);
  spr.createSprite(240,240);
  spr.setTextFont(1);
  spr.fillScreen(TFT_BLACK);            // Clear screen
  //spr.setTextSize(4);
  spr.setTextColor(TFT_WHITE); //was YELLOW
  spr.setCursor(0,0); //was 5,100
  spr.print("Starting");
  spr.pushSprite(0,0);

  ArduinoOTA.handle();

  runner.init();
  runner.addTask(doSensor);
  doSensor.enableDelayed();

  
}

void loop() {

  ArduinoOTA.handle();
  runner.execute();
}                        


void processSensor(){

  
  if (showMaxWindCtr-- > 0) { //show max wind speed value?
    spr.fillScreen(TFT_BLACK);            // Clear screen
    //spr.setTextSize(2);
    spr.setTextFont(1);
    spr.setTextColor(TFT_WHITE); //was YELLOW
    spr.setCursor(0,0); //was 5,20
    spr.print("Max Wind");
    spr.setCursor(0,10); //was 60,70
    spr.print("Speed");
    spr.setCursor(0,20); //was 80,120
    spr.print("XX");
    spr.setCursor(0,30); //was 80,170
    spr.print("Kmh");
    spr.pushSprite(0,0);

  } else {
  
    spr.fillScreen(TFT_BLACK);            // Clear screen
    //spr.setTextSize(3);
    spr.setTextFont(1);

    spr.setTextColor(TFT_WHITE);  //was GREEN
    spr.setCursor(0,0); //was 50,50
    spr.print("YY");
    spr.setCursor(0,10); //was 50,130
    spr.print("Kmh");
    spr.pushSprite(0,0);

    showMaxWindCtr = 3;

  }

  //spr.deleteSprite();
   
  } 

[Bodmer]

Possibly this is a power problem since WiFi demands high current transients and maybe these are upsetting the SPI bus.

Does the display have a hardware reset pin, if so then is it being driven by a processor GPIO?

[daveymg-nz]

Yes, the display does have a reset pin connected to GPIO22, I've listed the output of the Read User Settings example below.

TFT_eSPI ver = 2.5.31
Processor    = ESP32
Frequency    = 240MHz
Transactions = Yes
Interface    = SPI
Display driver = 7789
Display width  = 240
Display height = 240

MOSI    = GPIO 23
SCK     = GPIO 18
TFT_DC   = GPIO 21
TFT_RST  = GPIO 22

Font GLCD   loaded
Font 2      loaded
Font 4      loaded
Font 6      loaded
Font 7      loaded
Font 8      loaded
Smooth font enabled

Display SPI frequency = 27.00

Power is a possibility, although the esp is reset after the OTA upload and all of the code appears to function correctly, as it does after a USB upload.

I'm going to just use USB upload for now as I need to install the sensor, it's just a bit awkward to do any code changes. I'm going to setup another ESP32 and tft display and see if I can reproduce to same problem to investigate further. So this issue can be closed now.

Thanks for your help and (regardless of this issue) for the excellent display library.

[daveymg-nz]

To close this off, the root cause was user error, my bad. I didn't realise that PlatformIO maintains a separate set of library folders for each environment, so the User_Setup.h for the environment using OTA firmware upload was different to the setup in the environment using USB upload. I think this is the first library I've used where settings are maintained in the actual library files themselves, although I see there is a mechanism to define settings in the platformio.ini file, which is what I'll use now.