Merge pull request #278 from SAP/Scope-of-the-Variable

Scope of the Variable

Author: lucasborin

docs/check_documentation.md

@@ -17,7 +17,6 @@
 - [Cyclomatic Complexity](checks/cyclomatic-complexity.md)
 - [CX_ROOT Usage](checks/cx-root-usage.md)
 - [Database Access in Unit-Test](checks/db-access-in-ut.md)
-- [Declaration in IF](checks/declaration-in-if.md)
 - [Deprecated Classes](checks/deprecated-classes.md)
 - [Deprecated Key Word](checks/deprecated-key-word.md)
 - [Empty Catch](checks/empty_catch.md)
@@ -47,6 +46,7 @@
 - [READ TABLE with Subsequent Memory Assignment](checks/sub-assign-read-table.md)
 - [RECEIVING Statement Usage](checks/receiving-usage.md)
 - [Returning Name](checks/returning-name.md)
+- [Scope of Variable](checks/scope-of-variable.md)
 - [Self-Reference](checks/self-reference.md)
 - [TEST-SEAM Statement Usage](checks/test-seam-usage.md)
 - [Unit-Test Coverages (Statement, Branch and Procedure)](checks/unit-test-coverages.md)

docs/checks/declaration-in-if.md

@@ -0,0 +1,51 @@
+# code pal for ABAP
+
+[code pal for ABAP](../../README.md) > [Documentation](../check_documentation.md) > [Scope of Variable](scope-of-variable.md)
+
+## Scope of Variable
+
+### What is the Intent of the Check?
+If a variable is declared in a statement, it should be used/referred to inside this statement only (not outside).
+
+### How does the check work?
+It searches for `DATA` and `FIELD-SYMBOLS` declaration inside of `IF`, `ELSEIF`, `ELSE`, `DO`, `CASE/WHEN`, `LOOP`, and `WHILE` statements, and for its usage/reference outside this statement.
+
+### How to solve the issue?
+Relocate the declaration.
+
+### What to do in case of exception?
+You can suppress Code Inspector findings generated by this check using the pseudo comment `"#EC SCOPE_OF_VAR`.   
+The pseudo comment must be placed right after the variable usage/referece.
+
+```abap
+IF has_entries = abap_true.
+  DATA(value) = 1.
+ELSE.
+  value = 2. "#EC SCOPE_OF_VAR
+ENDIF.
+```
+
+### Example
+
+Before:
+```abap
+IF has_entries = abap_true.
+  DATA(value) = 1.
+ELSE.
+  value = 2.
+ENDIF.
+```
+
+After:
+```abap
+DATA value TYPE i.
+
+IF has_entries = abap_true.
+  value = 1.
+ELSE.
+  value = 2.
+ENDIF.
+```
+
+### Further Readings & Knowledge
+* [ABAP Styleguides on Clean Code](https://github.com/SAP/styleguides/blob/master/clean-abap/CleanABAP.md#dont-declare-inline-in-optional-branches)

docs/checks/imgs/declaration_in_if.png

@@ -0,0 +1,123 @@
+CLASS y_check_scope_of_variable DEFINITION PUBLIC INHERITING FROM y_check_base CREATE PUBLIC .
+  PUBLIC SECTION.
+    METHODS constructor .
+
+  PROTECTED SECTION.
+    METHODS inspect_tokens REDEFINITION.
+
+  PRIVATE SECTION.
+    METHODS is_isolated IMPORTING strucutre_row TYPE stmnt_stru
+                        RETURNING VALUE(result) TYPE abap_bool.
+
+    METHODS extract_variable_name IMPORTING token         TYPE string
+                                  RETURNING VALUE(result) TYPE string.
+
+    METHODS get_scope_structure IMPORTING strucutre_row TYPE stmnt_stru
+                                RETURNING VALUE(result) TYPE sstruc.
+
+ENDCLASS.
+
+
+
+CLASS y_check_scope_of_variable IMPLEMENTATION.
+
+
+  METHOD constructor.
+    super->constructor( ).
+
+    settings-pseudo_comment = '"#EC SCOPE_OF_VAR' ##NO_TEXT.
+    settings-disable_threshold_selection = abap_true.
+    settings-threshold = 0.
+    settings-prio = c_warning.
+    settings-documentation = |{ c_docs_path-checks }scope-of-variable.md|.
+
+    set_check_message( 'Variable in use out of its scope!' ).
+  ENDMETHOD.
+
+
+  METHOD inspect_tokens.
+
+    DATA(token) = get_token_abs( statement-from ).
+
+    IF token NP 'DATA(*)'
+    AND token NP 'FIELD-SYMBOLS(*)'.
+      RETURN.
+    ENDIF.
+
+    IF is_isolated( statement-struc ) = abap_false.
+      RETURN.
+    ENDIF.
+
+    DATA(variable) = extract_variable_name( token ).
+    DATA(scope) = get_scope_structure( statement-struc ).
+    DATA(statement_index) = index.
+
+    LOOP AT ref_scan_manager->get_statements( ) ASSIGNING FIELD-SYMBOL(<statement>)
+    FROM scope-stmnt_from TO scope-stmnt_to
+    WHERE number > statement-number.
+
+      statement_index = statement_index + 1.
+
+      IF <statement>-struc = statement-struc.
+        CONTINUE.
+      ENDIF.
+
+      LOOP AT ref_scan_manager->get_tokens( ) ASSIGNING FIELD-SYMBOL(<tokens>)
+      FROM <statement>-from TO <statement>-to
+      WHERE str = variable.
+
+        DATA(check_configuration) = detect_check_configuration( <statement> ).
+
+        IF check_configuration IS INITIAL.
+          RETURN.
+        ENDIF.
+
+        raise_error( statement_level     = <statement>-level
+                     statement_index     = statement_index
+                     statement_from      = <statement>-from
+                     error_priority      = check_configuration-prio ).
+      ENDLOOP.
+
+    ENDLOOP.
+  ENDMETHOD.
+
+
+  METHOD is_isolated.
+    DATA(structures) = ref_scan_manager->get_structures( ).
+    DATA(structure) = structures[ strucutre_row ].
+
+    result = xsdbool(    structure-stmnt_type = scan_struc_stmnt_type-if
+                      OR structure-stmnt_type = scan_struc_stmnt_type-then
+                      OR structure-stmnt_type = scan_struc_stmnt_type-elseif
+                      OR structure-stmnt_type = scan_struc_stmnt_type-else
+                      OR structure-stmnt_type = scan_struc_stmnt_type-do
+                      OR structure-stmnt_type = scan_struc_stmnt_type-case
+                      OR structure-stmnt_type = scan_struc_stmnt_type-when
+                      OR structure-stmnt_type = scan_struc_stmnt_type-loop
+                      OR structure-stmnt_type = scan_struc_stmnt_type-while ).
+  ENDMETHOD.
+
+
+  METHOD extract_variable_name.
+    result = token.
+    REPLACE ALL OCCURRENCES OF 'DATA(' IN result WITH ''.
+    REPLACE ALL OCCURRENCES OF 'FIELD-SYMBOLS(' IN result WITH ''.
+    REPLACE ALL OCCURRENCES OF ')' IN result WITH ''.
+  ENDMETHOD.
+
+
+  METHOD get_scope_structure.
+    DATA(structures) = ref_scan_manager->get_structures( ).
+    DATA(structure) = structures[ strucutre_row ].
+
+    DATA(is_root) = xsdbool(    structure-stmnt_type = scan_struc_stmnt_type-form
+                             OR structure-stmnt_type = scan_struc_stmnt_type-method
+                             OR structure-stmnt_type = scan_struc_stmnt_type-function
+                             OR structure-stmnt_type = scan_struc_stmnt_type-module
+                             OR structure-type       = scan_struc_type-event ).
+
+    result = COND #( WHEN is_root = abap_true THEN structure
+                                              ELSE get_scope_structure( structure-back ) ).
+  ENDMETHOD.
+
+ENDCLASS.