Use a “prefixe” before each command executed

[FauveNoir]

In i3 specifically, some apps do not opened in the workspace from whom they were called. It’s a weird behaviour.

So, the solution as described here is still to use exec i3 before the command.

So, it would be useful if shellex allow to define of kind of prefix to execute before each command.

Then the expected behavior would be this one:

1. The user open shellex ;
2. The user type his command randomcommand;
3. shellex execute i3 exec randomcommand.

[pseyfert]

You should be able to configure that on a per-user or per-machine basis in /etc/shellex or $HOME/.shellex. By writing a ZLE widget that adds your prefix and add it to preexec_functions. See also the comment here.

I haven't used ZLE in a while, so i can't write down a working example for you from the top of my head but I'll try to look at it in the coming days.

If you're happy with a bodge you can as well override the default 10-autoexec (either by removing the symbolic link /etc/shellex/10-autoexec, and replacing it by a regular file, or by creating $HOME/.shellex/10-autoexec) with something like the following

function shellex_preexec () {
    # In $1 the command-line is given
    # In $3 the command-line with expanded aliases and function-bodies is given

    i3 exec zsh -c $3 > /dev/null 2>&1 & disown

    exit
}

# We use preexec_functions, so that the user can decide to overwrite our choice
# or ammend it by own functions
preexec_functions=(shellex_preexec)

# preexec doesn't get executed on empty lines, so employ zle to exit on empty lines
# https://www.reddit.com/r/zsh/comments/s6t6d/is_there_an_alias_for_an_empty_line/
function empty-buffer-to-exit() {
    if [[ $#BUFFER == 0 ]]; then
        fc -P
        exit
    fi
}
# set special widget, see man zshzle
zle -N zle-line-finish empty-buffer-to-exit

You see that with respect to the original 10-autoexec I replaced zsh -c $3 by i3 exec zsh -c $3. It's not exactly what you want because I launch a zsh instance with the prefix, and then zsh launches your program. it still does the right thing for prefixes like nice (that's what i experimented with) - i'm not sure if i3 exec will also transparently affect the subprocess of zsh.

Note that I didn't just prepend the prefix to $3 because there might be more going on that just a command call. In the original design of shellex we wanted that a user can type multiple commands, say firefox & thunderbird & pidgin and simply prepending the command would only affect the first entry. Looking at the comments about what $3 and $1 are, we would even need to worry about prepending function definition ….

[pseyfert]

PS: thanks for raising the issue btw.

PPS: similar to what I suggested in #72, if you know you only need the prefix for one or two applications, you might as well create an alias that prefixes those commands. which is especially interesting if you don't want to prefix all commands but just some select few ones.

[pseyfert]

I've looked around a bit. A place where you can edit the executed command line is zle-line-finish, so the function that we already have in 10-autoexec (ie. similar to my previous draft):

...
function empty-buffer-to-exit-and-prefix() {
    if [[ $#BUFFER == 0 ]]; then
        fc -P
        exit
    fi
    BUFFER="i3 exec $BUFFER"
}
# set special widget, see man zshzle
zle -N zle-line-finish empty-buffer-to-exit-and-prefix

What's bad about this approach is that this would add i3 exec xmessage "hello" to the history file if you enter xmessage "hello". so next time you use shellex and hit ↑ shellex would show you i3 exec xmessage "hello"and if you run that, you'd executei3 exec i3 exec xmessage "hello". I guess you could as well check if BUFFER already starts with i3 exec` and only prefix it otherwise. that way at least the prefix chain doesn't grow in the history, when doing history search or hitting arrow-up you'd still see the prefix.
I wonder if asking on the zsh-user mailing list might be worth it - there is certainly more expertise on all the zsh switches.