Add auto configuration mode (emacs-lsp#277)

* Add auto configuration mode

* Change docs

* Fix dap-ui-mode disable

Co-authored-by: kiennq <[email protected]>

* Fix dap-ui-controls-mode disable

Co-authored-by: kiennq <[email protected]>

* Add option to specify which features to enable

* Remove debug message

* Add tags to choices on defcustom

* Minor adjustments

* Rename consts

* Add mode for show and hide windows

* Fix docs

* Move to minor mode hooks

Co-authored-by: kiennq <[email protected]>

Author: ericdallo

dap-mode.el

@@ -137,8 +137,31 @@ The hook will be called with the session file and the new set of breakpoint loca
 (defcustom dap-debug-template-configurations nil
   "Plist Template configurations for DEBUG/RUN."
   :safe #'listp
+  :group 'dap-mode
   :type '(plist))
 
+(defcustom dap-auto-configure-features '(sessions locals breakpoints expressions controls tooltip)
+  "Windows to auto show on debugging when in dap-ui-auto-configure-mode."
+  :group 'dap-mode
+  :type '(set (const :tag "Show sessions popup window when debugging and enable `dap-ui-sessions-mode`" sessions)
+              (const :tag "Show locals popup window when debugging" locals)
+              (const :tag "Show breakpoints popup window when debugging and enable `dap-ui-breakpoints-mode`" breakpoints)
+              (const :tag "Show expressions popup window when debugging" expressions)
+              (const :tag "Enable `dap-ui-controls-mode` with controls to manage the debug session when debugging" controls)
+              (const :tag "Enable `dap-tooltip-mode` that enables mouse hover support when debugging" tooltip)))
+
+(defconst dap-features->windows
+  '((sessions . (dap-ui-sessions . dap-ui--sessions-buffer))
+    (locals . (dap-ui-locals . dap-ui--locals-buffer))
+    (breakpoints . (dap-ui-breakpoints . dap-ui--breakpoints-buffer))
+    (expressions . (dap-ui-expressions . dap-ui--expressions-buffer))))
+
+(defconst dap-features->modes
+  '((sessions . dap-ui-sessions-mode)
+    (breakpoints . dap-ui-breakpoints-mode)
+    (controls . (dap-ui-controls-mode . posframe))
+    (tooltip . dap-tooltip-mode)))
+
 (defvar dap--debug-configuration nil
   "List of the previous configuration that have been executed.")
 
@@ -1598,6 +1621,36 @@ point is set."
   (interactive)
   (dap-mode t))
 
+
+;; Auto configure
+
+;;;###autoload
+(define-minor-mode dap-auto-configure-mode
+  "Auto configure dap minor mode."
+  :init-value nil
+  :global t
+  :group 'dap-mode
+  (cond
+   (dap-auto-configure-mode
+    (dap-mode 1)
+    (dap-ui-mode 1)
+    (seq-doseq (feature dap-auto-configure-features)
+      (when-let (mode (alist-get feature dap-features->modes))
+        (if (consp mode)
+            (when (require (cdr mode) nil t)
+              (funcall (car mode) 1))
+            (funcall mode 1))))
+    (dap-ui-many-windows-mode 1))
+   (t
+    (dap-mode -1)
+    (dap-ui-mode -1)
+    (seq-doseq (feature dap-auto-configure-features)
+      (when-let (mode (alist-get feature dap-features->modes))
+        (if (consp mode)
+            (funcall (car mode) -1)
+            (funcall mode -1))))
+    (dap-ui-many-windows-mode -1))))
+
 (provide 'dap-mode)
 ;;; dap-mode.el ends here
 

dap-ui.el

@@ -1076,7 +1076,7 @@ DEBUG-SESSION is the debug session triggering the event."
     (define-key (kbd "C L") #'dap-ui-breakpoint-log-message)))
 
 (define-minor-mode dap-ui-breakpoints-mode
-  "UI Session list minor mode."
+  "UI Breakpoints list minor mode."
   :init-value nil
   :group dap-ui
   :keymap dap-ui-breakpoints-mode-map)
@@ -1109,5 +1109,42 @@ DEBUG-SESSION is the debug session triggering the event."
   (add-hook 'dap-breakpoints-changed-hook #'dap-ui-breakpoints--refresh)
   (add-hook 'kill-buffer-hook 'dap-ui-breakpoints--cleanup-hooks nil t))
 
+(defun dap-ui--show-many-windows (_session)
+  "Show auto configured feature windows."
+  (seq-doseq (feature-start-stop dap-auto-configure-features)
+    (when-let (start-stop (alist-get feature-start-stop dap-features->windows))
+      (funcall (car start-stop)))))
+
+(defun dap-ui--hide-many-windows (_session)
+  "Hide all debug windows when sessions are dead."
+  (seq-doseq (feature-start-stop dap-auto-configure-features)
+    (-when-let* ((feature-start-stop (alist-get feature-start-stop dap-features->windows))
+                 (buffer-name (symbol-value (cdr feature-start-stop))))
+      (and (get-buffer buffer-name)
+           (kill-buffer buffer-name)))))
+
+;;;###autoload
+(defun dap-ui-show-many-windows ()
+  "Show auto configured feature windows."
+  (interactive)
+  (dap-ui--show-many-windows nil))
+
+;;;###autoload
+(defun dap-ui-hide-many-windows ()
+  "Hide all debug windows when sessions are dead."
+  (interactive)
+  (dap-ui--hide-many-windows nil))
+
+(define-minor-mode dap-ui-many-windows-mode
+  "Shows/hide the windows from `dap-auto-configure-features`"
+  :global t
+  (cond
+   (dap-ui-many-windows-mode
+    (add-hook 'dap-stopped-hook #'dap-ui--show-many-windows)
+    (add-hook 'dap-terminated-hook #'dap-ui--hide-many-windows))
+   (t
+    (remove-hook 'dap-stopped-hook #'dap-ui--show-many-windows)
+    (remove-hook 'dap-terminated-hook #'dap-ui--hide-many-windows))))
+
 (provide 'dap-ui)
 ;;; dap-ui.el ends here

docs/page/configuration.md

@@ -3,11 +3,20 @@ Configuration
 
 ## DAP mode configuration
 
-Enable both `dap-mode` and `dap-ui-mode` (requires posframe to be
-installed manually, available only for emacs version \>= 26).
+For an auto-configuration enable the `dap-auto-configure-mode`. You can configure which features from `dap-mode` do you want with `dap-auto-configure-features`:
 
-``` elisp
+```elisp
+;; Enabling only some features
+(setq dap-auto-configure-features '(sessions locals controls tooltip))
+```
+
+Or if you want to enable only specific modes instead:
+
+```elisp
 (dap-mode 1)
+
+;; The modes above are optional
+
 (dap-ui-mode 1)
 ;; enables mouse hover support
 (dap-tooltip-mode 1)

docs/page/how-to.md

@@ -1,41 +1,6 @@
 How to
 ======
 
-## Display debug windows on session startup
-
-Here it is a code that can be used to automatically display/hide debug windows.
-
-```elisp
-(defun my/window-visible (b-name)
-  "Return whether B-NAME is visible."
-  (-> (-compose 'buffer-name 'window-buffer)
-      (-map (window-list))
-      (-contains? b-name)))
-
-(defun my/show-debug-windows (session)
-  "Show debug windows."
-  (let ((lsp--cur-workspace (dap--debug-session-workspace session)))
-    (save-excursion
-      ;; display locals
-      (unless (my/window-visible dap-ui--locals-buffer)
-        (dap-ui-locals))
-      ;; display sessions
-      (unless (my/window-visible dap-ui--sessions-buffer)
-        (dap-ui-sessions)))))
-
-(add-hook 'dap-stopped-hook 'my/show-debug-windows)
-
-(defun my/hide-debug-windows (session)
-  "Hide debug windows when all debug sessions are dead."
-  (unless (-filter 'dap--session-running (dap--get-sessions))
-    (and (get-buffer dap-ui--sessions-buffer)
-         (kill-buffer dap-ui--sessions-buffer))
-    (and (get-buffer dap-ui--locals-buffer)
-         (kill-buffer dap-ui--locals-buffer))))
-
-(add-hook 'dap-terminated-hook 'my/hide-debug-windows)
-```
-
 ## Activate minor modes when stepping through code
 
 You may want to activate minor modes, e.g. `read-only-mode`, when the debugger is active in a buffer. If so, you could use a trick like this: