Merge branch 'xvfb'

Conflicts:
	docs/Home.md

Author: daspilker

docs/Home.md

@@ -22,6 +22,7 @@ Have a look at the [Jenkins Job DSL Gradle example](https://github.com/sheehan/j
  * Added support for [Sonar Plugin](http://docs.sonarqube.org/display/SONAR/Jenkins+Plugin)
  * Added `ignorePostCommitHooks` option for SCM trigger
  * Added support for [PostBuildScript Plugin](https://wiki.jenkins-ci.org/display/JENKINS/PostBuildScript+Plugin)
+ * Added support for [Xvfb Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Xvfb+Plugin)
  * The enum argument of `localRepository` for the Maven job and context has changed, see [[Migration]]
  * Added partial support for [Plot Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Plot+Plugin)
 * 1.30 (March 08 2015)

docs/Job-reference.md

@@ -118,6 +118,7 @@ freeStyleJob(String name) { // since 1.30
         timeout(Closure timeoutClosure = null)
         timestamps()
         toolenv(String... tools)
+        xvfb(String installation, Closure xvfbClosure = null) // since 1.31
         xvnc(boolean takeScreenshot) // deprecated
         xvnc(Closure xvncClosure = null) // since 1.26
     }
@@ -1694,6 +1695,38 @@ job('example') {
 
 (Since 1.19)
 
+### Xvfb
+
+```groovy
+job {
+    wrappers {
+        xvfb(String xvfbInstallation) {
+            screen(String screen)                               // defaults to 1024x768x24
+            debug(boolean debug = true)                         // defaults to false
+            timeout(int timeout)                                // defaults to 0
+            displayNameOffset(int displayNameOffset)            // defaults to 1
+            shutdownWithBuild(boolean shutdownWithBuild = true) // defaults to false
+            autoDisplayName(boolean autoDisplayName = true)     // defaults to false
+            assignedLabels(String labels)
+            parallelBuild(boolean parallelBuild = true)         // defaults to false
+        }
+    }
+}
+```
+
+Controls the Xvfb virtual frame buffer X11 server. Requires the
+[Xvfb Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Xvfb+Plugin).
+
+```groovy
+job {
+    wrappers {
+        xvfb('default') {
+            screen('1920x1080x24')
+        }
+    }
+}
+```
+
 ### Xvnc
 
 ```groovy

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/wrapper/WrapperContext.groovy

@@ -1,6 +1,7 @@
 package javaposse.jobdsl.dsl.helpers.wrapper
 
 import com.google.common.base.Preconditions
+import com.google.common.base.Strings
 import hudson.util.VersionNumber
 import javaposse.jobdsl.dsl.Context
 import javaposse.jobdsl.dsl.ContextHelper
@@ -308,6 +309,40 @@ class WrapperContext implements Context {
         }
     }
 
+    /**
+     * <org.jenkinsci.plugins.xvfb.XvfbBuildWrapper>
+     *     <installationName>xvfb</installationName>
+     *     <screen>1024x768x24</screen>
+     *     <debug>false</debug>
+     *     <timeout>0</timeout>
+     *     <displayNameOffset>1</displayNameOffset>
+     *     <shutdownWithBuild>false</shutdownWithBuild>
+     *     <autoDisplayName>false</autoDisplayName>
+     *     <assignedLabels>xvfb</assignedLabels>
+     *     <parallelBuild>false</parallelBuild>
+     * </org.jenkinsci.plugins.xvfb.XvfbBuildWrapper>
+     */
+    void xvfb(String installation, @DslContext(XvfbContext) Closure closure = null) {
+        Preconditions.checkArgument(!Strings.isNullOrEmpty(installation), 'installation must not be null or empty')
+
+        XvfbContext context = new XvfbContext()
+        ContextHelper.executeInContext(closure, context)
+
+        wrapperNodes << new NodeBuilder().'org.jenkinsci.plugins.xvfb.XvfbBuildWrapper' {
+            installationName(installation)
+            screen(context.screen)
+            debug(context.debug)
+            timeout(context.timeout)
+            displayNameOffset(context.displayNameOffset)
+            shutdownWithBuild(context.shutdownWithBuild)
+            autoDisplayName(context.autoDisplayName)
+            if (context.assignedLabels) {
+                assignedLabels(context.assignedLabels)
+            }
+            parallelBuild(context.parallelBuild)
+        }
+    }
+
     /**
      * <pre>
      * {@code

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/wrapper/XvfbContext.groovy

@@ -0,0 +1,46 @@
+package javaposse.jobdsl.dsl.helpers.wrapper
+
+import javaposse.jobdsl.dsl.Context
+
+class XvfbContext implements Context {
+    String screen = '1024x768x24'
+    boolean debug = false
+    int timeout = 0
+    int displayNameOffset = 1
+    boolean shutdownWithBuild = false
+    boolean autoDisplayName = false
+    String assignedLabels
+    boolean parallelBuild = false
+
+    void screen(String screen) {
+        this.screen = screen
+    }
+
+    void debug(boolean debug = true) {
+        this.debug = debug
+    }
+
+    void timeout(int timeout) {
+        this.timeout = timeout
+    }
+
+    void displayNameOffset(int displayNameOffset) {
+        this.displayNameOffset = displayNameOffset
+    }
+
+    void shutdownWithBuild(boolean shutdownWithBuild = true) {
+        this.shutdownWithBuild = shutdownWithBuild
+    }
+
+    void autoDisplayName(boolean autoDisplayName = true) {
+        this.autoDisplayName = autoDisplayName
+    }
+
+    void assignedLabels(String assignedLabels) {
+        this.assignedLabels = assignedLabels
+    }
+
+    void parallelBuild(boolean parallelBuild = true) {
+        this.parallelBuild = parallelBuild
+    }
+}

job-dsl-core/src/test/groovy/javaposse/jobdsl/dsl/helpers/wrapper/WrapperContextSpec.groovy

@@ -413,6 +413,65 @@ class WrapperContextSpec extends Specification {
         wrapper.takeScreenshot[0].value() == false
     }
 
+    def 'xvfb with minimal options'() {
+        when:
+        context.xvfb('default')
+
+        then:
+        with(context.wrapperNodes[0]) {
+            name() == 'org.jenkinsci.plugins.xvfb.XvfbBuildWrapper'
+            children().size() == 8
+            installationName[0].value() == 'default'
+            screen[0].value() == '1024x768x24'
+            debug[0].value() == false
+            timeout[0].value() == 0
+            displayNameOffset[0].value() == 1
+            shutdownWithBuild[0].value() == false
+            autoDisplayName[0].value() == false
+            parallelBuild[0].value() == false
+        }
+    }
+
+    def 'xvfb with all options'() {
+        when:
+        context.xvfb('default') {
+            screen('1920x1080x32')
+            debug()
+            timeout(500)
+            displayNameOffset(24)
+            shutdownWithBuild()
+            autoDisplayName()
+            assignedLabels('test')
+            parallelBuild()
+        }
+
+        then:
+        with(context.wrapperNodes[0]) {
+            name() == 'org.jenkinsci.plugins.xvfb.XvfbBuildWrapper'
+            children().size() == 9
+            installationName[0].value() == 'default'
+            screen[0].value() == '1920x1080x32'
+            debug[0].value() == true
+            timeout[0].value() == 500
+            displayNameOffset[0].value() == 24
+            shutdownWithBuild[0].value() == true
+            autoDisplayName[0].value() == true
+            assignedLabels[0].value() == 'test'
+            parallelBuild[0].value() == true
+        }
+    }
+
+    def 'xvfb without installation'() {
+        when:
+        context.xvfb(installation)
+
+        then:
+        thrown(IllegalArgumentException)
+
+        where:
+        installation << [null, '']
+    }
+
     def 'toolenv' () {
         when:
         context.toolenv('Ant 1.8.2', 'Maven 3')