interface.ino

// ------------------------
const char* getTimebaseLabel()	{
// ------------------------
	return tbNames[currentTimeBase];
}



// interface operations defined below

long lastBtnPress = 0;



// ------------------------
void btn4ISR()	{
// ------------------------
	static boolean pressed = false;
	static long pressedTime = 0;

	// btn pressed or released?
	if(!pressed && (digitalRead(BTN4) == LOW))	{
		// debounce
		if(millis() - pressedTime < BTN_DEBOUNCE_TIME)
			return;
		pressedTime = millis();
		pressed = true;
	}
	
	
	if(pressed && (digitalRead(BTN4) == HIGH))	{
		// debounce
		if(millis() - pressedTime < 5)
			return;
		
		pressed = false;
		
		// is it a short press
		if(millis() - pressedTime < 1000)	{
			// toggle hold
			hold = !hold;
			repaintLabels();
		}
		else	{
			// long press reset parameter to default
			resetParam();
		}
	}
}



// ------------------------
void readESwitchISR()	{
// ------------------------
	// debounce
	if(millis() - lastBtnPress < BTN_DEBOUNCE_TIME)
		return;
	lastBtnPress = millis();

	// select different parameters to change
	focusNextLabel();
	
	// request repainting of screen labels
	repaintLabels();
	
	// manually update display if frozen
	if(hold)
		drawWaves();
	
	if(triggerType != TRIGGER_AUTO)
		// break the sampling loop
		keepSampling = false;
}




// ------------------------
void resetParam()	{
// ------------------------
	// which label has current focus
	switch(currentFocus)	{
		case L_triggerLevel:
			// set trigger level to 0
			setTriggerLevel(0);
			saveParameter(PARAM_TLEVEL, 0);
			repaintLabels();
			break;
		case L_window:
			// set x in the middle
			changeXCursor((NUM_SAMPLES - GRID_WIDTH)/2);
			break;
		case L_vPos1:
			// zero the trace base
			calculateTraceZero(0);
			changeYCursor(0, -GRID_HEIGHT/2 - 1);
			break;
		case L_vPos2:
			// zero the trace base
			calculateTraceZero(1);
			changeYCursor(1, -GRID_HEIGHT/2 - 1);
			break;
		case L_vPos3:
			changeYCursor(2, -GRID_HEIGHT/2 - 1);
			break;
		case L_vPos4:
			changeYCursor(3, -GRID_HEIGHT/2 - 1);
			break;
		default:
			// toggle stats printing
			printStats = !printStats;
			saveParameter(PARAM_STATS, printStats);
			break;
	}
	
	// manually update display if frozen
	if(hold)
		drawWaves();
	
	if(triggerType != TRIGGER_AUTO)
		// break the sampling loop
		keepSampling = false;
}




// ------------------------
void calculateTraceZero(int waveID)		{
// ------------------------
	// calculate zero only if switch is in GND position
	if(couplingPos1 != CPL_GND)
		return;

	if(waveID > 1)
		return;
	
	uint16_t *wave = (waveID == 0)? ch1Capture : ch2Capture;
	
	// zero the trace
	int32_t sumSamples = 0;

	for(uint16_t k = 0; k < NUM_SAMPLES; k++)	{
		sumSamples += wave[k];
	}

	uint16_t Vavr = sumSamples/NUM_SAMPLES;

	if(waveID == 0)	{
		zeroVoltageA1 = Vavr;
		saveParameter(PARAM_ZERO1, zeroVoltageA1);
	}
	else	{
		zeroVoltageA2 = Vavr;
		saveParameter(PARAM_ZERO2, zeroVoltageA2);
	}
}




// ------------------------
void encoderChanged(int steps)	{
// ------------------------
	// which label has current focus
	switch(currentFocus)	{
		case L_timebase:
			if(steps > 0) decrementTimeBase(); else	incrementTimeBase();
			break;
		case L_triggerType:
			if(steps > 0) incrementTT(); else decrementTT();
			break;
		case L_triggerEdge:
			if(steps > 0) setTriggerRising(); else setTriggerFalling();
			break;
		case L_triggerLevel:
			if(steps > 0) incrementTLevel(); else decrementTLevel();
			break;
		case L_waves:
			if(steps > 0) incrementWaves(); else decrementWaves();
			break;
		case L_window:
			if(steps > 0) changeXCursor(xCursor + XCURSOR_STEP); else changeXCursor(xCursor - XCURSOR_STEP);
			break;
		case L_vPos1:
			if(steps > 0) changeYCursor(0, yCursors[0] - YCURSOR_STEP); else changeYCursor(0, yCursors[0] + YCURSOR_STEP);
			break;
		case L_vPos2:
			if(steps > 0) changeYCursor(1, yCursors[1] - YCURSOR_STEP); else changeYCursor(1, yCursors[1] + YCURSOR_STEP);
			break;
		case L_vPos3:
			if(steps > 0) changeYCursor(2, yCursors[2] - YCURSOR_STEP); else changeYCursor(2, yCursors[2] + YCURSOR_STEP);
			break;
		case L_vPos4:
			if(steps > 0) changeYCursor(3, yCursors[3] - YCURSOR_STEP); else changeYCursor(3, yCursors[3] + YCURSOR_STEP);
			break;
    case L_range1:
      if(steps > 0) incrementRange1(); else decrementRange1();
      break;
    case L_range2:
      if(steps > 0) incrementRange2(); else decrementRange2();
      break;
	}
	
	// manually update display if frozen
	if(hold)
		drawWaves();
	
	if(triggerType != TRIGGER_AUTO)
		// break the sampling loop
		keepSampling = false;
}



// ------------------------
void incrementTLevel()	{
// ------------------------
	int16_t tL = getTriggerLevel();
	setTriggerLevel(tL + 32);
	saveParameter(PARAM_TLEVEL, tL);
	repaintLabels();
}



// ------------------------
void decrementTLevel()	{
// ------------------------
	int16_t tL = getTriggerLevel();
	setTriggerLevel(tL - 32);
	saveParameter(PARAM_TLEVEL, tL);
	repaintLabels();
}


// A1, D1, D2, A2 
// 0, 2, 3, 1
// ------------------------
void incrementWaves()	{
// ------------------------
  int nwaves = waves[1] ? 1 : 0;
  if (waves[2]) nwaves += 2;
  if (waves[3]) nwaves += 4;
  nwaves = (nwaves + 1) & 0x7;  // rotate waves
	waves[1] = nwaves & 1 ? true : false;
  waves[2] = nwaves & 2 ? true : false;
  waves[3] = nwaves & 4 ? true : false;
	saveParameter(PARAM_WAVES + 1, waves[1]);
  saveParameter(PARAM_WAVES + 2, waves[2]);
  saveParameter(PARAM_WAVES + 3, waves[3]);

	repaintLabels();
}




// ------------------------
void decrementWaves()	{
// ------------------------
	// remove waves
	if(waves[1])	{
		waves[1] = false;
		saveParameter(PARAM_WAVES + 1, waves[1]);
	}
	else if(waves[3])	{
		waves[3] = false;
		saveParameter(PARAM_WAVES + 3, waves[3]);
	}
	else if(waves[2])	{
		waves[2] = false;
		saveParameter(PARAM_WAVES + 2, waves[2]);
	}
	else {
		return;
	}
	
	repaintLabels();
}



// ------------------------
void setTriggerRising()	{
// ------------------------
	if(triggerRising)
		return;
	
	setTriggerRising(true);
	saveParameter(PARAM_TRIGDIR, triggerRising);
	repaintLabels();
}



// ------------------------
void setTriggerFalling()	{
// ------------------------
	if(!triggerRising)
		return;
	
	setTriggerRising(false);
	saveParameter(PARAM_TRIGDIR, triggerRising);
	repaintLabels();
}




// ------------------------
void incrementTT()	{
// ------------------------
	if(triggerType == TRIGGER_SINGLE)
		return;
	
	setTriggerType(triggerType + 1);
	// trigger type is not saved
	// saveParameter(PARAM_TRIGTYPE, triggerType);
	repaintLabels();
}



// ------------------------
void decrementTT()	{
// ------------------------
	if(triggerType == TRIGGER_AUTO)
		return;
	setTriggerType(triggerType - 1);
	// trigger type is not saved
	// saveParameter(PARAM_TRIGTYPE, triggerType);
	repaintLabels();
}




// ------------------------
void incrementTimeBase()	{
// ------------------------
	if(currentTimeBase == T20MS)
		return;
	
	setTimeBase(currentTimeBase + 1);
}



// ------------------------
void decrementTimeBase()	{
// ------------------------
	if(currentTimeBase == T12US)
		return;
	
	setTimeBase(currentTimeBase - 1);
}



// ------------------------
void setTimeBase(uint8_t timeBase)	{
// ------------------------
	currentTimeBase = timeBase;
	setSamplingRate(timeBase);
	saveParameter(PARAM_TIMEBASE, currentTimeBase);
	// request repainting of screen labels
	repaintLabels();
}




// ------------------------
void toggleWave(uint8_t num)	{
// ------------------------
	waves[num] = !waves[num];
	saveParameter(PARAM_WAVES + num, waves[num]);
	repaintLabels();
}



// ------------------------
void changeYCursor(uint8_t num, int16_t yPos)	{
// ------------------------
	if(yPos > 0)
		yPos = 0;
	
	if(yPos < -GRID_HEIGHT)
		yPos = -GRID_HEIGHT;

	yCursors[num] = yPos;
	saveParameter(PARAM_YCURSOR + num, yCursors[num]);
	repaintLabels();
}



// ------------------------
void changeXCursor(int16_t xPos)	{
// ------------------------
	if(xPos < 0)
		xPos = 0;
	
	if(xPos > (NUM_SAMPLES - GRID_WIDTH))
		xPos = NUM_SAMPLES - GRID_WIDTH;
	
	xCursor = xPos;
	saveParameter(PARAM_XCURSOR, xCursor);
	repaintLabels();
}




// ------------------------
void incrementRange1()  {
// ------------------------
  if(rangePos1 == RNG_10mV)
    return;
  ++rangePos1;
  saveParameter(PARAM_RANGE1, rangePos1);
  // request repainting of screen labels
  repaintLabels();
}

// ------------------------
void decrementRange1()  {
// ------------------------
  if(rangePos1 == RNG_5V)
    return;
  --rangePos1;
  saveParameter(PARAM_RANGE1, rangePos1);
  // request repainting of screen labels
  repaintLabels();
}

// ------------------------
void incrementRange2()  {
// ------------------------
  if(rangePos2 == RNG_10mV)
    return;
  ++rangePos2;
  saveParameter(PARAM_RANGE2, rangePos2);
  // request repainting of screen labels
  repaintLabels();
}

// ------------------------
void decrementRange2()  {
// ------------------------
  if(rangePos2 == RNG_5V)
    return;
  --rangePos2;
  saveParameter(PARAM_RANGE2, rangePos2);
  // request repainting of screen labels
  repaintLabels();
}