Add hasProductChangeEvent check to isEmpty (#8402)

When support for product change events was added, it was not included in the isEmpty method.

Author: jandro996

telemetry/src/main/java/datadog/telemetry/EventSource.java

@@ -49,7 +49,8 @@ default boolean isEmpty() {
         && !hasDependencyEvent()
         && !hasMetricEvent()
         && !hasDistributionSeriesEvent()
-        && !hasLogMessageEvent();
+        && !hasLogMessageEvent()
+        && !hasProductChangeEvent();
   }
 
   final class Queued implements EventSource {

telemetry/src/test/groovy/datadog/telemetry/EventSourceTest.groovy

@@ -0,0 +1,64 @@
+package datadog.telemetry
+
+import datadog.telemetry.api.DistributionSeries
+import datadog.telemetry.api.Integration
+import datadog.telemetry.api.LogMessage
+import datadog.telemetry.api.Metric
+import datadog.telemetry.dependency.Dependency
+import datadog.trace.api.ConfigOrigin
+import datadog.trace.api.ConfigSetting
+import datadog.trace.api.telemetry.ProductChange
+import datadog.trace.test.util.DDSpecification
+
+import java.util.concurrent.LinkedBlockingQueue
+
+class EventSourceTest extends DDSpecification{
+
+  void "test isEmpty when adding and clearing #eventType"() {
+    setup:
+    final eventQueues = [
+      configChangeQueue      : new LinkedBlockingQueue<ConfigSetting>(),
+      integrationQueue       : new LinkedBlockingQueue<Integration>(),
+      dependencyQueue        : new LinkedBlockingQueue<Dependency>(),
+      metricQueue            : new LinkedBlockingQueue<Metric>(),
+      distributionSeriesQueue: new LinkedBlockingQueue<DistributionSeries>(),
+      logMessageQueue        : new LinkedBlockingQueue<LogMessage>(),
+      productChanges         : new LinkedBlockingQueue<ProductChange>()
+    ]
+
+    def eventSource = new EventSource.Queued(
+      eventQueues.configChangeQueue,
+      eventQueues.integrationQueue,
+      eventQueues.dependencyQueue,
+      eventQueues.metricQueue,
+      eventQueues.distributionSeriesQueue,
+      eventQueues.logMessageQueue,
+      eventQueues.productChanges
+      )
+
+    expect:
+    eventSource.isEmpty()
+
+    when: "add an event to the queue"
+    eventQueues[eventQueueName].add(eventInstance)
+
+    then: "eventSource should not be empty"
+    !eventSource.isEmpty()
+
+    when: "clear the queue"
+    eventQueues[eventQueueName].clear()
+
+    then: "eventSource should be empty again"
+    eventSource.isEmpty()
+
+    where:
+    eventType             | eventQueueName            | eventInstance
+    "Config Change"       | "configChangeQueue"       | new ConfigSetting("key", "value", ConfigOrigin.ENV)
+    "Integration"         | "integrationQueue"        | new Integration("name", true)
+    "Dependency"          | "dependencyQueue"         | new Dependency("name", "version", "type", null)
+    "Metric"              | "metricQueue"             | new Metric()
+    "Distribution Series" | "distributionSeriesQueue" | new DistributionSeries()
+    "Log Message"         | "logMessageQueue"         | new LogMessage()
+    "Product Change"      | "productChanges"          | new ProductChange()
+  }
+}