Merge pull request #399 from CoreMedia/pre-scm

added support for the pre-scm build step plugin

Author: daspilker

docs/Home.md

@@ -17,6 +17,7 @@ Have a look at the [Jenkins Job DSL Gradle example](https://github.com/sheehan/j
 
 ## Release Notes
 * 1.31 (unreleased)
+ * Added support for [Pre-SCM Build Step Plugin](https://wiki.jenkins-ci.org/display/JENKINS/pre-scm-buildstep)
  * The enum argument of `localRepository` for the Maven job and context has changed, see [[Migration]]
 * 1.30 (March 08 2015)
  * Added support for [Custom Tools Plugin](https://wiki.jenkins-ci.org/display/JENKINS/Custom+Tools+Plugin)

docs/Job-reference.md

@@ -108,6 +108,7 @@ freeStyleJob(String name) { // since 1.30
         maskPasswords() // since 1.26
         nodejs(String installation) // since 1.27
         preBuildCleanup(Closure closure = null) // since 1.22
+        preScmSteps(Closure closure) // since 1.31
         rbenv(String rubyVersion, Closure rbenvClosure = null) // since 1.27
         release(Closure releaseClosure) // since 1.22
         runOnSameNodeAs(String jobName, boolean useSameWorkspace = false)
@@ -1854,6 +1855,39 @@ job('example') {
 
 (since 1.22)
 
+### Pre SCM Build Steps
+
+```groovy
+job {
+    wrappers {
+        preScmSteps {
+            steps(Closure stepClosure)
+            failOnError(boolean failOnError = true) // defaults to false
+        }
+    }
+}
+```
+
+Allows build steps to run before SCM checkout. Requires the
+[Pre-SCM Build Step Plugin](https://wiki.jenkins-ci.org/display/JENKINS/pre-scm-buildstep).
+
+See [Build Steps](#build-steps) for available steps in the `stepClosure`.
+
+```groovy
+job {
+    wrappers {
+        preScmSteps {
+            steps {
+                shell('echo Hello World')
+            }
+            failOnError()
+        }
+    }
+}
+```
+
+(since 1.31)
+
 ### Log File Size Checker Plugin
 
 ```groovy

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/wrapper/PreScmStepsContext.groovy

@@ -0,0 +1,24 @@
+package javaposse.jobdsl.dsl.helpers.wrapper
+
+import javaposse.jobdsl.dsl.Context
+import javaposse.jobdsl.dsl.ContextHelper
+import javaposse.jobdsl.dsl.DslContext
+import javaposse.jobdsl.dsl.JobManagement
+import javaposse.jobdsl.dsl.helpers.step.StepContext
+
+class PreScmStepsContext implements Context {
+    final StepContext stepContext
+    boolean failOnError
+
+    PreScmStepsContext(JobManagement jobManagement) {
+        this.stepContext = new StepContext(jobManagement)
+    }
+
+    void steps(@DslContext(StepContext) Closure closure) {
+        ContextHelper.executeInContext(closure, stepContext)
+    }
+
+    void failOnError(boolean failOnError = true) {
+        this.failOnError = failOnError
+    }
+}

job-dsl-core/src/main/groovy/javaposse/jobdsl/dsl/helpers/wrapper/WrapperContext.groovy

@@ -751,4 +751,24 @@ class WrapperContext implements Context {
             convertHomesToUppercase context.convertHomesToUppercase
         }
     }
+
+    /**
+     * <org.jenkinsci.plugins.preSCMbuildstep.PreSCMBuildStepsWrapper>
+     *     <buildSteps>
+     *         <hudson.tasks.Shell>
+     *             <command>echo hello</command>
+     *         </hudson.tasks.Shell>
+     *     </buildSteps>
+     *     <failOnError>false</failOnError>
+     * </org.jenkinsci.plugins.preSCMbuildstep.PreSCMBuildStepsWrapper>
+     */
+    void preScmSteps(@DslContext(PreScmStepsContext) Closure closure) {
+        PreScmStepsContext context = new PreScmStepsContext(jobManagement)
+        ContextHelper.executeInContext(closure, context)
+
+        wrapperNodes << new NodeBuilder().'org.jenkinsci.plugins.preSCMbuildstep.PreSCMBuildStepsWrapper' {
+            buildSteps(context.stepContext.stepNodes)
+            failOnError(context.failOnError)
+        }
+    }
 }

job-dsl-core/src/test/groovy/javaposse/jobdsl/dsl/helpers/wrapper/WrapperContextSpec.groovy

@@ -1013,4 +1013,39 @@ class WrapperContextSpec extends Specification {
             }
         }
     }
+
+    def 'pre SCM build steps with minimal options'() {
+        when:
+        context.preScmSteps {
+        }
+
+        then:
+        with(context.wrapperNodes[0]) {
+            name() == 'org.jenkinsci.plugins.preSCMbuildstep.PreSCMBuildStepsWrapper'
+            children().size() == 2
+            buildSteps[0].children().size() == 0
+            failOnError[0].value() == false
+        }
+    }
+
+    def 'pre SCM build steps with all options'() {
+        when:
+        context.preScmSteps {
+            steps {
+                shell('echo HELLO')
+                batchFile('echo WORLD')
+            }
+            failOnError()
+        }
+
+        then:
+        with(context.wrapperNodes[0]) {
+            name() == 'org.jenkinsci.plugins.preSCMbuildstep.PreSCMBuildStepsWrapper'
+            children().size() == 2
+            buildSteps[0].children().size() == 2
+            buildSteps[0].children()[0].name() == 'hudson.tasks.Shell'
+            buildSteps[0].children()[1].name() == 'hudson.tasks.BatchFile'
+            failOnError[0].value() == true
+        }
+    }
 }