Added support for Debian Package plugin.

Author: Michael Legart

docs/Job-reference.md

@@ -139,6 +139,7 @@ freeStyleJob(String name) { // since 1.30
                       boolean flattenFiles, boolean optionalAllowed,
                       Closure copyArtifactClosure)
         criticalBlock(Closure stepClosure) // since 1.24
+        debianPackage(String path, Closure debianClosure)
         downstreamParameterized(Closure downstreamClosure)
         dsl(Closure dslClosure)
         dsl(String scriptText, String removedJobAction = null,
@@ -3044,6 +3045,22 @@ When a job is checked the following conditions must be validated before the job
 
 (Since 1.19)
 
+# [Debian Package Builder Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Debian+Package+Builder+Plugin)
+
+```groovy
+debianPackage(String path, Closure debianClosure) {
+    signPackage(true) // Sign package with GPG (key configured in Jenkins settings)
+    generateChangelog(false) // Build changelog from Git
+    buildEvenWhenThereAreNoChanges(false) // Build package if no changes has been made in SCM
+}
+```
+
+Supports <a href="https://wiki.jenkins-ci.org/display/JENKINS/Debian+Package+Builder+Plugin">the Debian PackageBuilder Plugin</a>.
+
+Path refers to a path in the workspace where the 'debian' catalog is stored.
+
+The plugin will automatically install packages required to build Debian packages.
+
 # [Parameterized Trigger as Build Step](https://wiki.jenkins-ci.org/display/JENKINS/Parameterized+Trigger+Plugin)
 
 ```groovy

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/step/DebianContext.groovy

@@ -0,0 +1,27 @@
+package javaposse.jobdsl.dsl.helpers.step
+
+import javaposse.jobdsl.dsl.Context
+
+class DebianContext implements Context {
+    String nextVersion
+    boolean generateChangelog
+    boolean signPackage
+    boolean buildEvenWhenThereAreNoChanges
+
+    void nextVersion(String nextVersion) {
+        this.nextVersion = nextVersion
+    }
+
+    void generateChangelog(boolean generateChangelog) {
+        this.generateChangelog = generateChangelog
+    }
+
+    void signPackage(boolean signPackage) {
+        this.signPackage = signPackage
+    }
+
+    void buildEvenWhenThereAreNoChanges(boolean buildEvenWhenThereAreNoChanges) {
+        this.buildEvenWhenThereAreNoChanges = buildEvenWhenThereAreNoChanges
+    }
+
+}

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/step/StepContext.groovy

@@ -1116,4 +1116,30 @@ class StepContext implements Context {
             }
         }
     }
+
+    /**
+     * <ru.yandex.jenkins.plugins.debuilder.DebianPackageBuilder plugin="debian-package-builder@1.6.6">
+     *     <pathToDebian>package</pathToDebian>
+     *     <nextVersion></nextVersion>
+     *     <generateChangelog>false</generateChangelog>
+     *     <signPackage>false</signPackage>
+     *     <buildEvenWhenThereAreNoChanges>false</buildEvenWhenThereAreNoChanges>
+     * </ru.yandex.jenkins.plugins.debuilder.DebianPackageBuilder>
+     */
+    void debianPackage(String path, @DslContext(DebianContext) Closure closure = null) {
+        Preconditions.checkArgument(!isNullOrEmpty(path), 'path must be specified')
+
+        DebianContext context = new DebianContext()
+        ContextHelper.executeInContext(closure, context)
+
+        stepNodes << new NodeBuilder().'ru.yandex.jenkins.plugins.debuilder.DebianPackageBuilder' {
+            pathToDebian(path)
+            if (context.nextVersion != null) {
+                nextVersion(context.nextVersion)
+            }
+            generateChangelog(context.generateChangelog)
+            signPackage(context.signPackage)
+            buildEvenWhenThereAreNoChanges(context.buildEvenWhenThereAreNoChanges)
+        }
+    }
 }

job-dsl-core/src/test/groovy/javaposse/jobdsl/dsl/helpers/step/StepContextSpec.groovy

@@ -2451,4 +2451,41 @@ still-another-dsl.groovy'''
         where:
         mode << ['GET', 'POST', 'PUT', 'DELETE']
     }
+
+    def 'call debian package with only required option'() {
+        when:
+        context.debianPackage('package')
+
+        then:
+        context.stepNodes.size() == 1
+        with(context.stepNodes[0]) {
+            name() == 'ru.yandex.jenkins.plugins.debuilder.DebianPackageBuilder'
+            pathToDebian[0].value() == 'package'
+            signPackage[0].value() == false
+            generateChangelog[0].value() == false
+            buildEvenWhenThereAreNoChanges[0].value() == false
+        }
+
+    }
+
+    def 'call debian package with all options'() {
+        when:
+        context.debianPackage('package') {
+            signPackage(true)
+            generateChangelog(true)
+            buildEvenWhenThereAreNoChanges(true)
+        }
+
+        then:
+        context.stepNodes.size() == 1
+        with(context.stepNodes[0]) {
+            name() == 'ru.yandex.jenkins.plugins.debuilder.DebianPackageBuilder'
+            pathToDebian[0].value() == 'package'
+            signPackage[0].value() == true
+            generateChangelog[0].value() == true
+            buildEvenWhenThereAreNoChanges[0].value() == true
+        }
+
+    }
+
 }