tactile/tactile.pro at master · KanoComputing/tactile · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# tactile.pro
#
# Copyright (C) 2018 Kano Computing Ltd.
# License: http://www.gnu.org/licenses/gpl-2.0.txt GNU GPL v2
#
# Main project file for qmake.


TEMPLATE = app

CONFIG += \
    kano_build_options \
    kano_qt_sdk

unix:!macx {
    QT += dbus
}

include(build/i18n.pri)
include(build/headers.pri)
include(build/sources.pri)

RESOURCES += res/all.qrc

QML_IMPORT_PATHS = \
    $$PWD/res/ui \
    $$SYSTEM_QML_PATHS \
    "/usr/share/tactile/ui"

DEFINES += QML_IMPORT_PATHS=\\\"$$join($$list($$QML_IMPORT_PATHS), ':')\\\"

DESTDIR = bin

# TODO: Move the logic below into kano-qt-sdk and remove!

# Move the generated i18n folder into the res/ dir
QMAKE_POST_LINK += \
    rm -rf $$PWD/res/i18n && \
    mv $$PWD/i18n $$PWD/res

# Compile out debugging statements for release.
# Comment this out during development.
DEFINES += QT_NO_DEBUG