[EdgeDB] Create Organization and Partner schemas (#2967)

Co-authored-by: Carson Full <[email protected]>

Author: bryanjnelson

dbschema/migrations/00029.edgeql

@@ -0,0 +1,45 @@
+CREATE MIGRATION m1t7atw76jdjhcnrngoj5euzbz7qxve7dokvbhh4x5333yxm5klkwa
+    ONTO m1rob2znvgmu7myqon4wzkdxur6765udhhucohw6apoxhtrbbnxova
+{
+  CREATE MODULE Organization IF NOT EXISTS;
+  CREATE MODULE Partner IF NOT EXISTS;
+  CREATE SCALAR TYPE Organization::Reach EXTENDING enum<Local, Regional, National, `Global`>;
+  CREATE SCALAR TYPE Organization::Type EXTENDING enum<Church, Parachurch, Mission, TranslationOrganization, Alliance>;
+  CREATE TYPE default::Organization EXTENDING default::Resource, Project::ContextAware, Mixin::Named {
+      ALTER PROPERTY name {
+          SET OWNED;
+          CREATE CONSTRAINT std::exclusive;
+      };
+      CREATE PROPERTY acronym: std::str;
+      CREATE MULTI PROPERTY reach: Organization::Reach;
+      CREATE MULTI PROPERTY types: Organization::Type;
+  };
+  CREATE SCALAR TYPE Partner::FinancialReportingType EXTENDING enum<Funded, FieldEngaged, Hybrid>;
+  CREATE SCALAR TYPE Partner::Type EXTENDING enum<Managing, Funding, Impact, Technical, Resource>;
+  CREATE TYPE default::Partner EXTENDING default::Resource, Project::ContextAware, Mixin::Named, Mixin::Pinnable, Mixin::Taggable {
+      CREATE REQUIRED LINK organization: default::Organization {
+          SET readonly := true;
+          CREATE CONSTRAINT std::exclusive;
+      };
+      ALTER PROPERTY name {
+          SET OWNED;
+          CREATE CONSTRAINT std::exclusive;
+      };
+      CREATE MULTI LINK countries: default::Location;
+      CREATE MULTI LINK fieldRegions: default::FieldRegion;
+      CREATE LINK languageOfWiderCommunication: default::Language;
+      CREATE MULTI LINK languagesOfConsulting: default::Language;
+      CREATE LINK pointOfContact: default::User;
+      CREATE REQUIRED PROPERTY active: std::bool {
+          SET default := true;
+      };
+      CREATE MULTI PROPERTY financialReportingTypes: Partner::FinancialReportingType;
+      CREATE REQUIRED PROPERTY globalInnovationsClient: std::bool {
+          SET default := false;
+      };
+      CREATE PROPERTY pmcEntityCode: std::str {
+          CREATE CONSTRAINT std::regexp('^[A-Z]{3}$');
+      };
+      CREATE MULTI PROPERTY types: Partner::Type;
+  };
+};

dbschema/organization.esdl

@@ -0,0 +1,29 @@
+module default {
+  type Organization extending Resource, Project::ContextAware, Mixin::Named {
+    overloaded name {
+      constraint exclusive;
+    }
+    
+    acronym: str;
+    #address: str; #TODO - this needs figured out - needed on here and Partner?
+    multi types: Organization::Type;
+    multi reach: Organization::Reach;
+  }
+}
+  
+module Organization {
+  scalar type Type extending enum<
+    Church,
+    Parachurch,
+    Mission,
+    TranslationOrganization,
+    Alliance
+  >;
+  
+  scalar type Reach extending enum<
+    Local,
+    Regional,
+    National,
+    `Global`
+  >;
+}

dbschema/partner.esdl

@@ -0,0 +1,50 @@
+module default {
+  type Partner extending Resource, Project::ContextAware, Mixin::Named, Mixin::Pinnable, Mixin::Taggable {
+    overloaded name {
+      constraint exclusive;
+    }
+    
+    required active: bool {
+      default := true;
+    };
+    required globalInnovationsClient: bool {
+      default := false;
+    };
+    
+    pmcEntityCode: str {
+      constraint regexp(r'^[A-Z]{3}$');
+    }
+    
+    #address: str; #TODO - this needs figured out - needed on here and Organization?
+    multi types: Partner::Type;
+    multi financialReportingTypes: Partner::FinancialReportingType;
+    
+    pointOfContact: User;
+    languageOfWiderCommunication: Language;
+    
+    required organization: Organization {
+      readonly := true;
+      constraint exclusive;
+    };
+    multi languagesOfConsulting: Language;
+    multi fieldRegions: FieldRegion;
+    multi countries: Location;
+  }
+}
+  
+module Partner {
+  scalar type Type extending enum<
+    Managing,
+    Funding,
+    Impact,
+    Technical,
+    Resource
+  >;
+  
+  #TODO - probably move to Partnership?
+  scalar type FinancialReportingType extending enum<
+    Funded,
+    FieldEngaged,
+    Hybrid
+  >;
+}