Merge branch 'debianpackageplugin'

Conflicts:
	job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/step/StepContext.groovy
	job-dsl-core/src/test/groovy/javaposse/jobdsl/dsl/helpers/step/StepContextSpec.groovy

Author: daspilker

docs/Home.md

@@ -20,6 +20,7 @@ Have a look at the [Jenkins Job DSL Gradle example](https://github.com/sheehan/j
  * Added support for [Build Node Column Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Build+Node+Column+Plugin)
  * Added support for [Pre-SCM Build Step Plugin](https://wiki.jenkins-ci.org/display/JENKINS/pre-scm-buildstep)
  * Added support for [Sonar Plugin](http://docs.sonarqube.org/display/SONAR/Jenkins+Plugin)
+ * Added support for [Debian Package Builder Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Debian+Package+Builder+Plugin)
  * Added `recurse` option for list views
  * Added `ignorePostCommitHooks` option for SCM trigger
  * Added `commentFilePath` option for [GitHub Pull Request Builder Plugin](https://wiki.jenkins-ci.org/display/JENKINS/GitHub+pull+request+builder+plugin)

docs/Job-reference.md

@@ -139,6 +139,7 @@ freeStyleJob(String name) { // since 1.30
                       boolean flattenFiles, boolean optionalAllowed,
                       Closure copyArtifactClosure)
         criticalBlock(Closure stepClosure) // since 1.24
+        debianPackage(String path, Closure debianClosure = null) // since 1.31
         downstreamParameterized(Closure downstreamClosure)
         dsl(Closure dslClosure)
         dsl(String scriptText, String removedJobAction = null,
@@ -3067,6 +3068,36 @@ When a job is checked the following conditions must be validated before the job
 
 (Since 1.19)
 
+# Debian Package Builder
+
+```groovy
+job {
+    step {
+        debianPackage(String path) {
+            signPackage(boolean sign = true) // defaults to true
+            generateChangelog(String nextVersion = null, boolean alwaysBuild = false)
+        }
+    }
+}
+```
+
+Requires the [Debian Package Builder Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Debian+Package+Builder+Plugin).
+
+The `path` parameter refers to a path in the workspace where the 'debian' catalog is stored. The plugin will
+automatically install packages required to build Debian packages.
+
+```groovy
+job {
+    step {
+        debianPackage('module') {
+            generateChangelog()
+        }
+    }
+}
+```
+
+(since 1.31)
+
 # [Parameterized Trigger as Build Step](https://wiki.jenkins-ci.org/display/JENKINS/Parameterized+Trigger+Plugin)
 
 ```groovy

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/step/DebianContext.groovy

@@ -0,0 +1,20 @@
+package javaposse.jobdsl.dsl.helpers.step
+
+import javaposse.jobdsl.dsl.Context
+
+class DebianContext implements Context {
+    boolean generateChangelog
+    String nextVersion
+    boolean alwaysBuild
+    boolean signPackage = true
+
+    void generateChangelog(String nextVersion = null, boolean alwaysBuild = false) {
+        this.generateChangelog = true
+        this.nextVersion = nextVersion
+        this.alwaysBuild = alwaysBuild
+    }
+
+    void signPackage(boolean signPackage = true) {
+        this.signPackage = signPackage
+    }
+}

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/step/StepContext.groovy

@@ -1059,4 +1059,30 @@ class StepContext implements Context {
             nodeJSInstallationName(installation)
         }
     }
+
+    /**
+     * <ru.yandex.jenkins.plugins.debuilder.DebianPackageBuilder>
+     *     <pathToDebian>package</pathToDebian>
+     *     <nextVersion></nextVersion>
+     *     <generateChangelog>false</generateChangelog>
+     *     <signPackage>false</signPackage>
+     *     <buildEvenWhenThereAreNoChanges>false</buildEvenWhenThereAreNoChanges>
+     * </ru.yandex.jenkins.plugins.debuilder.DebianPackageBuilder>
+     */
+    void debianPackage(String path, @DslContext(DebianContext) Closure closure = null) {
+        jobManagement.requireMinimumPluginVersion('debian-package-builder', '1.6.6')
+
+        Preconditions.checkArgument(!isNullOrEmpty(path), 'path must be specified')
+
+        DebianContext context = new DebianContext()
+        ContextHelper.executeInContext(closure, context)
+
+        stepNodes << new NodeBuilder().'ru.yandex.jenkins.plugins.debuilder.DebianPackageBuilder' {
+            pathToDebian(path)
+            nextVersion(context.nextVersion ?: '')
+            generateChangelog(context.generateChangelog)
+            signPackage(context.signPackage)
+            buildEvenWhenThereAreNoChanges(context.alwaysBuild)
+        }
+    }
 }

job-dsl-core/src/test/groovy/javaposse/jobdsl/dsl/helpers/step/StepContextSpec.groovy

@@ -2256,4 +2256,41 @@ still-another-dsl.groovy'''
             nodeJSInstallationName[0].value() == 'node (0.0.1)'
         }
     }
+
+    def 'call debian package with only required option'() {
+        when:
+        context.debianPackage('package')
+
+        then:
+        with(context.stepNodes[0]) {
+            name() == 'ru.yandex.jenkins.plugins.debuilder.DebianPackageBuilder'
+            children().size() == 5
+            pathToDebian[0].value() == 'package'
+            nextVersion[0].value() == ''
+            generateChangelog[0].value() == false
+            signPackage[0].value() == true
+            buildEvenWhenThereAreNoChanges[0].value() == false
+        }
+        _ * jobManagement.requireMinimumPluginVersion('debian-package-builder', '1.6.6')
+    }
+
+    def 'call debian package with all options'() {
+        when:
+        context.debianPackage('package') {
+            signPackage(false)
+            generateChangelog('1.0', true)
+        }
+
+        then:
+        with(context.stepNodes[0]) {
+            name() == 'ru.yandex.jenkins.plugins.debuilder.DebianPackageBuilder'
+            children().size() == 5
+            pathToDebian[0].value() == 'package'
+            nextVersion[0].value() == '1.0'
+            generateChangelog[0].value() == true
+            signPackage[0].value() == false
+            buildEvenWhenThereAreNoChanges[0].value() == true
+        }
+        _ * jobManagement.requireMinimumPluginVersion('debian-package-builder', '1.6.6')
+    }
 }