Added missing options to the zsh completion definitions

Added missing options to the completion definition files for the
rc-service, rc-status, and rc-update commands.
(Including --user and -U):

Added status to the cmd option for rc-service.

Author: nilninull

zsh-completion/_rc-service

@@ -4,33 +4,44 @@ _rc_services() {
   if [[ -n "${opt_args[(i)-l|--list]}" ]]; then
     _nothing
   else
-    _values 'service' $(rc-service -l)
+    _values 'service' $(rc-service "${opt_args[(i)-U|--user]}" -l)
   fi
 }
 
 _rc_actions() {
   local service="${line[1]}"
 
-  if [[ -n "${opt_args[(i)-e|--exists|-r|--resolve]}" ]] || ! $(rc-service -e $service) ; then
+  if [[ -n "${opt_args[(i)-e|--exists|-r|--resolve]}" ]] || ! $(rc-service "${opt_args[(i)-U|--user]}" -e $service) ; then
     _nothing
   else
-    local -a actions=(${(f)"$(rc-service -C $service describe 2>&1)"})
+    local -a actions=(${(f)"$(rc-service "${opt_args[(i)-U|--user]}" -C $service describe 2>&1)"})
     shift actions
     actions=(${actions# \* })
     actions=(${actions/:*})
-    actions=(stop start restart describe zap ${actions[@]})
+    actions=(stop start restart status describe zap ${actions[@]})
     _describe -V 'action' actions
   fi
-
 }
 
 _arguments -C -s \
+  '(-d --debug)'{-d,--debug}'[set xtrace when running the command]' \
+  '(-D --nodeps)'{-D,--nodeps}'[ignore dependencies]' \
   '(-e --exists)'{-e,--exists}'[tests if the service exists or not]' \
+  '(-c --ifcrashed)'{-c,--ifcrashed}'[if the service is crashed run the command]' \
+  '(-i --ifexists)'{-i,--ifexists}'[if the service exists run the command]' \
+  '(-I --ifinactive)'{-I,--ifinactive}'[if the service is inactive run the command]' \
+  '(-N --ifnotstarted)'{-N,--ifnotstarted}'[if the service is not started run the command]' \
+  '(-s --ifstarted)'{-s,--ifstarted}'[if the service is started run the command]' \
+  '(-S --ifstopped)'{-S,--ifstopped}'[if the service is stopped run the command]' \
   '(-l --list)'{-l,--list}'[list all available services]' \
   '(-r --resolve)'{-r,--resolve}'[resolve the service name to an init script]' \
+  '(-Z --dry-run)'{-Z,--dry-run}'[dry run (show what would happen)]' \
+  '(- :)'{-h,--help}'[Display this help output]' \
   '(-C --nocolor)'{-C,--nocolor}'[Disable color output]' \
+  '(- :)'{-V,--version}'[Display software version]' \
   '(-v --verbose)'{-v,--verbose}'[Run verbosely]' \
-  '(-q --quiet)'{-q,--quiet}'[Run quietly]' \
+  '(-q --quiet)'{-q,--quiet}'[Run quietly (repeat to suppress errors)]' \
+  '(-U --user)'{-U,--user}'[Run in user mode]' \
   '1:service:_rc_services' \
   '2:action:_rc_actions'
 

zsh-completion/_rc-status

@@ -1,18 +1,26 @@
 #compdef rc-status
 
-_arguments -s \
-  {'(--all)-a','(-a)--all'}'[Show services at all runlevels]' \
-  {'(--crashed)-c','(-c)--crashed'}'[Show crashed services]' \
-  {'(--list)-l','(-l)--list'}'[Show list of runlevels]' \
-  {'(--runlevel)-r','(-r)--runlevel'}'[Show the name of the current runlevel]' \
-  {'(--servicelist)-s','(-s)--servicelist'}'[Show all services]' \
-  {'(--unused)-u','(-u)--unused'}'[Show services not assigned to any run level]' \
-  {'(--help)-h','(-h)--help'}'[Print this help output]' \
-  {'(--nocolor)-C','(-C)--nocolor'}'[Disable color output]' \
-  {'(--version)-V','(-V)--version'}'[Display software version]' \
-  {'(--verbose)-v','(-v)--verbose'}'[Run verbosely]' \
-  {'(--quiet)-q','(-q)--quiet'}'[Run quietly (Does not affect errors)]'
+_rc_runlevels() {
+  _values runlevels $(rc-status "${opt_args[(i)-U|--user]}" --list)
+}
 
-_values 'runlevels' $(rc-status --list)
+_arguments -s \
+  '(-a --all)'{-a,--all}'[Show services from all run levels]' \
+  '(-c --crashed)'{-c,--crashed}'[Show crashed services]' \
+  '(-f --format)'{-f,--format}'[format status to be parsable (currently arg must be ini)]:format:(ini)' \
+  '(-i --in-state)'{-i,--in-state}'[Show services which are in this state]:state:(stopped started stopping starting inactive hotplugged failed scheduled crashed)' \
+  '(-l --list)'{-l,--list}'[Show list of run levels]' \
+  '(-m --manual)'{-m,--manual}'[Show manually started services]' \
+  '(-r --runlevel)'{-r,--runlevel}'[Show the name of the current runlevel]' \
+  '(-s --servicelist)'{-s,--servicelist}'[Show service list]' \
+  '(-S --supervised)'{-S,--supervised}'[show supervised services]' \
+  '(-u --unused)'{-u,--unused}'[Show services not assigned to any runlevel]' \
+  '(- :)'{-h,--help}'[Display this help output]' \
+  '(-C --nocolor)'{-C,--nocolor}'[Disable color output]' \
+  '(- :)'{-V,--version}'[Display software version]' \
+  '(-v --verbose)'{-v,--verbose}'[Run verbosely]' \
+  '(-q --quiet)'{-q,--quiet}'[Run quietly (repeat to suppress errors)]' \
+  '(-U --user)'{-U,--user}'[Run in user mode]' \
+  '1:runlevels:_rc_runlevels'
 
 # vim: set et sw=2 ts=2 ft=zsh:

zsh-completion/_rc-update

@@ -1,31 +1,47 @@
 #compdef rc-update
 
-local used_init
-used_init=(${=${(M)${(f)"$(rc-update show 2>/dev/null)"}:#*|*[a-z]*}% |*})
+_rc_actions() {
+  _values "actions" \
+    'add[Add the service to the runlevel or the current one if none given]' \
+    'del[Delete the service from the runlevel or the current one if none given]' \
+    'show[Show all enabled services and the runlevels they belong to]'
+}
 
-if (( CURRENT == 2 )); then
-  _values "rc-update actions" \
-    'add[Add script to a runlevel]' \
-    'del[Delete script from a runlevel]' \
-    'show[Show scripts in  a runlevel]' \
-    '-a[Process all runlevels]' \
-    '-s[Stack a runlevel instead of a service]'
-elif (( CURRENT == 3 )); then
-  case "$words[2]" in
-    add)
-      _values "service" $(rc-service --list)
-      ;;
-    del)
-      _values "service" $used_init
-      ;;
-    show)
-      _values "runlevels" $(rc-status --list) \
-        '-v[Show all service scripts]' \
-        '--verbose[Show all service scripts]'
-      ;;
+_rc_service() {
+  case $line[1] in
+  add)
+    _values "service" $(rc-service "${opt_args[(i)-U|--user]}" --list)
+    ;;
+  del)
+    _values "service" ${=${(M)${(f)"$(rc-update ${opt_args[(i)-U|--user]} show 2>/dev/null)"}:#*|*[a-z]*}% |*}
+    ;;
+  show)
+    _values "runlevels" $(rc-status "${opt_args[(i)-U|--user]}" --list)
+    _values "options" '(-v --verbose)'{-v,--verbose}'[Show all service scripts]'
+    ;;
   esac
-elif (( CURRENT == 4 )); then
-  _values "runlevels" $(rc-status --list)
-fi
+}
+
+_rc_runlevels() {
+  if [[ $line[1] == show ]]; then
+    _nothing
+  else
+    _values "runlevels" $(rc-status "${opt_args[(i)-U|--user]}" --list)
+  fi
+}
+
+_arguments -C -s \
+  '(-a --all)'{-a,--all}'[Process all runlevels]' \
+  '(-s --stack)'{-s,--stack}'[Stack a runlevel instead of a service]' \
+  '(-u --update)'{-u,--update}'[Force an update of the dependency tree]' \
+  '(- :)'{-h,--help}'[Display this help output]' \
+  '(-C --nocolor)'{-C,--nocolor}'[Disable color output]' \
+  '(- :)'{-V,--version}'[Display software version]' \
+  '(-v --verbose)'{-v,--verbose}'[Run verbosely]' \
+  '(-q --quiet)'{-q,--quiet}'[Run quietly (repeat to suppress errors)]' \
+  '(-U --user)'{-U,--user}'[Run in user mode]' \
+  '1:actions:_rc_actions' \
+  '2:service:_rc_service' \
+  '3:runlevels:_rc_runlevels'
 
 # vim: set et sw=2 ts=2 ft=zsh: