Receive error message

[msman0]

Hi, I receive at CapiBridge the following message when the PirBOX-LITE send:
LoRa JSON Message: deserializeJson() returned InvalidInput
I have compared the both config files and there are the same settings.

During programming the PirBOX-LITE I got the following warning but programming seem ok:

/../PirBox-Lite/PirBox-Lite.ino: In function 'String xorCipher(String)':
/../PirBox-Lite/PirBox-Lite.ino:48:21: warning: comparison between signed and unsigned integer expressions [-Wsign-compare]
   for (int i = 0; i < input.length(); i++) {
                   ~~^~~~~~~~~~~~~~~~

What can I do to solve the problem?
Thank you.

[AI-RedCode]

Hi msman0,

The error deserializeJson() returned InvalidInput usually indicates that the JSON payload received is not valid or malformed.

From the README and your message, a few things to check and try:

1. Encryption Key Matching:
   Make sure that the encryption_key and its length on both the PirBOX-LITE and in CapiBridge's config.h exactly match. A mismatch will cause the XOR decryption to produce invalid data, resulting in JSON deserialization errors.

2. XOR Cipher Function Warning:
   The warning you see at compiling the PirBOX-LITE code is safe to ignore for now; it is a signed/unsigned comparison warning inside your xorCipher function loop and shouldn’t affect functionality.

3. Payload Format:
   Verify that the PirBOX-LITE is indeed sending a properly encrypted JSON string with the required keys "k" (gateway key) and "id" (node name). You can test this by setting the CapiBridge UART switch to ESP1 and monitoring the raw LoRa packets in the Serial Monitor (baud 115200) to see what is actually received.

4. LoRa Config Matching:
   Double-check that both devices share the exact same LoRa parameters (frequency, spreading factor, sync word, preamble length, etc.). Differences cause garbled data reception.

You can find full details for encryption keys and example code in the README:
https://github.com/PricelessToolkit/CapiBridge#esp1ino-sketch-configuration
and also see the sensor JSON string example here:
https://github.com/PricelessToolkit/CapiBridge#json-string-sent-by-a-sensor/node

Following these hints ensures the JSON deserialization will succeed. The mismatch or corrupted payload is the typical cause of deserializeJson() returned InvalidInput.

Good luck!

✅ If this answer helped, please close the discussion.
🤖 I’m an AI and If my response is incorrect or not sufficient, don’t worry @PricelessToolkit will review this discussion soon.

[msman0]

@AI-RedCode thank you AI. How can I can see the raw LoRa packets? I have, as you mentioned, the Serial Monitor with 115200 baud, but I only the the message I have told you.

[msman0]

I have found the possibility to display the RAW Json.

LoRa ROW Message: W!���!���/]�H!E�|j
�C{3�"m":"off","b":93}

Where are these characters coming from? Since the end of the data was decoded correctly, this does not appear to be an encryption issue.

[msman0]

Now it worked...I don't know why exactly. I have reentered the Gateway and flashed the sensor new...

[PricelessToolkit]

Hi msman0, Sorry for the late reply. As I see, my assistant :)) has already pointed you in the right direction. By the way, AI only responds to the first message.

[msman0]

Thank you. Sorry to disturb again. The motion "on" message ist still corrupt. Only the "off" message ist correct.
The Row message "on" looks like:

LoRa ROW Message: W!���!���/]�H!E�|j
�C{]��n]��l��"b":92}

Any idea what to change?

[PricelessToolkit]

HI,

You uncommented this part, comment it back Lignes 791-793
It's a "LoRa ROW Message"; it's for diagnostic purposes

    //Serial.print("LoRa ROW Message: ");
    //Serial.println(recv);
    //Serial.println(" ");

You will see "LoRa JSON Message:" NOT ROW!! If the encryption keys are the same in the node and in the gateway, and encryption is enabled on both devices.

config.h

#define GATEWAY_KEY "xy"                           // Separation Key "Keep it small" Must match exactly sensors key
#define Encryption true                            // Global Payload Encryption, true or false
#define encryption_key_length 4                    // must match number of bytes in the XOR key array
#define encryption_key { 0x4B, 0xA3, 0x3F, 0x9C }  // Multi-byte XOR key (between 2–16 values).

You get "LoRa JSON Message:" ??

[msman0]

Yes I uncommented lines 791-793.
I tested without encyption and it worked.
With encryption (both key are the same) I these messages:

LoRa ROW Message: W!���!���/]�H!E�|j
�C{]��n]��l��"b":92}
  
LoRa JSON Message: deserializeJson() returned InvalidInput
LoRa ROW Message: W!���!���/]�H!E�|j
�C{]��n]��l���/]��9F�Q
  
LoRa JSON Message: {"k":"ax","id":"PirBox","m":"off","b":92,"r":-61}

The "off" message ist correct, but the "on" message is not correct decrypted. the last characters in the encrypted message are clear text

"b":92}

I don't understand why these happens...

[PricelessToolkit]

Give me the configs i will test them

[msman0]

Thank you, done in the former thread

[PricelessToolkit]

Please give this updated PirBox code a try the encryption section has been tidied up for clarity.
If the issue persists, could you also test using the original key:

"{ 0x4B, 0xA3, 0x3F, 0x9C }"

PirBox-Lite.zip

[msman0]

Thank you. With your new PirBox-Lite ino it didn't work, same error.

With your standard encryption key 0x4B,0xA3 etc. it worked. I don't understand why...

I will try other keys next few days....

[PricelessToolkit]

ok, now I understand. I will fix it. Please give me a couple of days.

[PricelessToolkit]

for a quick fix "change in capibridge and in pirbox"

replace

String xorCipher(const String& input) {
  const byte key[] = encryption_key;
  const int keyLength = encryption_key_length;
  String output;
  output.reserve(input.length());
  for (int i = 0; i < input.length(); i++) {
    byte keyByte = key[i % keyLength];
    output += char(input[i] ^ keyByte);
  }
  return output;
}

with

String xorCipher(String in) {
  // 1) Use an ARRAY, not a pointer, for the macro initializer
  static const uint8_t key[] = encryption_key;
  const int K = encryption_key_length;

  auto isB64 = [](const String& s)->bool{
    if (s.length() % 4) return false;
    for (size_t i=0;i<s.length();++i){
      char c=s[i];
      if (!((c>='A'&&c<='Z')||(c>='a'&&c<='z')||(c>='0'&&c<='9')||c=='+'||c=='/'||c=='=')) return false;
    }
    return true;
  };

  auto b64enc = [](const uint8_t* b, size_t n)->String{
    static const char T[]="ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/";
    String o; o.reserve(((n+2)/3)*4);
    for(size_t i=0;i<n;i+=3){
      uint32_t v = ((uint32_t)b[i] << 16)
                 | ((i+1<n ? (uint32_t)b[i+1] : 0) << 8)
                 |  (i+2<n ? (uint32_t)b[i+2] : 0);
      o += T[(v>>18)&63]; o += T[(v>>12)&63];
      o += (i+1<n) ? T[(v>>6)&63] : '=';
      o += (i+2<n) ? T[v&63]      : '=';
    }
    return o;
  };

  auto b64val = [](char c)->int{
    if(c>='A'&&c<='Z') return c-'A';
    if(c>='a'&&c<='z') return 26+c-'a';
    if(c>='0'&&c<='9') return 52+c-'0';
    if(c=='+') return 62;
    if(c=='/') return 63;
    return -1;
  };

  auto b64dec = [&](const String& s)->String{
    String o; o.reserve((s.length()/4)*3);
    for(size_t i=0;i<s.length(); i+=4){
      int a=b64val(s[i]), b=b64val(s[i+1]);
      int c = (s[i+2]=='=') ? -1 : b64val(s[i+2]);
      int d = (s[i+3]=='=') ? -1 : b64val(s[i+3]);

      // 2) Upcast before shifting (AVR int is 16-bit)
      uint32_t v = ((uint32_t)(a & 63) << 18)
                 | ((uint32_t)(b & 63) << 12)
                 | ((uint32_t)((c < 0 ? 0 : (c & 63))) << 6)
                 |  (uint32_t)((d < 0 ? 0 : (d & 63)));

      o += (char)((v >> 16) & 0xFF);
      if (c >= 0) o += (char)((v >> 8) & 0xFF);
      if (d >= 0) o += (char)(v & 0xFF);
    }
    return o;
  };

  if (isB64(in)) {                 // decrypt: Base64 -> XOR -> JSON
    String bytes = b64dec(in);
    String out; out.reserve(bytes.length());
    for (size_t i=0;i<bytes.length();++i)
      out += (char)(((uint8_t)bytes[i]) ^ key[i % K]);
    return out;
  } else {                         // encrypt: JSON -> XOR -> Base64
    String x; x.reserve(in.length());
    for (size_t i=0;i<in.length();++i)
      x += (char)(((uint8_t)in[i]) ^ key[i % K]);
    return b64enc((const uint8_t*)x.c_str(), x.length());
  }
}

[msman0]

Thank you, the new code worked with my encryption key now.

[PricelessToolkit]

I will update the code soon. I've added more functionality, including two-way ESP-NOW support, bug fixes, and more.