|
| 1 | +#[starknet::contract] |
| 2 | +pub mod ERC721 { |
| 3 | + use core::num::traits::Zero; |
| 4 | + use starknet::get_caller_address; |
| 5 | + use starknet::ContractAddress; |
| 6 | + use starknet::storage::{Map, StorageMapReadAccess, StorageMapWriteAccess}; |
| 7 | + use openzeppelin_introspection::interface::{ISRC5Dispatcher, ISRC5DispatcherTrait}; |
| 8 | + use erc721::interfaces::{ |
| 9 | + IERC721, IERC721ReceiverDispatcher, IERC721ReceiverDispatcherTrait, IERC721_RECEIVER_ID, |
| 10 | + IERC721Mintable, IERC721Burnable, |
| 11 | + }; |
| 12 | + |
| 13 | + #[storage] |
| 14 | + pub struct Storage { |
| 15 | + pub owners: Map<u256, ContractAddress>, |
| 16 | + pub balances: Map<ContractAddress, u256>, |
| 17 | + pub approvals: Map<u256, ContractAddress>, |
| 18 | + pub operator_approvals: Map<(ContractAddress, ContractAddress), bool>, |
| 19 | + } |
| 20 | + |
| 21 | + #[event] |
| 22 | + #[derive(Drop, starknet::Event)] |
| 23 | + pub enum Event { |
| 24 | + Transfer: Transfer, |
| 25 | + Approval: Approval, |
| 26 | + ApprovalForAll: ApprovalForAll, |
| 27 | + } |
| 28 | + |
| 29 | + #[derive(Drop, starknet::Event)] |
| 30 | + pub struct Transfer { |
| 31 | + pub from: ContractAddress, |
| 32 | + pub to: ContractAddress, |
| 33 | + pub token_id: u256, |
| 34 | + } |
| 35 | + |
| 36 | + #[derive(Drop, starknet::Event)] |
| 37 | + pub struct Approval { |
| 38 | + pub owner: ContractAddress, |
| 39 | + pub approved: ContractAddress, |
| 40 | + pub token_id: u256, |
| 41 | + } |
| 42 | + |
| 43 | + #[derive(Drop, starknet::Event)] |
| 44 | + pub struct ApprovalForAll { |
| 45 | + pub owner: ContractAddress, |
| 46 | + pub operator: ContractAddress, |
| 47 | + pub approved: bool, |
| 48 | + } |
| 49 | + |
| 50 | + pub mod Errors { |
| 51 | + pub const INVALID_TOKEN_ID: felt252 = 'ERC721: invalid token ID'; |
| 52 | + pub const INVALID_ACCOUNT: felt252 = 'ERC721: invalid account'; |
| 53 | + pub const INVALID_OPERATOR: felt252 = 'ERC721: invalid operator'; |
| 54 | + pub const UNAUTHORIZED: felt252 = 'ERC721: unauthorized caller'; |
| 55 | + pub const INVALID_RECEIVER: felt252 = 'ERC721: invalid receiver'; |
| 56 | + pub const INVALID_SENDER: felt252 = 'ERC721: invalid sender'; |
| 57 | + pub const SAFE_TRANSFER_FAILED: felt252 = 'ERC721: safe transfer failed'; |
| 58 | + pub const ALREADY_MINTED: felt252 = 'ERC721: token already minted'; |
| 59 | + } |
| 60 | + |
| 61 | + #[abi(embed_v0)] |
| 62 | + impl ERC721 of IERC721<ContractState> { |
| 63 | + fn owner_of(self: @ContractState, token_id: u256) -> ContractAddress { |
| 64 | + self._require_owned(token_id) |
| 65 | + } |
| 66 | + |
| 67 | + fn balance_of(self: @ContractState, owner: ContractAddress) -> u256 { |
| 68 | + assert(!owner.is_zero(), Errors::INVALID_ACCOUNT); |
| 69 | + self.balances.read(owner) |
| 70 | + } |
| 71 | + |
| 72 | + fn set_approval_for_all( |
| 73 | + ref self: ContractState, operator: ContractAddress, approved: bool, |
| 74 | + ) { |
| 75 | + assert(!operator.is_zero(), Errors::INVALID_OPERATOR); |
| 76 | + let owner = get_caller_address(); |
| 77 | + self.operator_approvals.write((owner, operator), approved); |
| 78 | + self.emit(ApprovalForAll { owner, operator, approved }); |
| 79 | + } |
| 80 | + |
| 81 | + fn approve(ref self: ContractState, approved: ContractAddress, token_id: u256) { |
| 82 | + let owner = self._require_owned(token_id); |
| 83 | + let caller = get_caller_address(); |
| 84 | + assert( |
| 85 | + caller == owner || self.is_approved_for_all(owner, caller), Errors::UNAUTHORIZED, |
| 86 | + ); |
| 87 | + |
| 88 | + self.approvals.write(token_id, approved); |
| 89 | + self.emit(Approval { owner, approved, token_id }); |
| 90 | + } |
| 91 | + |
| 92 | + fn get_approved(self: @ContractState, token_id: u256) -> ContractAddress { |
| 93 | + self._require_owned(token_id); |
| 94 | + self.approvals.read(token_id) |
| 95 | + } |
| 96 | + |
| 97 | + fn transfer_from( |
| 98 | + ref self: ContractState, from: ContractAddress, to: ContractAddress, token_id: u256, |
| 99 | + ) { |
| 100 | + let previous_owner = self._require_owned(token_id); |
| 101 | + assert(from == previous_owner, Errors::INVALID_SENDER); |
| 102 | + assert(!to.is_zero(), Errors::INVALID_RECEIVER); |
| 103 | + assert( |
| 104 | + self._is_approved_or_owner(from, get_caller_address(), token_id), |
| 105 | + Errors::UNAUTHORIZED, |
| 106 | + ); |
| 107 | + |
| 108 | + self.balances.write(from, self.balances.read(from) - 1); |
| 109 | + self.balances.write(to, self.balances.read(to) + 1); |
| 110 | + self.owners.write(token_id, to); |
| 111 | + self.approvals.write(token_id, Zero::zero()); |
| 112 | + |
| 113 | + self.emit(Transfer { from, to, token_id }); |
| 114 | + } |
| 115 | + |
| 116 | + fn safe_transfer_from( |
| 117 | + ref self: ContractState, |
| 118 | + from: ContractAddress, |
| 119 | + to: ContractAddress, |
| 120 | + token_id: u256, |
| 121 | + data: Span<felt252>, |
| 122 | + ) { |
| 123 | + Self::transfer_from(ref self, from, to, token_id); |
| 124 | + assert( |
| 125 | + self._check_on_erc721_received(from, to, token_id, data), |
| 126 | + Errors::SAFE_TRANSFER_FAILED, |
| 127 | + ); |
| 128 | + } |
| 129 | + |
| 130 | + fn is_approved_for_all( |
| 131 | + self: @ContractState, owner: ContractAddress, operator: ContractAddress, |
| 132 | + ) -> bool { |
| 133 | + self.operator_approvals.read((owner, operator)) |
| 134 | + } |
| 135 | + } |
| 136 | + |
| 137 | + #[abi(embed_v0)] |
| 138 | + pub impl ERC721Burnable of IERC721Burnable<ContractState> { |
| 139 | + fn burn(ref self: ContractState, token_id: u256) { |
| 140 | + self._burn(token_id) |
| 141 | + } |
| 142 | + } |
| 143 | + |
| 144 | + #[abi(embed_v0)] |
| 145 | + pub impl ERC721Mintable of IERC721Mintable<ContractState> { |
| 146 | + fn mint(ref self: ContractState, to: ContractAddress, token_id: u256) { |
| 147 | + self._mint(to, token_id) |
| 148 | + } |
| 149 | + } |
| 150 | + |
| 151 | + #[generate_trait] |
| 152 | + pub impl InternalImpl of InternalTrait { |
| 153 | + fn _mint(ref self: ContractState, to: ContractAddress, token_id: u256) { |
| 154 | + assert(!to.is_zero(), Errors::INVALID_RECEIVER); |
| 155 | + assert(self.owners.read(token_id).is_zero(), Errors::ALREADY_MINTED); |
| 156 | + |
| 157 | + self.balances.write(to, self.balances.read(to) + 1); |
| 158 | + self.owners.write(token_id, to); |
| 159 | + |
| 160 | + self.emit(Transfer { from: Zero::zero(), to, token_id }); |
| 161 | + } |
| 162 | + |
| 163 | + fn _burn(ref self: ContractState, token_id: u256) { |
| 164 | + let owner = self._require_owned(token_id); |
| 165 | + |
| 166 | + self.balances.write(owner, self.balances.read(owner) - 1); |
| 167 | + |
| 168 | + self.owners.write(token_id, Zero::zero()); |
| 169 | + self.approvals.write(token_id, Zero::zero()); |
| 170 | + |
| 171 | + self.emit(Transfer { from: owner, to: Zero::zero(), token_id }); |
| 172 | + } |
| 173 | + |
| 174 | + fn _require_owned(self: @ContractState, token_id: u256) -> ContractAddress { |
| 175 | + let owner = self.owners.read(token_id); |
| 176 | + assert(!owner.is_zero(), Errors::INVALID_TOKEN_ID); |
| 177 | + owner |
| 178 | + } |
| 179 | + |
| 180 | + fn _is_approved_or_owner( |
| 181 | + self: @ContractState, owner: ContractAddress, spender: ContractAddress, token_id: u256, |
| 182 | + ) -> bool { |
| 183 | + !spender.is_zero() |
| 184 | + && (owner == spender |
| 185 | + || self.is_approved_for_all(owner, spender) |
| 186 | + || spender == self.get_approved(token_id)) |
| 187 | + } |
| 188 | + |
| 189 | + fn _check_on_erc721_received( |
| 190 | + self: @ContractState, |
| 191 | + from: ContractAddress, |
| 192 | + to: ContractAddress, |
| 193 | + token_id: u256, |
| 194 | + data: Span<felt252>, |
| 195 | + ) -> bool { |
| 196 | + let src5_dispatcher = ISRC5Dispatcher { contract_address: to }; |
| 197 | + |
| 198 | + if src5_dispatcher.supports_interface(IERC721_RECEIVER_ID) { |
| 199 | + IERC721ReceiverDispatcher { contract_address: to } |
| 200 | + .on_erc721_received( |
| 201 | + get_caller_address(), from, token_id, data, |
| 202 | + ) == IERC721_RECEIVER_ID |
| 203 | + } else { |
| 204 | + src5_dispatcher.supports_interface(openzeppelin_account::interface::ISRC6_ID) |
| 205 | + } |
| 206 | + } |
| 207 | + } |
| 208 | +} |
0 commit comments