Detects when any window changes to full screen mode

[H5820121]

@Descolada
Thank you very much for the useful scripts!
How can I detect when any window changes to full screen mode (F11)?
Thanks!

[Descolada]

Have you tried setting up a WinEvent.Maximize event handler? That means using the WinEvent.ahk library, see this example: https://github.com/Descolada/AHK-v2-libraries/blob/main/Examples/WinEvent/Example3_WindowMaximized.ahk

Or perhaps WinEvent.MoveEnd? With both approaches you'd probably need to check that the window size is at least screen size.

[H5820121]

Have you tried setting up a WinEvent.Maximize event handler?

It detects when a window is maximized but I need to detect when the window is only in full screen mode (I think this is when the Client window width and height are the same as the screen width and height).

[H5820121]

@Descolada
I tried WinEvent.MoveEnd and WinEvent.Maximize and both do not detect when a window changes from maximized to full screen mode.

[Descolada]

Haven't extensively tested it, but something like this seems to work:

#include WinEvent.ahk

WinEvent.Move(WindowMoveEvent)
g_WindowList := Map()
for hWnd in WinGetList()
    g_WindowList[hWnd] := IsFullScreen(hWnd)

WindowMoveEvent(hWnd, hook, dwmsEventTime) {
    prevState := g_WindowList.Has(hwnd) ? g_WindowList[hwnd] : 0
    g_WindowList[hwnd] := newState := IsFullScreen(hWnd)
    SetTimer(CleanWindowList, -250)
    if (newState == prevState)
        return
    
    title := WinGetTitle(hWnd)
    ToolTip newState ? '"' title '" entered fullscreen' : '"' title '" exited fullscreen'
}

CleanWindowList() {
    for hWnd in g_WindowList.Clone()
        if !WinExist(hWnd)
            g_WindowList.Delete(hWnd)
}

IsFullScreen(hWnd) => (WinGetPos(&X, &Y, &W, &H, hWnd), X <= 0 && Y <= 0 && (X+W) >= A_ScreenWidth && (Y+H) >= A_ScreenHeight)