Play error: Input string was not in a correct format

[AnthonyFavier]

I'm trying to play the simulation with a ZenoTravel domain but it fails when trying to executed the "fly-slow" action with the following message:
FormatException: Input string was not in a correct format

I tried to modify the fluents names to remove dashes and even reduce their length but it doesn't help. It seems to be somehow linked to the increasing effect of the action.

The error occurs in the most basic setup I can make, i.e., creating a fresh new scene through the PDSim tab and with the backend server running with the domain and problem below and the planner ENHSP.

I would appreciate your help to find what's wrong!

Domain.pddl

;; Enrico Scala (enricos83@gmail.com) and Miquel Ramirez (miquel.ramirez@gmail.com)
(define (domain zenotravel)
;(:requirements :typing :fluents)
(:types locatable city - object
	aircraft person - locatable)
(:predicates (located ?x - locatable  ?c - city)
             (in ?p - person ?a - aircraft))
(:functions (fuel ?a - aircraft)
            (distance ?c1 - city ?c2 - city)
            (slow-burn ?a - aircraft)
            (fast-burn ?a - aircraft)
            (capacity ?a - aircraft)
            (total-fuel-used)
	    (onboard ?a - aircraft)
            (zoom-limit ?a - aircraft)
            )


(:action board
 :parameters (?p - person ?a - aircraft ?c - city)
 :precondition (and (located ?p ?c)
                 (located ?a ?c))
 :effect (and (not (located ?p ?c))
              (in ?p ?a)
		(increase (onboard ?a) 1)))


(:action debark
 :parameters (?p - person ?a - aircraft ?c - city)
 :precondition (and (in ?p ?a)
                 (located ?a ?c))
 :effect (and (not (in ?p ?a))
              (located ?p ?c)
		(decrease (onboard ?a) 1)))

(:action flyslow
 :parameters (?a - aircraft ?c1 ?c2 - city)
 :precondition (and (located ?a ?c1)
                 (>= (fuel ?a) 
                         (* (distance ?c1 ?c2) (slow-burn ?a))))
 :effect (and (not (located ?a ?c1))
              (located ?a ?c2)
              (increase (total-fuel-used)
                         (* (distance ?c1 ?c2) (slow-burn ?a)))
              (decrease (fuel ?a) 
                         (* (distance ?c1 ?c2) (slow-burn ?a)))))
                                  
(:action flyfast
 :parameters (?a - aircraft ?c1 ?c2 - city)
 :precondition (and (located ?a ?c1)
                 (>= (fuel ?a) 
                         (* (distance ?c1 ?c2) (fast-burn ?a)))
                 (<= (onboard ?a) (zoom-limit ?a)))
 :effect (and (not (located ?a ?c1))
              (located ?a ?c2)
              (increase (total-fuel-used)
                         (* (distance ?c1 ?c2) (fast-burn ?a)))
              (decrease (fuel ?a) 
                         (* (distance ?c1 ?c2) (fast-burn ?a)))
	)
) 

(:action refuel	
 :parameters (?a - aircraft)
 :precondition (and (> (capacity ?a) (fuel ?a))

		)
 :effect (and (assign (fuel ?a) (capacity ?a)))
)


)

Problem.pddl

(define (problem ZTRAVEL-2-4)
(:domain zenotravel)
(:objects
	plane1 - aircraft
	plane2 - aircraft
	plane3 - aircraft
	plane4 - aircraft
	person1 - person
	person2 - person
	person3 - person
	person4 - person
	city0 - city
	city1 - city
	city2 - city
	city3 - city
	)
(:init
	(located plane1 city1)
	(= (capacity plane1) 2990)
	(= (fuel plane1) 174)
	(= (slow-burn plane1) 1)
	(= (fast-burn plane1) 3)
	(= (onboard plane1) 0)
	(= (zoom-limit plane1) 3)
	(located plane2 city2)
	(= (capacity plane2) 4839)
	(= (fuel plane2) 1617)
	(= (slow-burn plane2) 2)
	(= (fast-burn plane2) 5)
	(= (onboard plane2) 0)
	(= (zoom-limit plane2) 5)

	(located plane3 city0)
	(= (capacity plane3) 4839)
	(= (fuel plane3) 1617)
	(= (slow-burn plane3) 2)
	(= (fast-burn plane3) 5)
	(= (onboard plane3) 0)
	(= (zoom-limit plane3) 5)
	(located plane4 city1)
	(= (capacity plane4) 4839)
	(= (fuel plane4) 1617)
	(= (slow-burn plane4) 2)
	(= (fast-burn plane4) 5)
	(= (onboard plane4) 0)
	(= (zoom-limit plane4) 5)


	(located person1 city3)
	(located person2 city0)
	(located person3 city0)
	(located person4 city1)
	(= (distance city0 city0) 0)
	(= (distance city0 city1) 569)
	(= (distance city0 city2) 607)
	(= (distance city0 city3) 754)
	(= (distance city1 city0) 569)
	(= (distance city1 city1) 0)
	(= (distance city1 city2) 504)
	(= (distance city1 city3) 557)
	(= (distance city2 city0) 607)
	(= (distance city2 city1) 504)
	(= (distance city2 city2) 0)
	(= (distance city2 city3) 660)
	(= (distance city3 city0) 754)
	(= (distance city3 city1) 557)
	(= (distance city3 city2) 660)
	(= (distance city3 city3) 0)
	(= (total-fuel-used) 0)
)
(:goal (and
	(located person1 city2)
	(located person2 city3)
	(located person3 city3)
	(located person4 city3)

	))

)

[Cryoscopic-E]

Thanks for the issue :) I tracked it down being a problem of not recognising the decrement this form: (decrease (fuel ?a) (* (distance ?c1 ?c2) (slow-burn ?a))), in particular the multiplication. Is non-trivial but I have something ready and I'll push an update soon (PhD thesis getting in the way).

The future fix in fact can be found here in a decoupled API for visualisation/simulation: https://github.com/Cryoscopic-E/GeTPlan-PDSimAPI

[AnthonyFavier]

Good to hear! Thank you very much for the prompt feedback, looking forward to the pushed fix!