feat: expose a Bazel rule (#341)

alexeagle · web-flow · commit 4549390a770f · 2023-05-02T15:28:39.000-04:00
* feat: expose a Bazel rule Previously we documented that users should use the container_test rule from rules_docker: https://github.com/bazelbuild/rules_docker/blob/8c3a8110a0c519929a7e79c39ac345a0f8c74d04/contrib/test.bzl#L125 However, rules_docker is no longer maintained. rules_oci means to be a replacement, but doesn't want to add a rule for a binary that is published elsewhere. It's easier to understand if this repo publishes both the binary, and the bazel rule that wraps it, so that any changes can be made to them together.
diff --git a/.github/workflows/bazel.yaml b/.github/workflows/bazel.yaml
@@ -0,0 +1,16 @@
+name: Bazel
+
+# Controls when the action will run.
+on:
+  # Triggers the workflow on push or pull request events but only for the main branch
+  push:
+    branches: [main]
+  pull_request:
+    branches: [main]
+
+jobs:
+  test:
+    uses: bazel-contrib/.github/.github/workflows/bazel.yaml@cb7908519b9a71d7531b13cafce759eb260575d3
+    with:
+      folders: '["bazel/test"]'
+      exclude_windows: true
diff --git a/.github/workflows/ci.bazelrc b/.github/workflows/ci.bazelrc
@@ -0,0 +1,13 @@
+# This file contains Bazel settings to apply on CI only.
+# It is referenced with a --bazelrc option in the call to bazel in ci.yaml
+
+# Debug where options came from
+build --announce_rc
+# This directory is configured in GitHub actions to be persisted between runs.
+build --disk_cache=~/.cache/bazel
+build --repository_cache=~/.cache/bazel-repo
+# Don't rely on test logs being easily accessible from the test runner,
+# though it makes the log noisier.
+test --test_output=errors
+# Allows tests to run bazelisk-in-bazel, since this is the cache folder used
+test --test_env=XDG_CACHE_HOME
diff --git a/.gitignore b/.gitignore
@@ -3,4 +3,4 @@ structure-test
 structure_tests.test
 .vscode
 out/
-**/bazel-*
+bazel-*
diff --git a/BUILD.bazel b/BUILD.bazel
@@ -0,0 +1 @@
+# Marker that this is the root of a Bazel package
diff --git a/MODULE.bazel b/MODULE.bazel
@@ -0,0 +1,17 @@
+"Bazel module definition, see https://bazel.build/external/overview#bzlmod"
+module(
+    name = "container_structure_test",
+    compatibility_level = 1,
+    # Replaced dynamically when published
+    version = "0.0.0",
+)
+
+# To run yq
+bazel_dep(name = "aspect_bazel_lib", version = "1.28.0")
+bazel_dep(name = "bazel_skylib", version = "1.4.1")
+bazel_dep(name = "platforms", version = "0.0.5")
+
+ext = use_extension("//:repositories.bzl", "extension")
+use_repo(ext, "structure_test_toolchains")
+
+register_toolchains("@structure_test_toolchains//:all")
diff --git a/README.md b/README.md
@@ -359,62 +359,22 @@ Does *not* support command tests.
 
 ### Running Structure Tests Through Bazel
 Structure tests can also be run through `bazel`.
-To do so, load the rule and its dependencies in your `WORKSPACE`:
-```BUILD
-git_repository(
-    name = "io_bazel_rules_docker",
-    commit = "8aeab63328a82fdb8e8eb12f677a4e5ce6b183b1",
-    remote = "https://github.com/bazelbuild/rules_docker.git",
-)
-
-load(
-    "@io_bazel_rules_docker//container:container.bzl",
-    "repositories",
-)
-repositories()
-
 
-load(
-    "@io_bazel_rules_docker//contrib:test.bzl",
-    "container_test",
-)
-
-# io_bazel_rules_go is the dependency of container_test rules.
-http_archive(
-    name = "io_bazel_rules_go",
-    url = "https://github.com/bazelbuild/rules_go/releases/download/0.9.0/rules_go-0.9.0.tar.gz",
-    sha256 = "4d8d6244320dd751590f9100cf39fd7a4b75cd901e1f3ffdfd6f048328883695",
-)
-load("@io_bazel_rules_go//go:def.bzl", "go_rules_dependencies", "go_register_toolchains")
-go_rules_dependencies()
-go_register_toolchains()
+With Bazel 6 and bzlmod, just see https://registry.bazel.build/modules/container_structure_test.
+Otherwise, load the rule and its dependencies in your `WORKSPACE`, see bazel/test/WORKSPACE.bazel in this repo.
 
-```
+Load the rule definition in your BUILD file and declare a `container_structure_test` target, passing in your image and config file as parameters:
 
-and then include the rule definition in your `BUILD` file:
+```bazel
+load("@container_structure_test//:defs.bzl", "container_structure_test")
 
-```BUILD
-load("@io_bazel_rules_docker//contrib:test.bzl", "container_test")
-```
-
-Then, create a `container_test` rule, passing in your image and config
-file as parameters:
-
-```BUILD
-container_build(
-    name = "hello",
-    base = "//java:java8",
-    cmd = ["/HelloJava_deploy.jar"],
-    files = [":HelloJava_deploy.jar"],
-)
-
-
-container_test(
+container_structure_test(
     name = "hello_test",
     configs = ["testdata/hello.yaml"],
     image = ":hello",
 )
 ```
+
 ### Flags:
 `container-structure-test test -h`
 ```
diff --git a/WORKSPACE.bazel b/WORKSPACE.bazel
diff --git a/bazel/BUILD.bazel b/bazel/BUILD.bazel
@@ -0,0 +1,4 @@
+toolchain_type(
+    name = "structure_test_toolchain_type",
+    visibility = ["//visibility:public"],
+)
diff --git a/bazel/container_structure_test.bzl b/bazel/container_structure_test.bzl
@@ -0,0 +1,84 @@
+"Implementation details for container_structure_test rule."
+
+load("@aspect_bazel_lib//lib:paths.bzl", "BASH_RLOCATION_FUNCTION", "to_rlocation_path")
+load("@aspect_bazel_lib//lib:windows_utils.bzl", "create_windows_native_launcher_script")
+
+_attrs = {
+    "image": attr.label(
+        allow_single_file = True,
+        doc = "Label of an oci_image or oci_tarball target.",
+    ),
+    "configs": attr.label_list(allow_files = True, mandatory = True),
+    "driver": attr.string(
+        default = "docker",
+        # https://github.com/GoogleContainerTools/container-structure-test/blob/5e347b66fcd06325e3caac75ef7dc999f1a9b614/pkg/drivers/driver.go#L26-L28
+        values = ["docker", "tar", "host"],
+        doc = "See https://github.com/GoogleContainerTools/container-structure-test#running-file-tests-without-docker",
+    ),
+    "_runfiles": attr.label(default = "@bazel_tools//tools/bash/runfiles"),
+    "_windows_constraint": attr.label(default = "@platforms//os:windows"),
+}
+
+CMD = """\
+#!/usr/bin/env bash
+
+{BASH_RLOCATION_FUNCTION}
+
+readonly st=$(rlocation {st_path})
+readonly yq=$(rlocation {yq_path})
+readonly image=$(rlocation {image_path})
+
+# When the image points to a folder, we can read the index.json file inside
+if [[ -d "$image" ]]; then
+  readonly DIGEST=$("$yq" eval '.manifests[0].digest | sub(":"; "-")' "${{image}}/index.json")
+fi
+
+exec "$st" test {fixed_args} $@
+"""
+
+def _structure_test_impl(ctx):
+    fixed_args = ["--driver", ctx.attr.driver]
+    test_bin = ctx.toolchains["@container_structure_test//bazel:structure_test_toolchain_type"].st_info.binary
+    yq_bin = ctx.toolchains["@aspect_bazel_lib//lib:yq_toolchain_type"].yqinfo.bin
+
+    image_path = to_rlocation_path(ctx, ctx.file.image)
+    # Prefer to use a tarball if we are given one, as it works with more 'driver' types.
+    if image_path.endswith(".tar"):
+        fixed_args.extend(["--image", "$(rlocation %s)" % image_path])
+    else:
+        # https://github.com/GoogleContainerTools/container-structure-test/blob/5e347b66fcd06325e3caac75ef7dc999f1a9b614/cmd/container-structure-test/app/cmd/test.go#L110
+        if ctx.attr.driver != "docker":
+            fail("when the 'driver' attribute is not 'docker', then the image must be a .tar file")
+        fixed_args.extend(["--image-from-oci-layout", "$(rlocation %s)" % image_path])
+        fixed_args.extend(["--default-image-tag", "registry.structure_test.oci.local/image:$DIGEST"])
+
+    for arg in ctx.files.configs:
+        fixed_args.extend(["--config", "$(rlocation %s)" % to_rlocation_path(ctx, arg)])
+
+    bash_launcher = ctx.actions.declare_file("%s.sh" % ctx.label.name)
+    ctx.actions.write(
+        bash_launcher,
+        content = CMD.format(
+            BASH_RLOCATION_FUNCTION = BASH_RLOCATION_FUNCTION,
+            st_path = to_rlocation_path(ctx, test_bin),
+            yq_path = to_rlocation_path(ctx, yq_bin),
+            image_path = image_path,
+            fixed_args = " ".join(fixed_args),
+        ),
+        is_executable = True,
+    )
+
+    is_windows = ctx.target_platform_has_constraint(ctx.attr._windows_constraint[platform_common.ConstraintValueInfo])
+    launcher = create_windows_native_launcher_script(ctx, bash_launcher) if is_windows else bash_launcher
+
+    runfiles = ctx.runfiles(
+        files = ctx.files.image + ctx.files.configs + [
+            bash_launcher, test_bin, yq_bin
+        ]).merge(ctx.attr._runfiles.default_runfiles)
+
+    return DefaultInfo(runfiles = runfiles, executable = launcher)
+
+lib = struct(
+    attrs = _attrs,
+    implementation = _structure_test_impl,
+)
diff --git a/bazel/test/.bazelrc b/bazel/test/.bazelrc
@@ -0,0 +1 @@
+# Bazel options go here
diff --git a/bazel/test/.bazelversion b/bazel/test/.bazelversion
@@ -0,0 +1 @@
+6.1.1
diff --git a/bazel/test/BUILD.bazel b/bazel/test/BUILD.bazel
@@ -0,0 +1,8 @@
+load("@container_structure_test//:defs.bzl", "container_structure_test")
+
+container_structure_test(
+    name = "test",
+    configs = ["test.yaml"],
+    driver = "tar",
+    image = "tarball.tar",
+)
diff --git a/bazel/test/MODULE.bazel b/bazel/test/MODULE.bazel
@@ -0,0 +1,13 @@
+"Bazel dependencies under --enable_bzlmod"
+module(
+    name = "smoke",
+    compatibility_level = 1,
+    version = "0.0.0",
+)
+
+bazel_dep(name = "container_structure_test", version = "0.0.0")
+
+local_path_override(
+    module_name = "container_structure_test",
+    path = "../..",
+)
diff --git a/bazel/test/README.md b/bazel/test/README.md
@@ -0,0 +1,9 @@
+# Bazel smoke test
+
+Verifies that the container_structure_test bazel rule exposed by this project works properly.
+
+```sh
+cd bazel/test
+bazel test ...
+bazel test --enable_bzlmod ...
+```
diff --git a/bazel/test/WORKSPACE.bazel b/bazel/test/WORKSPACE.bazel
@@ -0,0 +1,30 @@
+load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
+
+http_archive(
+    name = "aspect_bazel_lib",
+    sha256 = "97fa63d95cc9af006c4c7b2123ddd2a91fb8d273012f17648e6423bae2c69470",
+    strip_prefix = "bazel-lib-1.30.2",
+    url = "https://github.com/aspect-build/bazel-lib/releases/download/v1.30.2/bazel-lib-v1.30.2.tar.gz",
+)
+
+http_archive(
+    name = "bazel_skylib",
+    sha256 = "b8a1527901774180afc798aeb28c4634bdccf19c4d98e7bdd1ce79d1fe9aaad7",
+    urls = [
+        "https://mirror.bazel.build/github.com/bazelbuild/bazel-skylib/releases/download/1.4.1/bazel-skylib-1.4.1.tar.gz",
+        "https://github.com/bazelbuild/bazel-skylib/releases/download/1.4.1/bazel-skylib-1.4.1.tar.gz",
+    ],
+)
+
+local_repository(
+    name = "container_structure_test",
+    path = "../..",
+)
+
+load("@container_structure_test//:repositories.bzl", "container_structure_test_register_toolchain")
+
+container_structure_test_register_toolchain(name = "cst")
+
+load("@aspect_bazel_lib//lib:repositories.bzl", "register_yq_toolchains")
+
+register_yq_toolchains()
diff --git a/bazel/test/WORKSPACE.bzlmod b/bazel/test/WORKSPACE.bzlmod
@@ -0,0 +1 @@
+# Replaces WORKSPACE.bazel under --enable_bzlmod
diff --git a/bazel/test/tarball.tar b/bazel/test/tarball.tar
diff --git a/bazel/test/test.yaml b/bazel/test/test.yaml
@@ -0,0 +1,8 @@
+schemaVersion: "2.0.0"
+
+metadataTest:
+  envVars:
+    - key: "ENV"
+      value: "/test"
+  entrypoint: ["/custom_bin"]
+  cmd: ["--arg1", "--arg2"]
diff --git a/bazel/toolchain.bzl b/bazel/toolchain.bzl
@@ -0,0 +1,45 @@
+"""This module implements the toolchain rule to locate the binary."""
+
+StructureTestInfo = provider(
+    doc = "Information about how to invoke the container-structure-test executable.",
+    fields = {
+        "binary": "Executable container-structure-test binary",
+    },
+)
+
+def _structure_test_toolchain_impl(ctx):
+    binary = ctx.executable.structure_test
+
+    template_variables = platform_common.TemplateVariableInfo({
+        "STRUCTURE_TEST_BIN": binary.path,
+    })
+    default = DefaultInfo(
+        files = depset([binary]),
+        runfiles = ctx.runfiles(files = [binary]),
+    )
+    st_info = StructureTestInfo(binary = binary)
+
+    toolchain_info = platform_common.ToolchainInfo(
+        st_info = st_info,
+        template_variables = template_variables,
+        default = default,
+    )
+    return [
+        default,
+        toolchain_info,
+        template_variables,
+    ]
+
+structure_test_toolchain = rule(
+    implementation = _structure_test_toolchain_impl,
+    attrs = {
+        "structure_test": attr.label(
+            doc = "A hermetically downloaded structure_test executable for the target platform.",
+            mandatory = True,
+            executable = True,
+            cfg = "exec",
+            allow_single_file = True,
+        ),
+    },
+    doc = "Defines a structure_test toolchain. See: https://docs.bazel.build/versions/main/toolchains.html#defining-toolchains.",
+)
diff --git a/bazel/toolchains_repo.bzl b/bazel/toolchains_repo.bzl
diff --git a/defs.bzl b/defs.bzl
diff --git a/repositories.bzl b/repositories.bzl

Original file line number	Diff line number	Diff line change
`@@ -0,0 +1 @@`
	`1`	`+# Marker that this is the root of a Bazel package`