Как узнать, какой метод обхода в данный момент выбран ?

[MaximusPanin]

Пробежался по меню, но нигде не нашел отображение запущенного метода обхода. Ни в Check Status, ни в Run Diagnostics. Может как-то звездочкой выделить активный или в диагностике отобразить ?

[Dronatar]

В реестре переходим в HKLM\SYSTEM\CurrentControlSet\Services\zapret нажимаем ПКМ на ImagePath и выбираем Изменить..., после чего, для удобства копируем Значение: в любой текстовый документ, и потом ищем более похожий general на это.

Да, было бы хорошо, сделать подобное отображение, благодарю за идею.

[Dronatar]

• Информация о том, какой файл был установлен сервисом #3890

[alexvruden]

Добавить в service.bat такие строки (выделено жирно):

кусок service.bat

set "menu_choice=null"

echo =======================
echo 1. Install Service
echo 2. Remove Services
echo 3. Check Status
echo 4. Run Diagnostics
echo 5. Check Updates
echo 6. Switch Game Filter (%GameFilterStatus%)
echo 7. Switch ipset (%IPsetStatus%)
echo 8. Update ipset list
echo 9. Strategy
echo 0. Exit
set /p menu_choice=Enter choice (0-9):

if "%menu_choice%"=="1" goto service_install
if "%menu_choice%"=="2" goto service_remove
if "%menu_choice%"=="3" goto service_status
if "%menu_choice%"=="4" goto service_diagnostics
if "%menu_choice%"=="5" goto service_check_updates
if "%menu_choice%"=="6" goto game_switch
if "%menu_choice%"=="7" goto ipset_switch
if "%menu_choice%"=="8" goto ipset_update
if "%menu_choice%"=="9" goto strategy_list
if "%menu_choice%"=="0" exit /b
goto menu

:strategy_list
cls
chcp 437 > nul
set /a "strategy_count=1"
set "strategy_count_name="
set "strategy_run="
tasklist /FI "IMAGENAME eq winws.exe" | find /I "winws.exe" > nul
if !errorlevel!==0 (
set /p strategy_run=<%~dp0strategy.run
echo 0. Kill 'winws.exe' daemon process
) else (
if exist %~dp0status del /F /Q status >nul
if exist %~dp0winws.pid del /F /Q winws.pid >nul
if exist %~dp0strategy.run del /F /Q strategy.run >nul
)
for /f "delims=" %%I in ('2^>nul dir /B %~dp0strategy*.') do (
if "x%strategy_run%"=="x%%I" (
call:PrintGreen "!strategy_count!. %%I [ACTIVE]"
) else (
echo !strategy_count!. %%I
)
set "strategy_count_name!strategy_count!=%%I"
set /a "strategy_count=!strategy_count!+1"
)
set "strategy_menu_choice="
set "strategy_filename_choice="
echo.
set /p "strategy_menu_choice=Enter num : "
if "%strategy_menu_choice%"=="0" (
if "x%strategy_run%"=="x" (
echo.
echo Bad choice: !strategy_menu_choice!
) else (
taskkill /T /F /FI "IMAGENAME eq winws.exe" > nul
echo.
echo Done.
)
pause
goto menu
)
set strategy_filename_choice=!strategy_count_name%strategy_menu_choice%!
if "x%strategy_filename_choice%"=="x" (
echo.
echo Bad choice: !strategy_menu_choice!
) else (
taskkill /T /F /FI "IMAGENAME eq winws.exe" > nul
set "winws_arg="
if exist %~dp0status del /F /Q status >nul
if exist %~dp0winws.pid del /F /Q winws.pid >nul
if exist %~dp0strategy.run del /F /Q strategy.run >nul
for /F "skip=1 tokens=*" %%i in (%~dp0strategy%strategy_filename_choice%) do set winws_arg=!winws_arg! %%i
echo @echo off>temp.bat
echo setlocal EnableDelayedExpansion>>temp.bat
echo set "GameFilter=%GameFilter%">>temp.bat
echo set "BIN=%~dp0bin">>temp.bat
echo set "LISTS=%~dp0lists">>temp.bat
echo echo.>>temp.bat
echo echo Start command line parameters verify...>>temp.bat
echo echo.>>temp.bat
echo %~dp0bin\winws.exe --dry-run !winws_arg! >>temp.bat
echo if %%errorlevel%% equ 0 ^(>>temp.bat
echo echo params ok^>status>>temp.bat
echo echo.>>temp.bat
echo echo Starting daemon...>>temp.bat
echo %~dp0bin\winws.exe --daemon --pidfile=%~dp0winws.pid !winws_arg! 1^>status >>temp.bat
echo ^<nul set /p str="Daemon started PID=">>temp.bat
echo type %~dp0winws.pid>>temp.bat
echo echo %strategy_filename_choice%^>strategy.run>>temp.bat
echo echo Done.>>temp.bat
echo echo.>>temp.bat
echo ^) else ^(>>temp.bat
echo echo params error^>status>>temp.bat
echo echo Daemon started ERROR>>temp.bat
echo ^)>>temp.bat
echo exit /b>>temp.bat
call %~dp0temp.bat
del /F /Q temp.bat >nul
)
echo.
pause
goto menu

:: STATUS ==============================
:service_status

Создать дитекторию 'strategy' для стратегий. поместить в эту директорию файлы без расширения с примером содержания ниже:

файл ALT6

:: first line for comments --wf-tcp=80,443,%GameFilter% --wf-udp=443,50000-50100,%GameFilter% --filter-udp=443 --hostlist="%LISTS%list-general.txt" --dpi-desync=fake --dpi-desync-repeats=6 --dpi-desync-fake-quic="%BIN%quic_initial_www_google_com.bin" --new --filter-udp=50000-50100 --filter-l7=discord,stun --dpi-desync=fake --dpi-desync-repeats=6 --new --filter-tcp=80 --hostlist="%LISTS%list-general.txt" --dpi-desync=fake,split2 --dpi-desync-autottl=2 --dpi-desync-fooling=md5sig --new --filter-tcp=443 --hostlist="%LISTS%list-general.txt" --dpi-desync=split2 --dpi-desync-repeats=2 --dpi-desync-split-seqovl=681 --dpi-desync-split-pos=1 --dpi-desync-fooling=badseq,hopbyhop2 --dpi-desync-split-seqovl-pattern="%BIN%tls_clienthello_www_google_com.bin" --new --filter-udp=443 --ipset="%LISTS%ipset-all.txt" --dpi-desync=fake --dpi-desync-repeats=6 --dpi-desync-fake-quic="%BIN%quic_initial_www_google_com.bin" --new --filter-tcp=80 --ipset="%LISTS%ipset-all.txt" --dpi-desync=fake,split2 --dpi-desync-autottl=2 --dpi-desync-fooling=md5sig --new --filter-tcp=443,%GameFilter% --ipset="%LISTS%ipset-all.txt" --dpi-desync=split2 --dpi-desync-split-seqovl=681 --dpi-desync-split-pos=1 --dpi-desync-fooling=badseq,hopbyhop2 --dpi-desync-split-seqovl-pattern="%BIN%tls_clienthello_www_google_com.bin" --new --filter-udp=%GameFilter% --ipset="%LISTS%ipset-all.txt" --dpi-desync=fake --dpi-desync-autottl=2 --dpi-desync-repeats=12 --dpi-desync-any-protocol=1 --dpi-desync-fake-unknown-udp="%BIN%quic_initial_www_google_com.bin" --dpi-desync-cutoff=n2

Что получим - пункт 9 список стратегий. Выбираем стратегию , будет проверка стратегии и запуск демона, если все параметры нормальные. В папке появятся служебные файлы 'status', 'winws.pid', 'strategy.run'. В пункте 9 теперь будет подсветка запущеной стратегии, даже если закрыть батник и потом снова запустить .
Пункт '0' в списке стратегий появится при активном демоне , выбор пункта завершит работу демона. Выбор других пунктов переключит стратегию.
Вся прежняя работа скриптов не нарушена, вы можете использовать прежний запуск или мой вариант.
Все исправления в архиве.

1.zip