trigger hurt

[yourmom468x]

can you implement this please? :>

[H2xDev]

Hi! @yourmom468x

The entities implementation is not a part of the plugin and behavior of entities depends on the game design completely. Take entities/trigger_once.gd as a basis for implementation for your trigger_hurt entity. Check that your player controller is in the trigger_hurt's area and then decrease health value.

Important

Make sure your entity scene has Area3D with name area and it has collision shape inside.

Here's how i implemented my trigger_hurt:

# trigger_hurt.gd
@tool
class_name trigger_hurt extends trigger_multiple

## Damage per half second
const DAMAGE_RATE = 0.5;

var damage: float = 0.0:
	get: return float(entity.get("damage", 0.0));

var damagetype: Damageable.DamageType:
	get: return entity.get("damagetype", Damageable.DamageType.GENERIC) as Damageable.DamageType;

var bodies: Array = [];
var timer: float = 0.0;

func _entity_ready():
	super._entity_ready();

	$area.body_entered.connect(_on_body_entered);
	$area.body_exited.connect(_on_body_left);

func _process(delta):
	if not enabled: 
		timer = 0.0;
		return;

	timer -= delta;

	if timer <= 0.0:
		timer = DAMAGE_RATE;
		damage_bodies();

func _on_body_entered(body):
	if bodies.has(body):
		return;

	bodies.append(body);

func _on_body_left(body):
	if bodies.has(body):
		bodies.erase(body);
	timer = -0.01;

func damage_bodies():
	for body in bodies:
		(body as Damageable).take_damage(damage, damagetype);

# trigger_multiple.gd
@tool
class_name trigger_multiple
extends ValveIONode

const FLAG_CLIENTS = 1;

func get_filter_entity() -> filter_entity:
	var target_entity = get_target(entity.get("filtername", ""));

	if not target_entity: return null;

	return target_entity as filter_entity;

func _entity_ready():
	$area.body_entered.connect(func(body):
		var is_client_passed = has_flag(FLAG_CLIENTS) and ValveIONode.aliases.get("!player", null) == body;

		var filter = get_filter_entity();
		var is_filter_passed = filter.is_passed(body) if filter else false;

		if is_client_passed or is_filter_passed:
			trigger_output("OnTrigger");
			trigger_output("OnStartTouch");
	);

	$area.body_exited.connect(func(body):
		var is_client_passed = has_flag(FLAG_CLIENTS) and ValveIONode.aliases.get("!player", null) == body;
		var filter = get_filter_entity();
		var is_filter_passed = filter.is_passed(body) if filter else false;

		if is_client_passed or is_filter_passed: 
			trigger_output("OnEndTouch");
	);

func _apply_entity(e):
	super._apply_entity(e);
	
	$area/collision.shape = get_entity_shape();