Allow negative indices for submatrices of mutable matrices

We define cover(MutableMatrix) so we can just use submatrixFree (which
calls cover).

Author: d-torrance

M2/Macaulay2/m2/mutablemat.m2

@@ -99,13 +99,13 @@ promote(MutableMatrix,Number) := Matrix => (f,S) -> (
 --------------------------------
 -- submatrices -----------------
 --------------------------------
-MutableMatrix _ List := Matrix => (f,v) -> submatrix(f,listZ splice v)	-- get some columns
-MutableMatrix ^ List := Matrix => (f,v) -> submatrix(f,listZ splice v,) -- get some rows
-submatrix(MutableMatrix,VisibleList,VisibleList) := (m,rows,cols) -> map(ring m,rawSubmatrix(raw m, listZ toList splice rows, listZ toList splice cols))
-submatrix(MutableMatrix,VisibleList            ) := (m,cols     ) -> map(ring m,rawSubmatrix(raw m, listZ toList splice cols))
-submatrix(MutableMatrix,Nothing    ,VisibleList) := (m,null,cols) -> submatrix(m,cols)
-submatrix(MutableMatrix, VisibleList, Nothing)     := (m, rows, null) -> map(ring m, rawSubmatrix(raw m, listZZ rows, 0 .. numColumns m - 1))
-submatrix(MutableMatrix, Nothing,     Nothing)     := (m, null, null) -> m
+MutableMatrix _ List := Matrix => (f,v) -> submatrix(f, v)  -- get some columns
+MutableMatrix ^ List := Matrix => (f,v) -> submatrix(f, v,) -- get some rows
+submatrix(MutableMatrix, VisibleList, VisibleList) := (m, rows, cols) -> submatrixFree(m, rows, cols)
+submatrix(MutableMatrix, VisibleList)              := (m,       cols) -> submatrixFree(m, null, cols)
+submatrix(MutableMatrix, Nothing,     VisibleList) := (m, rows, cols) -> submatrix(m, cols)
+submatrix(MutableMatrix, VisibleList, Nothing)     := (m, rows, cols) -> submatrixFree(m, rows, null)
+submatrix(MutableMatrix, Nothing,     Nothing)     := (m, rows, cols) -> m
 
 --------------------------------
 numRows(RawMutableMatrix) := (m) -> rawNumberOfRows m
@@ -306,6 +306,8 @@ QRDecomposition Matrix := A -> (
      (Q,R) := QRDecomposition A;
      (matrix Q,matrix R))
 
+cover MutableMatrix := MutableMatrix => identity
+
 rank MutableMatrix := (M) -> (
     if isField ring M then
       rawLinAlgRank raw M

M2/Macaulay2/packages/Macaulay2Doc/functions/cover-doc.m2

@@ -8,7 +8,7 @@ document {
      SeeAlso => {"ambient", "super"}}
 
 document {
-     Key => {(cover,Matrix)},
+     Key => {(cover,Matrix), (cover,MutableMatrix)},
      Headline => "get the map between the covering free modules",
      Usage => "cover f",
      Inputs => {"f"},

M2/Macaulay2/tests/normal/mutmat.m2

@@ -72,3 +72,7 @@ assert(ring mutableMatrix(ZZ/101, {{1,2,3}}) === ZZ/101)
 M = mutableMatrix {{1, 2, 3}, {4, 5, 6}}
 assert Equation(target M, ZZ^2)
 assert Equation(source M, ZZ^3)
+
+-- submatrices
+assert Equation(M_{0, -1}, mutableMatrix {{1, 3}, {4, 6}})
+assert Equation(M^{-1}, mutableMatrix {{4, 5, 6}})