Merge pull request #403 from CoreMedia/postbuildscript

added support for PostBuildScript Plugin

Author: daspilker

docs/Home.md

@@ -20,6 +20,7 @@ Have a look at the [Jenkins Job DSL Gradle example](https://github.com/sheehan/j
  * Added support for [Build Node Column Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Build+Node+Column+Plugin)
  * Added support for [Pre-SCM Build Step Plugin](https://wiki.jenkins-ci.org/display/JENKINS/pre-scm-buildstep)
  * Added `ignorePostCommitHooks` option for SCM trigger
+ * Added support for [PostBuildScript Plugin](https://wiki.jenkins-ci.org/display/JENKINS/PostBuildScript+Plugin)
  * The enum argument of `localRepository` for the Maven job and context has changed, see [[Migration]]
 * 1.30 (March 08 2015)
  * Added support for [Custom Tools Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Custom+Tools+Plugin)

docs/Job-reference.md

@@ -228,6 +228,7 @@ freeStyleJob(String name) { // since 1.30
                Boolean sendToIndividuals = false)
         mavenDeploymentLinker(String regex) // since 1.23
         pmd(String pattern, Closure staticAnalysisClosure = null)
+        postBuildScripts(Closure postBuildScriptsClosure) // since 1.31
         postBuildTask(Closure closure) // since 1.19
         publishCloneWorkspace(String workspaceGlob, Closure cloneWorkspaceClosure)
         publishCloneWorkspace(String workspaceGlob, String workspaceExcludeGlob,
@@ -3987,6 +3988,37 @@ publishers {
 
 (Since 1.19)
 
+### Post Build Scripts
+
+```groovy
+job {
+    publishers {
+        postBuildScripts {
+            steps(Closure stepClosure)
+            onlyIfBuildSucceeds(boolean onlyIfBuildSucceeds = true) // defaults to true
+        }
+    }
+}
+```
+
+Execute a set of scripts at the end of the build. Requires the
+[PostBuildScript Plugin](https://wiki.jenkins-ci.org/display/JENKINS/PostBuildScript+Plugin).
+
+```groovy
+job {
+    publishers {
+        postBuildScripts {
+            steps {
+                shell('echo Hello World')
+            }
+            onlyIfBuildSucceeds(false)
+        }
+    }
+}
+```
+
+(since 1.31)
+
 ### [Post Build Task](https://wiki.jenkins-ci.org/display/JENKINS/Post+build+task)
 
 Searches for a regular expression in the console log and, if matched, executes a script. Requires the [Post Build Task Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Post+build+task).

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/publisher/PostBuildScriptsContext.groovy

@@ -0,0 +1,24 @@
+package javaposse.jobdsl.dsl.helpers.publisher
+
+import javaposse.jobdsl.dsl.Context
+import javaposse.jobdsl.dsl.ContextHelper
+import javaposse.jobdsl.dsl.DslContext
+import javaposse.jobdsl.dsl.JobManagement
+import javaposse.jobdsl.dsl.helpers.step.StepContext
+
+class PostBuildScriptsContext implements Context {
+    final StepContext stepContext
+    boolean onlyIfBuildSucceeds = true
+
+    PostBuildScriptsContext(JobManagement jobManagement) {
+        this.stepContext = new StepContext(jobManagement)
+    }
+
+    void steps(@DslContext(StepContext) Closure stepClosure) {
+        ContextHelper.executeInContext(stepClosure, stepContext)
+    }
+
+    void onlyIfBuildSucceeds(boolean onlyIfBuildSucceeds = true) {
+        this.onlyIfBuildSucceeds = onlyIfBuildSucceeds
+    }
+}

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/publisher/PublisherContext.groovy

@@ -1705,6 +1705,26 @@ class PublisherContext implements Context {
         }
     }
 
+    /**
+     * <org.jenkinsci.plugins.postbuildscript.PostBuildScript>
+     *     <buildSteps>
+     *         <hudson.tasks.Shell>
+     *             <command>echo foo</command>
+     *         </hudson.tasks.Shell>
+     *     </buildSteps>
+     *     <scriptOnlyIfSuccess>true</scriptOnlyIfSuccess>
+     * </org.jenkinsci.plugins.postbuildscript.PostBuildScript>
+     */
+    void postBuildScripts(@DslContext(PostBuildScriptsContext) Closure closure) {
+        PostBuildScriptsContext context = new PostBuildScriptsContext(jobManagement)
+        ContextHelper.executeInContext(closure, context)
+
+        publisherNodes << new NodeBuilder().'org.jenkinsci.plugins.postbuildscript.PostBuildScript' {
+            buildSteps(context.stepContext.stepNodes)
+            scriptOnlyIfSuccess(context.onlyIfBuildSucceeds)
+        }
+    }
+
     private static createDefaultStaticAnalysisNode(String publisherClassName, Closure staticAnalysisClosure,
                                                    String pattern) {
         StaticAnalysisContext staticAnalysisContext = new StaticAnalysisContext()

job-dsl-core/src/test/groovy/javaposse/jobdsl/dsl/helpers/publisher/PublisherContextSpec.groovy

@@ -2992,4 +2992,37 @@ class PublisherContextSpec extends Specification {
         then:
         thrown(IllegalArgumentException)
     }
+
+    def 'call post build scripts with minimal options'() {
+        when:
+        context.postBuildScripts {
+        }
+
+        then:
+        with(context.publisherNodes[0]) {
+            name() == 'org.jenkinsci.plugins.postbuildscript.PostBuildScript'
+            children().size() == 2
+            buildSteps[0].children().size == 0
+            scriptOnlyIfSuccess[0].value() == true
+        }
+    }
+
+    def 'call post build scripts with all options'() {
+        when:
+        context.postBuildScripts {
+            steps {
+                shell('echo TEST')
+            }
+            onlyIfBuildSucceeds(false)
+        }
+
+        then:
+        with(context.publisherNodes[0]) {
+            name() == 'org.jenkinsci.plugins.postbuildscript.PostBuildScript'
+            children().size() == 2
+            buildSteps[0].children().size == 1
+            buildSteps[0].children()[0].name() == 'hudson.tasks.Shell'
+            scriptOnlyIfSuccess[0].value() == false
+        }
+    }
 }