Merge pull request #184 from hernanmd/iss_reverse_binomial

Add reverse binomial with tests.

Author: SergeStinckwich

src/Math-Numerical/Integer.extension.st

@@ -7,6 +7,37 @@ Integer >> gamma [
 	^ (self - 1) factorial.
 ]
 
+{ #category : #'*Math-Numerical' }
+Integer >> inverseBinomialCoefficient [
+
+	" Reverse binomial coefficient. Answer a <Collection> with all n and k such that n take: k = self. Elements in the answered Collection should be read as paired. Each pair represents (n,k) in the binomial coefficient formula. 
+	See https://math.stackexchange.com/a/103385/205 for details. "
+
+	| k |
+	[ self > 1 ] assert.
+	k := 0.
+	^ Array streamContents: [ :stream | 
+		  [ true ] whileTrue: [ 
+			  | nmin nmax choose |
+			  k := k + 1.
+			  2 * k + 1 * self <= (4 ** k) ifTrue: [ ^ stream contents ].
+			  nmin := ((k factorial * self) nthRoot: k) ceiling.
+			  nmax := nmin + k + 1.
+			  nmin := nmin max: 2 * k.
+			  choose := nmin asInteger numberOfCombinationsTaken: k.
+			  nmin to: nmax do: [ :n | 
+				  choose = self ifTrue: [ 
+					  stream nextPutAll: { 
+							  n asInteger.
+							  k asInteger }.
+					  k < (n - k) ifTrue: [ 
+						  stream nextPutAll: { 
+								  n asInteger.
+								  (n - k) asInteger } ] ].
+				  choose := choose * (n + 1).
+				  choose := (choose / (n + 1 - k)) ceiling ] ] ]
+]
+
 { #category : #'*Math-Numerical' }
 Integer >> random [
 		"Answer a random integer between 0 and the receiver."

src/Math-Tests-Numerical/IntegerTest.extension.st

@@ -0,0 +1,17 @@
+Extension { #name : #IntegerTest }
+
+{ #category : #'*Math-Tests-Numerical' }
+IntegerTest >> testFindNK [
+
+	self assert: 6 inverseBinomialCoefficient equals:  #(6 1 6 5 4 2).
+	self assert: 10 inverseBinomialCoefficient equals: #(10 1 10 9 5 2 5 3).
+	self assert: 20 inverseBinomialCoefficient equals: #(20 1 20 19 6 3).	
+	self assert: 21 inverseBinomialCoefficient equals: #(21 1 21 20 7 2 7 5).
+	self assert: 55 inverseBinomialCoefficient equals: #(55 1 55 54 11 2 11 9).
+	self assert: 120 inverseBinomialCoefficient equals: #(120 1 120 119 16 2 16 14 10 3 10 7).
+	self assert: 3003 inverseBinomialCoefficient equals: #(3003 1 3003 3002 78 2 78 76 15 5 15 10 14 6 14 8).
+	self assert: 8966473191018617158916954970192684 inverseBinomialCoefficient equals: #(8966473191018617158916954970192684 1 8966473191018617158916954970192684 8966473191018617158916954970192683 123 45 123 78).
+
+	self should: [ 1 inverseBinomialCoefficient ] raise: Error.
+	self should: [ 0 inverseBinomialCoefficient ] raise: Error.
+]