[EdgeDB] Partnership schema (#3064)

Co-authored-by: Carson Full <[email protected]>

Author: atGit2021

dbschema/migrations/00049.edgeql

@@ -0,0 +1,32 @@
+CREATE MIGRATION m1kzwpoy3r3awvbzqxxzz3upkkemxjtf33ra53zkuxzexsc7r5x4zq
+    ONTO m1tn7o5vizqaygjvghqysxzw6ruf4xohudb2usgfg4z622ens24mba
+{
+  CREATE MODULE Partnership IF NOT EXISTS;
+  ALTER SCALAR TYPE Partner::FinancialReportingType RENAME TO Partnership::FinancialReportingType;
+  CREATE SCALAR TYPE Partnership::AgreementStatus EXTENDING enum<NotAttached, AwaitingSignature, Signed>;
+  CREATE TYPE default::Partnership EXTENDING Project::Child {
+      CREATE REQUIRED LINK partner: default::Partner;
+      CREATE CONSTRAINT std::exclusive ON ((.project, .partner));
+      CREATE LINK agreement: default::File;
+      CREATE LINK mou: default::File;
+      CREATE LINK organization := (.partner.organization);
+      CREATE PROPERTY mouEndOverride: cal::local_date;
+      CREATE PROPERTY mouEnd := ((.mouEndOverride ?? .project.mouEnd));
+      CREATE PROPERTY mouStartOverride: cal::local_date;
+      CREATE PROPERTY mouStart := ((.mouStartOverride ?? .project.mouStart));
+      CREATE REQUIRED PROPERTY agreementStatus: Partnership::AgreementStatus {
+          SET default := (Partnership::AgreementStatus.NotAttached);
+      };
+      CREATE PROPERTY financialReportingType: Partnership::FinancialReportingType;
+      CREATE REQUIRED PROPERTY mouStatus: Partnership::AgreementStatus {
+          SET default := (Partnership::AgreementStatus.NotAttached);
+      };
+      CREATE REQUIRED PROPERTY primary: std::bool {
+          SET default := false;
+      };
+      CREATE MULTI PROPERTY types: Partner::Type;
+  };
+  ALTER TYPE default::Project {
+      CREATE LINK partnerships := (.<project[IS default::Partnership]);
+  };
+};

dbschema/partner.esdl

@@ -17,7 +17,7 @@ module default {
 
     #address: str; #TODO - this needs figured out - needed on here and Organization?
     multi types: Partner::Type;
-    multi financialReportingTypes: Partner::FinancialReportingType;
+    multi financialReportingTypes: Partnership::FinancialReportingType;
 
     pointOfContact: User;
     languageOfWiderCommunication: Language;
@@ -40,11 +40,4 @@ module Partner {
     Technical,
     Resource
   >;
-  
-  #TODO - probably move to Partnership?
-  scalar type FinancialReportingType extending enum<
-    Funded,
-    FieldEngaged,
-    Hybrid
-  >;
 }

dbschema/partnership.esdl

@@ -0,0 +1,41 @@
+module default {
+  type Partnership extending Project::Child {
+    required partner: Partner;
+    constraint exclusive on ((.project, .partner));
+    organization := .partner.organization;
+    
+    required primary: bool {
+      default := false;
+    };
+    multi types: Partner::Type;
+    financialReportingType: Partnership::FinancialReportingType;
+    
+    mouStart := .mouStartOverride ?? .project.mouStart;
+    mouEnd := .mouEndOverride ?? .project.mouEnd;
+    mouStartOverride: cal::local_date;
+    mouEndOverride: cal::local_date;
+    
+    agreement: File;
+    required agreementStatus: Partnership::AgreementStatus {
+      default := Partnership::AgreementStatus.NotAttached;
+    };
+    mou: File;
+    required mouStatus: Partnership::AgreementStatus {
+      default := Partnership::AgreementStatus.NotAttached;
+    };
+  }
+}
+  
+module Partnership {
+  scalar type AgreementStatus extending enum<
+    NotAttached,
+    AwaitingSignature,
+    Signed
+  >;
+  
+  scalar type FinancialReportingType extending enum<
+    Funded,
+    FieldEngaged,
+    Hybrid
+  >;
+}

dbschema/project.esdl

@@ -81,6 +81,8 @@ module default {
 
     link rootDirectory: Directory;
 
+    partnerships := .<project[is Partnership];
+    
     overloaded link projectContext: Project::Context {
       default := (insert Project::Context {
         # https://github.com/edgedb/edgedb/issues/3960