Can tilesets be exported?

[vibrant-reindeer]

Hello everyone,

is there an option to export the tilesets generated by using tilemap layers? I can't find anything about this in the documentation, the GUI export dialog or the CLI export options.

Or am I misunderstanding the tilemap feature? The JSON export contains the tileset indices for tilemap layers so I figured it would be possible to use Pixelorama as a tilemap + tileset editor. Am I mistaken? Are tilemaps just a fancy way to create images and I should just use a different tool?

[Variable-ind]

Hy 👋
The tilemap layers work just like in Aseprite. For export, the image of the tilemap "layer" is exported. Not the tileset itself.

If you wish to modify a "Tileset", it may me better to import it as a "Sprite sheet" instead.

Can you tell me more about what exactly you wish to make? I might be able to suggest a better way 😁

[vibrant-reindeer]

Or i might just make the extension myself 😂 (if you wish) Shouldn't be that hard as i know about the code

Oh no, please don't invest your valuable time into this just for me. :D As I said, I'm just exploring features. Checking out tools and what they can do. I don't have a project I'm working on, just checking out which of the open source tools a worth learning. Pixelorama is definitely the best one for pixel art I have come across and it's written in Godot, which I already invested quite a lot of time into learning. So that's a plus if I ever wanted to add features myself. But if I ever need this specific feature I can quickly import and export with that old version of Aseprite I compiled years ago. :D

But it probably would be a good feature to put on the roadmap for tilemaps. I'm sure others would be interested in this too, especially if it would also be possible to convert a pixel layer into tilemap layer + tileset. Seems like most of the necessary parts would already be there from pixel drawing mode.

[vibrant-reindeer]

I just realized you can simply copy+paste pixel data into a tilemap layer and the tiles are automatically created. So that second feature already exists. :D

[Variable-ind]

Yes it exists

[Variable-ind]

Oh no, please don't invest your valuable time into this just for me.

I tried it anyway 😂 (Don't worry i'm on vocation from studies so i've got plenty of time), This currently exports all the tilesets in the current project as separate image per "tile". Is this closer to what you were imagining.

Extract me.zip

source code (Main.gd of the extension):

extends Node

@onready var extension_api: Node  ## A variable for easy reference to the Api
var id: int

func _enter_tree() -> void:
	## NOTE: use get_node_or_null("/root/ExtensionsApi") to access api.
	extension_api = get_node_or_null("/root/ExtensionsApi")
	var exporter_info := {"extension": ".png", "description": "Export Tileset"}
	id = extension_api.export.add_export_option(
		exporter_info, self, extension_api.export.ExportTab.IMAGE, false
	)  # 2nd argument (in this case "self") must have "override_export()" in it's script
	extension_api.signals.signal_export_about_to_preview(get_images)


func get_images(data_to_show: Dictionary):
	var export = get_node_or_null("/root/Export")
	if !export:
		return
	var exp_id = data_to_show["exporter_id"]
	var processed_images: Array = data_to_show["preview_images"]
	if id == exp_id:
		var project = extension_api.project.current_project
		if project:
			processed_images.clear()
			for tileset in project.tilesets:
				for tile_idx in tileset.tiles.size():
					var tile = tileset.tiles[tile_idx]
					if tile.image:
						var new_image = export.ProcessedImage.new(tile.image, tile_idx)
						processed_images.append(new_image)


func _exit_tree() -> void:
	# remember to remove things that you added using this extension
	extension_api.signals.signal_export_about_to_preview(get_images, true)
	extension_api.export.remove_export_option(id)


func override_export(details: Dictionary) -> bool:
	# in this function you take control of image processing and saving from pixelorama
	# return true for SUCCESS, false for FAILURE

	# the (details) include everything you could possibly need for exporting
	# keys of the "details" dictionary include:
	# "processed_images", "export_dialog", "export_paths", "project"
	# (Note: processed_images is an array of ProcessedImage resource which further has parameters
	# called image and duration)
	var project = extension_api.project.current_project
	if project and details["export_paths"].size() > 0:
		var base_path: String = details["export_paths"][0].get_base_dir()
		for tileset in project.tilesets:
			var tile_prefix = str(
				project.name, "-", tileset.name, "-", tileset.tile_size.x, "x", tileset.tile_size.y, "-", tileset.tile_shape
			)
			for i in tileset.tiles.size():
				var tile = tileset.tiles[i]
				if tile.image:
					var full_name = tile_prefix + str("-", i, ".png")
					var error = tile.image.save_png(base_path.path_join(full_name))
					if error != OK:
						return false
	return true

[vibrant-reindeer]

That's awesome and it works great, thank you so much!

I thought it would be even more convenient (for importing into Godot) to have the tilesets as sprite sheets. After reading your code, looking into the ExtensionsAPI and a bit of trial and error I made another extension. This one converts all tilesets into their own projects where each tile is one frame. These projects can then be exported using the regular sprite sheet export.

ConvertTilesetsToProjects-zipped.zip

extends Node

@onready var extension_api: Node  ## A variable for easy reference to the Api

var item_id: int

func _enter_tree() -> void:
	extension_api = get_node_or_null("/root/ExtensionsApi")
	item_id = extension_api.menu.add_menu_item(extension_api.menu.EDIT, "Convert Tilesets to Projects", self)

func _exit_tree() -> void:
	pass

func menu_item_clicked():
	var project = extension_api.project.current_project
	
	for tileset in project.tilesets:
		var tileset_project_name := str(project.name, "-", tileset.name)
		#var tile_size = Vector2i(16, 16) # FIXME
		var tile_size = tileset.tile_size
		var frames := Array([], TYPE_OBJECT, &"RefCounted", load("res://src/Classes/Frame.gd"))
		var tileset_project = extension_api.project.new_project(frames, tileset_project_name, tile_size)
		extension_api.project.current_project = tileset_project
		for i in tileset.tiles.size()-1:
			extension_api.project.add_new_frame(0)
		for i in tileset.tiles.size():
				var tile = tileset.tiles[i]
				extension_api.project.set_pixelcel_image(tile.image.duplicate(true), i, 0)
				
		# Workaround for cel previews not updating.
		extension_api.selection.select_all()
		extension_api.selection.clear()
	return true