Rewrote ilogbf and ilogbl in assembly

Author: ZERICO2005

src/libc/ilogbf.c

@@ -0,0 +1,62 @@
+	assume	adl=1
+
+	section	.text
+
+	public	_ilogbf, _ilogb
+
+; int ilogbf(float)
+_ilogb:
+_ilogbf:
+	ld	hl, 6
+	add	hl, sp
+	ld	a, (hl)
+	dec	hl
+	dec	hl
+	dec	hl
+	ld	de, (hl)
+	sbc	hl, hl
+	ex	de, hl
+	; DE is zero
+	add	hl, hl
+
+	adc	a, a
+	jr	z, .maybe_subnormal
+	inc	a
+	scf
+	jr	z, .inf_nan
+	rr	e	; E = 128 or float32_bias + 1
+	sbc	hl, hl
+	ld	l, a
+	sbc	hl, de
+	ret
+
+.maybe_subnormal:
+	; DE is zero, Carry unknown
+	add	hl, de
+	sbc	hl, de
+	jr	z, .ret_zero
+	call	__ictlz
+	; Carry flag will be set at the end of __ictlz
+;	scf
+	sbc	hl, hl
+	neg
+	add	a, 129
+	ld	l, a
+	ret
+
+.ret_zero:
+.inf_nan:
+ 	ld	hl, $800000	; FP_ILOGB0
+	sbc	hl, de	; FP_ILOGBNAN or INT_MAX when carry is set
+	ex	de, hl
+	;	DE was zero, so HL is now zero
+	ld	l, 4	; EDOM
+	ld	(_errno), hl
+	ld	hl, ___fe_cur_env
+	set	4, (hl)	; FE_INVALID
+	ex	de, hl
+	ret
+
+	extern	_errno
+	extern	___fe_cur_env
+	extern	__ictlz

src/libc/ilogbf.src

@@ -6,10 +6,65 @@
 
 ; int ilogbl(long double)
 _ilogbl:
-	; x = fabsl(x)
-	ld	hl, 10
-	add	hl, sp
-	res	7, (hl)
-	jq	__ilogbl_c
+	ld	iy, 0
+	lea	de, iy + 0
+	add	iy, sp
+	ld	hl, (iy + 9)
+	add	hl, hl
+	ld	a, h
+	rlca
+	rlca
+	rlca
+	add	hl, hl
+	add	hl, hl
+	add.s	hl, hl	; clears upper bits
+	and	a, $07
+	ld	l, h
+	ld	h, a
+	; HL = exponent
+	adc	hl, de
+	jr	z, .maybe_subnormal
+	inc	hl
+	bit	3, h
+	jr	nz, .inf_nan
+	; Float64_exp_bias + 1
+	ld	de, -1024
+	add	hl, de
+	ret
 
-	extern	__ilogbl_c
+.maybe_subnormal:
+	ld	c, (iy + 9)
+	ld	b, e	; DE is zero
+	ld	de, (iy + 6)
+	ld	hl, (iy + 3)
+	call	__llctlz
+	cp	a, 64
+	sbc	hl, hl
+	jr	z, .ret_zero	; A was 64
+	neg
+	ld	l, a
+	; -1023 + 11 + 1
+	; Float64_ilogb_subnorm_max + Float64_exponent_bits + Float64_sign_bits
+	ld	de, -1011
+	add	hl, de
+	ret
+
+.ret_zero:
+	ex	de, hl
+	inc	de
+.inf_nan:
+ 	ld	hl, $7FFFFF	; FP_ILOGBNAN or INT_MAX
+	add	hl, de	; FP_ILOGB0 when DE is one
+	ex	de, hl
+	;	DE was zero or one, so HL is now zero or one
+	ld	l, 4	; EDOM
+	ld	(_errno), hl
+	ld	hl, ___fe_cur_env
+	set	4, (hl)	; FE_INVALID
+	ex	de, hl
+	ret
+
+	extern	__fpclassifyl
+	extern	_errno
+	extern	___fe_cur_env
+	extern	__llctlz

src/libc/ilogbl.c

@@ -23,6 +23,8 @@ size_t run_test(void) {
     for (size_t i = 0; i < length; i++) {
         int result = ilogbf(input[i]);
         if (result != output[i]) {
+            // printf("%3zu: %08lX\n\t%d != %d\n", i, input[i], result, output[i]);
+            // while (!os_GetCSC());
             return i;
         }
     }
@@ -32,6 +34,7 @@ size_t run_test(void) {
 }
 
 int main(void) {
+
     os_ClrHome();
     size_t fail_index = run_test();
     if (fail_index == SIZE_MAX) {

src/libc/ilogbl.src

@@ -23,6 +23,7 @@ size_t run_test(void) {
     for (size_t i = 0; i < length; i++) {
         int result = ilogbl(input[i]);
         if (result != output[i]) {
+            // printf("%4zu: %016llX\n %d != %d\n", i, input[i], result, output[i]);
             return i;
         }
     }