Experimental artifact promotion task

As part of my efforts to consolidate SharedActions, I've created this
new experimental task to handle artifact promotion. It requies the same
environment variables as before, but it is not automated. To use this,
simply use `gradleutils.pom.promote()` inside of your maven publication.

```gradle
publications.register('pluginMaven', MavenPublication) {
    gradleutils.pom.promote it
    changelog.publish it
    // ...
```

Author: Jonathing

src/main/groovy/net/minecraftforge/gradleutils/GradleUtils.groovy

@@ -40,6 +40,10 @@ class GradleUtils {
             project.afterEvaluate(action)
     }
 
+    static Provider<String> getEnvVar(String name, ProviderFactory providers) {
+        providers.of(GradleUtilsSources.EnvVar) { it.parameters.variableName.set name }
+    }
+
     static Provider<Boolean> hasEnvVar(String name, ProviderFactory providers) {
         providers.of(GradleUtilsSources.HasEnvVar) { it.parameters.variableName.set name }
     }

src/main/groovy/net/minecraftforge/gradleutils/GradleUtilsSources.groovy

@@ -6,10 +6,28 @@ import org.gradle.api.Describable
 import org.gradle.api.provider.Property
 import org.gradle.api.provider.ValueSource
 import org.gradle.api.provider.ValueSourceParameters
+import org.jetbrains.annotations.Nullable
 
 @CompileStatic
 @PackageScope
 final class GradleUtilsSources {
+    @CompileStatic
+    static abstract class EnvVar implements ValueSource<@Nullable String, Parameters>, Describable {
+        interface Parameters extends ValueSourceParameters {
+            Property<String> getVariableName();
+        }
+
+        @Override
+        @Nullable String obtain() {
+            System.getenv(this.parameters.variableName.get())
+        }
+
+        @Override
+        String getDisplayName() {
+            "Environment Variable value: ${this.parameters.variableName.get()}"
+        }
+    }
+
     @CompileStatic
     static abstract class HasEnvVar implements ValueSource<Boolean, Parameters>, Describable {
         interface Parameters extends ValueSourceParameters {

src/main/groovy/net/minecraftforge/gradleutils/PomUtils.groovy

@@ -8,23 +8,27 @@ import groovy.transform.CompileStatic
 import groovy.transform.PackageScope
 import net.minecraftforge.gradleutils.gitversion.GitVersionExtension
 import org.gradle.api.Action
+import org.gradle.api.Project
 import org.gradle.api.logging.Logger
 import org.gradle.api.provider.ProviderFactory
 import org.gradle.api.publish.maven.MavenPom
 import org.gradle.api.publish.maven.MavenPomDeveloper
 import org.gradle.api.publish.maven.MavenPomLicense
+import org.gradle.api.publish.maven.MavenPublication
 
 /** Utilities for making configuring a {@link MavenPom} more ergonomic. */
 @CompileStatic
 @SuppressWarnings('unused')
 final class PomUtils {
+    private final Project project
     private final Logger logger
     private final ProviderFactory providers
 
     private final GitVersionExtension gitversion
 
-    @PackageScope PomUtils(Logger logger, ProviderFactory providers, GitVersionExtension gitversion) {
-        this.logger = logger
+    @PackageScope PomUtils(Project project, ProviderFactory providers, GitVersionExtension gitversion) {
+        this.project = project
+        this.logger = project.logger
         this.providers = providers
         this.gitversion = gitversion
     }
@@ -83,6 +87,10 @@ final class PomUtils {
         }
     }
 
+    void promote(MavenPublication publication) {
+        PromoteArtifact.register(this.project, publication)
+    }
+
     /**
      * Reduces boilerplate when setting up GitHub details in a {@link MavenPom}.
      *

src/main/groovy/net/minecraftforge/gradleutils/PromoteArtifact.groovy

@@ -0,0 +1,109 @@
+package net.minecraftforge.gradleutils
+
+import groovy.json.JsonBuilder
+import groovy.transform.CompileStatic
+import org.gradle.api.DefaultTask
+import org.gradle.api.Project
+import org.gradle.api.provider.Property
+import org.gradle.api.provider.ProviderFactory
+import org.gradle.api.publish.maven.MavenPublication
+import org.gradle.api.tasks.Input
+import org.gradle.api.tasks.Optional
+import org.gradle.api.tasks.TaskAction
+import org.gradle.api.tasks.TaskProvider
+import org.jetbrains.annotations.ApiStatus
+
+import javax.inject.Inject
+import javax.net.ssl.SSLContext
+import java.net.http.HttpClient
+import java.net.http.HttpRequest
+import java.net.http.HttpResponse
+import java.time.Duration
+
+@CompileStatic
+@ApiStatus.Experimental
+abstract class PromoteArtifact extends DefaultTask {
+    static TaskProvider<PromoteArtifact> register(Project project, MavenPublication publication) {
+        project.tasks.register('promoteArtifact', PromoteArtifact) { task ->
+            final webhookURL = GradleUtils.getEnvVar('PROMOTE_ARTIFACT_WEBHOOK', project.providers)
+            final username = GradleUtils.getEnvVar('PROMOTE_ARTIFACT_WEBHOOK', project.providers)
+            final password = GradleUtils.getEnvVar('PROMOTE_ARTIFACT_WEBHOOK', project.providers)
+            task.onlyIf { webhookURL.present && username.present && password.present }
+
+            task.artifactGroup.set publication.groupId
+            task.artifactName.set publication.artifactId
+            task.artifactVersion.set publication.version
+            task.webhookURL.set webhookURL
+            task.username.set username
+            task.password.set password
+        }
+    }
+
+    @Inject
+    abstract ProviderFactory getProviders()
+
+    PromoteArtifact() {
+        this.artifactGroup.convention 'net.minecraftforge'
+        this.artifactName.convention this.providers.provider { this.project.name }
+        this.artifactVersion.convention this.providers.provider { String.valueOf this.project.version }
+        this.promotionType.convention Type.LATEST
+    }
+
+    @Input
+    abstract Property<String> getArtifactGroup()
+
+    @Input
+    abstract Property<String> getArtifactName()
+
+    @Input
+    abstract Property<String> getArtifactVersion()
+
+    @Input
+    @Optional
+    abstract Property<Type> getPromotionType()
+
+    @Input
+    abstract Property<String> getWebhookURL()
+
+    @Input
+    abstract Property<String> getUsername()
+
+    @Input
+    abstract Property<String> getPassword()
+
+    static enum Type {
+        LATEST, RECOMMENDED;
+
+        @Override
+        String toString() {
+            return super.toString().toLowerCase()
+        }
+    }
+
+    @TaskAction
+    void exec() {
+        var client = HttpClient
+            .newBuilder()
+            .sslParameters(SSLContext.default.defaultSSLParameters.tap { protocols = ["TLSv1.3"] })
+            .build()
+
+        var request = HttpRequest
+            .newBuilder()
+            .uri(URI.create(this.webhookURL.get()))
+            .setHeader("Content-Type", 'application/json')
+            .setHeader("Authorization", "Basic ${Base64.getEncoder().encodeToString("${this.username.get()}:${this.password.get()}".getBytes())}")
+            .timeout(Duration.ofSeconds(10))
+            .POST(HttpRequest.BodyPublishers.ofString(new JsonBuilder(
+                group: this.artifactGroup.get(),
+                artifact: this.artifactName.get(),
+                version: this.artifactVersion.get(),
+                type: this.promotionType.getOrElse(Type.LATEST).toString()
+            ).toPrettyString()))
+            .build()
+
+        var response = client.send(request, HttpResponse.BodyHandlers.ofString())
+        if (response.statusCode() != 200) {
+            throw new RuntimeException("Failed to promote artifact: ${response.statusCode()} ${response.body()}")
+        }
+    }
+}