A toggle to stay in /msg with a specific user

[untuned]

Obviously it can't be /msgtoggle, as that turns off messaging for that user.

I would like there to be a way to stay in a /msg conversation with someone, without having to type /r <message> or /msg <user> <message> every time. It makes it easier to stay in a long conversation with someone without accidentally typing something in the main chat.

[oskarkk]

I wrote a "wrapper" for /m and /r commands in Skript. It works just as you say, but may be a little buggy. Here's the code:

command /rozmowa [<text>]:
  trigger:
    if arg-1 is not set:
      if {rozmowa.player::%player%} is not set:
        message "Musisz podać nick gracza: /rozmowa <gracz>"
        stop trigger
      set {_player} to {rozmowa.player::%player%}
      if {rozmowa.enabled::%player%} is true:
        set {rozmowa.enabled::%player%} to false
        message "Wyłączono tryb wysyłania wiadomości prywatnych do %{_player}%"
        stop trigger
    else:
      set {_player} to arg-1
      set {rozmowa.player::%player%} to {_player}

    if {_player} parsed as player is offline:
      message "Gracz %{_player}% jest offline lub nie istnieje"
      message "Podaj nick gracza: /rozmowa <gracz>"
    else:
      set {rozmowa.enabled::%player%} to true
      message "Włączono tryb wysyłania wiadomości prywatnych do %{_player}%. Aby wyłączyć, wpisz /rozmowa"

on chat:
  {rozmowa.enabled::%player%} is true
  set {_player} to {rozmowa.player::%player%}
  make player execute command "/m %{_player}% %message%"
  cancel event

on quit:
  if {rozmowa.enabled::%player%} is true:
    set {rozmowa.enabled::%player%} to false
  loop {rozmowa.player::*}:
    loop-value is player's name
    {rozmowa.enabled::%loop-index%} is true
    set {rozmowa.enabled::%loop-index%} to false
    message "Wyłączono tryb wysyłania wiadomości prywatnych do %player%" to loop-index parsed as player

The command is /rozmowa (you can change the name to anything you like), and after you use /rozmowa untuned all subsequent messages written in chat will work like using /msg untuned yourmessagehere. You use /rozmowa again to turn it off.

Anyway, it would be nice to have it done properly in Essentials.

[mdcfe]

I wouldn't be opposed to a PR that implemented this, though we would need to find a suitable name for the command if it were to be added.