Adds an industrial centrifuge to replace the honey extractor.

Author: MistakeNot4892

code/game/machinery/centrifuge.dm

@@ -0,0 +1,171 @@
+/datum/storage/hopper/industrial/centrifuge
+	can_hold = list(
+		/obj/item/food,
+		/obj/item/honey_frame
+	)
+	expected_type = /obj/machinery/centrifuge
+
+/datum/storage/hopper/industrial/centrifuge/can_be_inserted(obj/item/W, mob/user, stop_messages, click_params)
+	. = ..()
+	if(. && !W.reagents?.total_volume)
+		if(user)
+			to_chat(user, SPAN_WARNING("\The [W] is empty."))
+		return FALSE
+
+/obj/machinery/centrifuge
+	name = "industrial centrifuge"
+	desc = "A machine used to extract reagents and materials from objects via spinning them at extreme speed."
+	icon = 'icons/obj/machines/centrifuge.dmi'
+	icon_state = ICON_STATE_WORLD
+	anchored = TRUE
+	density = TRUE
+	construct_state = /decl/machine_construction/default/panel_closed
+	uncreated_component_parts = null
+	storage = /datum/storage/hopper/industrial/centrifuge
+	base_type = /obj/machinery/centrifuge
+	stat_immune = 0
+
+	// Reference to our reagent container. Set to a path to create on init.
+	var/obj/item/loaded_beaker
+
+	// Stolen from fabricators.
+	var/sound_id
+	var/datum/sound_token/sound_token
+	var/work_sound = 'sound/machines/fabricator_loop.ogg'
+
+/obj/machinery/centrifuge/mapped
+	loaded_beaker = /obj/item/chems/glass/beaker/large
+
+/obj/machinery/centrifuge/Initialize()
+	. = ..()
+	if(ispath(loaded_beaker))
+		loaded_beaker = new loaded_beaker
+
+/obj/machinery/centrifuge/Destroy()
+	QDEL_NULL(loaded_beaker)
+	return ..()
+
+/obj/machinery/centrifuge/dismantle()
+	if(loaded_beaker)
+		loaded_beaker.dropInto(loc)
+		loaded_beaker = null
+	return ..()
+
+/obj/machinery/centrifuge/components_are_accessible(path)
+	return use_power != POWER_USE_ACTIVE && ..()
+
+/obj/machinery/centrifuge/cannot_transition_to(state_path, mob/user)
+	if(use_power == POWER_USE_ACTIVE)
+		return SPAN_NOTICE("You must wait for \the [src] to finish first!")
+	return ..()
+
+/obj/machinery/centrifuge/attackby(obj/item/used_item, mob/user)
+
+	if(use_power == POWER_USE_ACTIVE)
+		to_chat(user, SPAN_NOTICE("\The [src] is currently spinning, wait until it's finished."))
+		return TRUE
+
+	if((. = component_attackby(used_item, user)))
+		return
+
+	// Load in a new container for products.
+	if(istype(used_item, /obj/item/chems/glass/beaker))
+		if(loaded_beaker)
+			to_chat(user, SPAN_WARNING("\The [src] already has a beaker loaded."))
+			return TRUE
+		if(user.try_unequip(used_item, src))
+			loaded_beaker = used_item
+			to_chat(user, SPAN_NOTICE("You load \the [loaded_beaker] into \the [src]."))
+		return TRUE
+
+	// Parent call handles inserting the frame into our contents,
+	return ..()
+
+/obj/machinery/centrifuge/attack_hand(mob/user)
+
+	if(use_power == POWER_USE_ACTIVE)
+		user.visible_message("\The [user] disengages \the [src].")
+		update_use_power(POWER_USE_IDLE)
+		return TRUE
+
+	if(use_power == POWER_USE_IDLE)
+		if(!loaded_beaker || QDELETED(loaded_beaker))
+			to_chat(user, SPAN_WARNING("\The [src] has no beaker loaded to receive any products."))
+			loaded_beaker = null // just in case
+			return TRUE
+
+		if(length(get_stored_inventory()))
+			user.visible_message("\The [user] engages \the [src].")
+			update_use_power(POWER_USE_ACTIVE)
+		else
+			to_chat(user, SPAN_WARNING("\The [src]'s hopper is empty."))
+		return TRUE
+
+	if(use_power == POWER_USE_OFF || !operable())
+		to_chat(user, SPAN_WARNING("\The [src]'s interface is unresponsive."))
+		return TRUE
+
+	return ..()
+
+/obj/machinery/centrifuge/Process(wait, tick)
+	..()
+
+	if(use_power != POWER_USE_ACTIVE)
+		return
+
+	if(!loaded_beaker)
+		visible_message("\The [src] stops spinning and flashes a red light.")
+		update_use_power(POWER_USE_IDLE)
+		return
+
+	var/list/processing_items = get_stored_inventory()
+	if(!length(processing_items))
+		visible_message("\The [src] stops spinning and flashes a green light.")
+		update_use_power(POWER_USE_IDLE)
+		return
+
+	var/obj/item/thing = processing_items[1]
+	thing.handle_centrifuge_process(src)
+	if(!QDELETED(thing) && loc)
+		thing.dropInto(loc)
+
+/obj/machinery/centrifuge/Initialize()
+	sound_id = "[work_sound]"
+	return ..()
+
+/obj/machinery/centrifuge/Destroy()
+	QDEL_NULL(sound_token)
+	return ..()
+
+/obj/machinery/centrifuge/update_use_power()
+	. = ..()
+	if(use_power == POWER_USE_ACTIVE)
+		if(!sound_token)
+			sound_token = play_looping_sound(src, sound_id, work_sound, volume = 30)
+	else
+		QDEL_NULL(sound_token)
+
+/obj/machinery/centrifuge/on_update_icon()
+	icon_state = initial(icon_state)
+	if(stat & BROKEN)
+		icon_state = "[icon_state]-broken"
+	else if(use_power == POWER_USE_OFF || !operable())
+		icon_state = "[icon_state]-off"
+	else if(use_power == POWER_USE_ACTIVE)
+		icon_state = "[icon_state]-working"
+
+/obj/machinery/centrifuge/get_alt_interactions(var/mob/user)
+	. = ..()
+	if(loaded_beaker)
+		LAZYADD(., list(/decl/interaction_handler/remove_centrifuge_beaker))
+
+/decl/interaction_handler/remove_centrifuge_beaker
+	name = "Remove Beaker"
+	expected_target_type = /obj/machinery/centrifuge
+
+/decl/interaction_handler/remove_centrifuge_beaker/invoked(atom/target, mob/user, obj/item/prop)
+	var/obj/machinery/centrifuge/centrifuge = target
+	if(centrifuge.loaded_beaker)
+		centrifuge.loaded_beaker.dropInto(centrifuge.loc)
+		user.put_in_hands(centrifuge.loaded_beaker)
+		centrifuge.loaded_beaker = null

code/game/objects/items/__item.dm

@@ -1320,3 +1320,34 @@ modules/mob/living/human/life.dm if you die, you will be zoomed out.
 			coating_string = FONT_COLORED(coating.get_color(), coating_string)
 		return coating_string
 	return ..()
+
+// Bespoke proc for handling when a centrifuge smooshes us, only currently used by growns and hive frames.
+/obj/item/proc/handle_centrifuge_process(obj/machinery/centrifuge/centrifuge)
+	SHOULD_CALL_PARENT(TRUE)
+	return istype(centrifuge) && !QDELETED(centrifuge.loaded_beaker) && istype(centrifuge.loaded_beaker)
+
+/obj/item/proc/convert_matter_to_lumps(skip_qdel = FALSE)
+
+	var/list/scrap_matter = list()
+	for(var/mat in matter)
+		var/mat_amount = matter[mat]
+		var/obj/item/stack/material/mat_stack = /obj/item/stack/material/lump
+		var/mat_per_stack = SHEET_MATERIAL_AMOUNT * initial(mat_stack.matter_multiplier)
+		var/sheet_amount  = round(mat_amount / mat_per_stack)
+		if(sheet_amount)
+			var/obj/item/stack/material/lump/lump = new(loc, sheet_amount, mat)
+			LAZYADD(., lump)
+			mat_amount -= sheet_amount * mat_per_stack
+		if(mat_amount)
+			scrap_matter[mat] += mat_amount
+
+	if(length(scrap_matter))
+		var/obj/item/debris/scraps/scraps = new(loc)
+		scraps.matter = scrap_matter.Copy()
+		scraps.update_primary_material()
+		LAZYADD(., scraps)
+
+	matter = null
+	material = null
+	if(!skip_qdel)
+		qdel(src)

code/game/objects/items/circuitboards/machinery/household.dm

@@ -46,19 +46,24 @@
 /obj/item/stock_parts/circuitboard/cooker/get_buildable_types()
 	return subtypesof(/obj/machinery/cooker)
 
-/obj/item/stock_parts/circuitboard/honey
-	name = "circuitboard (honey extractor)"
-	build_path = /obj/machinery/honey_extractor
+/obj/item/stock_parts/circuitboard/centrifuge
+	name = "circuitboard (industrial centrifuge)"
+	build_path = /obj/machinery/centrifuge
 	board_type = "machine"
 	origin_tech = @'{"biotech":2,"engineering":1}'
 	req_components = list(
 		/obj/item/stock_parts/manipulator = 2,
 		/obj/item/stock_parts/matter_bin = 2)
 
-/obj/item/stock_parts/circuitboard/honey/seed
+/obj/item/stock_parts/circuitboard/seed_extractor
 	name = "circuitboard (seed extractor)"
 	build_path = /obj/machinery/seed_extractor
 	board_type = "machine"
+	origin_tech = @'{"biotech":2,"engineering":1}'
+	req_components = list(
+		/obj/item/stock_parts/manipulator = 2,
+		/obj/item/stock_parts/matter_bin = 2
+	)
 
 /obj/item/stock_parts/circuitboard/seed_storage
 	name = "circuitboard (seed storage)"

code/modules/fabrication/designs/imprinter/designs_misc_circuits.dm

@@ -344,11 +344,11 @@
 /datum/fabricator_recipe/imprinter/circuit/cooker
 	path = /obj/item/stock_parts/circuitboard/cooker
 
-/datum/fabricator_recipe/imprinter/circuit/honey_extractor
-	path = /obj/item/stock_parts/circuitboard/honey
+/datum/fabricator_recipe/imprinter/circuit/centrifuge
+	path = /obj/item/stock_parts/circuitboard/centrifuge
 
 /datum/fabricator_recipe/imprinter/circuit/seed_extractor
-	path = /obj/item/stock_parts/circuitboard/honey/seed
+	path = /obj/item/stock_parts/circuitboard/seed_extractor
 
 /datum/fabricator_recipe/imprinter/circuit/vending
 	path = /obj/item/stock_parts/circuitboard/vending

code/modules/hydroponics/beekeeping/beehive.dm

@@ -165,60 +165,6 @@
 			++trays
 	honeycombs = min(honeycombs + 0.1 * coef * min(trays, 5), frames * 100)
 
-/obj/machinery/honey_extractor
-	name = "honey extractor"
-	desc = "A machine used to extract honey and wax from a beehive frame."
-	icon = 'icons/obj/virology.dmi'
-	icon_state = "centrifuge"
-	anchored = TRUE
-	density = TRUE
-	construct_state = /decl/machine_construction/default/panel_closed
-	uncreated_component_parts = null
-	stat_immune = 0
-
-	var/processing = 0
-	var/honey = 0
-
-/obj/machinery/honey_extractor/components_are_accessible(path)
-	return !processing && ..()
-
-/obj/machinery/honey_extractor/cannot_transition_to(state_path, mob/user)
-	if(processing)
-		return SPAN_NOTICE("You must wait for \the [src] to finish first!")
-	return ..()
-
-/obj/machinery/honey_extractor/attackby(var/obj/item/I, var/mob/user)
-	if(processing)
-		to_chat(user, "<span class='notice'>\The [src] is currently spinning, wait until it's finished.</span>")
-		return TRUE
-	if(istype(I, /obj/item/honey_frame))
-		var/obj/item/honey_frame/H = I
-		if(!H.honey)
-			to_chat(user, "<span class='notice'>\The [H] is empty, put it into a beehive.</span>")
-			return TRUE
-		user.visible_message("<span class='notice'>\The [user] loads \the [H] into \the [src] and turns it on.</span>", "<span class='notice'>You load \the [H] into \the [src] and turn it on.</span>")
-		processing = H.honey
-		icon_state = "centrifuge_moving"
-		qdel(H)
-		spawn(50)
-			new /obj/item/honey_frame(loc)
-			new /obj/item/stack/material/bar/wax(loc, 1)
-			honey += processing
-			processing = 0
-			icon_state = "centrifuge"
-		return TRUE
-	else if(istype(I, /obj/item/chems/glass))
-		if(!honey)
-			to_chat(user, "<span class='notice'>There is no honey in \the [src].</span>")
-			return TRUE
-		var/obj/item/chems/glass/G = I
-		var/transferred = min(G.reagents.maximum_volume - G.reagents.total_volume, honey)
-		G.add_to_reagents(/decl/material/liquid/nutriment/honey, transferred)
-		honey -= transferred
-		user.visible_message("<span class='notice'>\The [user] collects honey from \the [src] into \the [G].</span>", "<span class='notice'>You collect [transferred] units of honey from \the [src] into \the [G].</span>")
-		return TRUE
-	return ..() // smack it, interact with components, etc.
-
 /obj/item/bee_smoker
 	name = "bee smoker"
 	desc = "A device used to calm down bees before harvesting honey."
@@ -236,6 +182,16 @@
 	material = /decl/material/solid/organic/wood/oak
 	var/honey = 0
 
+// This is crap, will be replaced in beewrite PR.
+/obj/item/honey_frame/handle_centrifuge_process(obj/machinery/centrifuge/centrifuge)
+	if(!(. = ..()) || !honey)
+		return
+	centrifuge?.loaded_beaker?.add_to_reagents(/decl/material/liquid/nutriment/honey, honey)
+	honey = 0
+	new /obj/item/honey_frame(centrifuge.loc)
+	new /obj/item/stack/material/bar(centrifuge.loc, 1, /decl/material/solid/organic/wax)
+	qdel(src)
+
 /obj/item/honey_frame/filled
 	name = "filled beehive frame"
 	desc = "A frame for the beehive that the bees have filled with honeycombs."

code/modules/hydroponics/grown.dm

@@ -15,6 +15,18 @@
 	var/seeds_extracted = FALSE
 	var/datum/seed/seed
 
+// This is sort of pointless while food is a valid input on the ChemMaster but maybe
+// in the future there will be some more interesting ways to process growns/food.
+/obj/item/food/grown/handle_centrifuge_process(obj/machinery/centrifuge/centrifuge)
+	if(!(. = ..()))
+		return
+	if(reagents?.total_volume)
+		reagents.trans_to_holder(centrifuge.loaded_beaker.reagents, reagents.total_volume)
+	for(var/obj/item/thing in contents)
+		thing.dropInto(centrifuge.loc)
+	for(var/atom/movable/thing in convert_matter_to_lumps())
+		thing.dropInto(centrifuge.loc)
+
 /obj/item/food/grown/examine(mob/user, distance)
 	. = ..()
 	if(user && distance <= 1 && seed && user.skill_check(work_skill, SKILL_BASIC))

code/modules/materials/definitions/liquids/materials_liquid_toxins.dm

@@ -65,7 +65,7 @@
 	name = "spider venom"
 	uid = "liquid_spider_venom"
 	lore_text = "A deadly necrotic toxin produced by giant spiders to disable their prey."
-	taste_description = "absolutely vile"
+	taste_description = "vile poison"
 	color = "#91d895"
 	toxicity_targets_organ = BP_LIVER
 	toxicity = 5

icons/obj/machines/centrifuge.dmi

@@ -26489,7 +26489,7 @@
 	pixel_x = -21;
 	pixel_y = -10
 	},
-/obj/machinery/honey_extractor,
+/obj/machinery/centrifuge/mapped,
 /turf/floor/tiled/steel_grid,
 /area/exodus/hydroponics/garden)
 "bev" = (

maps/exodus/exodus-2.dmm

@@ -6040,7 +6040,7 @@
 "zj" = (
 /obj/effect/floor_decal/corner/beige/half,
 /obj/structure/table/glass,
-/obj/machinery/honey_extractor,
+/obj/machinery/centrifuge/mapped,
 /turf/floor/tiled,
 /area/ministation/hydro)
 "zl" = (