common.prf

# depending on your Qt configuration, you want to enable or disable
# one of the release/debug builds (if all three lines are commented,
# the default of your Qt installation will used)

# build with both debug and release mode
#CONFIG += debug_and_release build_all

# build with release mode only
#CONFIG += release

# build with debug mode only
#CONFIG += debug

# for all debug builds, add "_d" extension to target
CONFIG(debug, debug|release) {
  TARGET = $${TARGET}_d 
}

isEmpty(DESTDIR) {
  isEmpty(GLOBAL_DESTDIR): DESTDIR = $$PWD/../bin
  !isEmpty(GLOBAL_DESTDIR): DESTDIR = $$GLOBAL_DESTDIR
}

# Allow override (e.g., qmake PYTHONQT_GENERATED_PATH=/abs/path)
isEmpty(PYTHONQT_GENERATED_PATH) {
  PYTHONQT_GENERATED_PATH = $$PWD/../generated_cpp
}

# Fallbacks to checked-in wrappers
!exists($$PYTHONQT_GENERATED_PATH) {
  # If no files are generated, try the checked-in wrappers:
  PYTHONQT_GENERATED_PATH = $$PWD/../generated_cpp_$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}

  !exists($$PYTHONQT_GENERATED_PATH) {
    PYTHONQT_GENERATED_PATH = $$PWD/../generated_cpp_$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}
  }
}

!exists($$PYTHONQT_GENERATED_PATH) {
  error("No generated wrapper sources for Qt $${QT_VERSION}.\n" \
        "Looked in:\n" \
        "  - $$PWD/../generated_cpp\n" \
	"  - $$PWD/../generated_cpp_$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION} (e.g., generated_cpp_5.15)\n" \
        "Generate them first:\n" \
        "  qmake CONFIG+=generator_only && make\n" \
        "  cd generator && ./pythonqt_generator\n" \
        "Or pass an explicit path:\n" \
        "  qmake PYTHONQT_GENERATED_PATH=/abs/path")
}

!build_pass {
  message("Qt version: Qt$${QT_VERSION}")
  message("Using generated sources files from $${PYTHONQT_GENERATED_PATH}")
}

VERSION = 3.2.0
greaterThan(QT_MAJOR_VERSION, 5) | greaterThan(QT_MINOR_VERSION, 9): CONFIG += c++17 c++11
win32: CONFIG += skip_target_version_ext
gcc|win32-clang-msvc:QMAKE_CXXFLAGS += -Wno-deprecated-declarations -Wuninitialized -Winit-self -pedantic
win32-clang-msvc:QMAKE_CXXFLAGS += -Wno-unused-command-line-argument
#Do not issue warning to system includes
gcc:!isEmpty(QT_INSTALL_HEADERS): QMAKE_CXXFLAGS += -isystem $$[QT_INSTALL_HEADERS]