Clean up gravity generator code

Author: out-of-phaze

code/game/area/areas.dm

@@ -412,14 +412,30 @@ var/global/list/mob/living/forced_ambiance_list = new
 		sound_to(L, sound(null, channel = sound_channels.lobby_channel))
 		forced_ambiance_list -= L
 
-/area/proc/gravitychange(var/gravitystate = 0)
+/area/proc/gravitychange(gravitystate = 0, skip_thunk = FALSE)
 	has_gravity = gravitystate
-
+	if(skip_thunk)
+		// For mass-area-gravity-modification where it might be more efficient to loop over mobs manually after.
+		return
 	for(var/mob/M in src)
 		if(has_gravity)
 			thunk(M)
 		M.update_floating()
 
+/proc/mass_gravitychange(list/areas_to_change, gravitystate = 0)
+	var/list/lookup_list = new /list(length(areas_to_change))
+	for(var/area/changing_area in areas_to_change)
+		changing_area.gravitychange(gravitystate = gravitystate, skip_thunk = TRUE)
+		lookup_list[changing_area] = TRUE // for faster membership checks
+	// thunks do literally nothing for non-human mobs, but we'll be future-proof and do all living mobs
+	for(var/mob/living/victim in global.living_mob_list_)
+		var/area/victim_area = get_area(victim)
+		if(!lookup_list[victim_area])
+			continue
+		if(victim_area.has_gravity)
+			victim_area.thunk(victim)
+		victim.update_floating()
+
 /area/proc/thunk(mob/mob)
 	if(isspaceturf(get_turf(mob))) // Can't fall onto nothing.
 		return

code/modules/power/gravitygenerator.dm

@@ -1,24 +1,23 @@
-// It... uses a lot of power.  Everything under power is engineering stuff, at least.
-
 /obj/machinery/computer/gravity_control_computer
-	name = "Gravity Generator Control"
-	desc = "A computer to control a local gravity generator.  Qualified personnel only."
+	name = "gravity generator control computer"
+	desc = "A computer to control a local gravity generator. Qualified personnel only."
 	icon = 'icons/obj/computer.dmi'
 	icon_state = "airtunnel0e"
 	anchored = TRUE
 	density = TRUE
 	var/obj/machinery/gravity_generator/gravity_generator
 
-/obj/machinery/gravity_generator/
-	name = "Gravitational Generator"
+// Wait. This isn't even used anywhere?
+/obj/machinery/gravity_generator
+	name = "gravitational generator"
 	desc = "A device which produces a graviton field when set up."
 	icon = 'icons/obj/singularity.dmi'
 	icon_state = "TheSingGen"
 	anchored = TRUE
 	density = TRUE
 	idle_power_usage = 200
 	active_power_usage = 1000
-	var/on = 1
+	var/on = TRUE
 	var/list/localareas = list()
 	var/effectiverange = 25
 
@@ -32,14 +31,14 @@
 	locatelocalareas()
 
 /obj/machinery/computer/gravity_control_computer/proc/updatemodules()
-	for(dir in list(NORTH,EAST,SOUTH,WEST))
-		gravity_generator = locate(/obj/machinery/gravity_generator/, get_step(src, dir))
-		if (gravity_generator)
+	for(var/check_dir in global.cardinal)
+		gravity_generator = locate(/obj/machinery/gravity_generator, get_step(src, check_dir))
+		if(gravity_generator)
 			return
 
 /obj/machinery/gravity_generator/proc/locatelocalareas()
 	for(var/area/A in range(src,effectiverange))
-		if(istype(A,/area/space))
+		if(istype(A,/area/space)) // todo: un-hardcode this
 			continue // No (de)gravitizing space.
 		localareas |= A
 
@@ -85,25 +84,23 @@
 	onclose(user, "gravgen")
 
 
+/obj/machinery/gravity_generator/proc/toggle_gravity()
+	on = !on
+	update_use_power(on ? POWER_USE_ACTIVE : POWER_USE_IDLE)
+	if(on)
+		mass_gravitychange(localareas, TRUE)
+	else
+		var/list/still_covered_areas = list()
+		// We do it this way to avoid nested loops, and also because gravity generators are relatively rare.
+		for(var/obj/machinery/gravity_generator/other_generator in SSmachines.machinery)
+			if(other_generator.on)
+				still_covered_areas |= localareas & other_generator.localareas
+		mass_gravitychange(localareas - still_covered_areas, FALSE)
+
 /obj/machinery/computer/gravity_control_computer/OnTopic(user, href_list)
 	if((. = ..()))
 		return
 
 	if(href_list["gentoggle"])
 		. = TOPIC_REFRESH
-		if(gravity_generator.on)
-			gravity_generator.on = 0
-
-			for(var/area/A in gravity_generator.localareas)
-				var/obj/machinery/gravity_generator/G
-				for(G in SSmachines.machinery)
-					if((A in G.localareas) && (G.on))
-						break
-				if(!G)
-					A.gravitychange(0)
-				CHECK_TICK
-		else
-			for(var/area/A in gravity_generator.localareas)
-				gravity_generator.on = 1
-				A.gravitychange(1)
-				CHECK_TICK
+		gravity_generator.toggle_gravity()