[EdgeDB] ProgressReport.Child & VarianceExplanation schema (#3087)

Co-authored-by: Carson Full <[email protected]>

Author: atGit2021

dbschema/migrations/00055.edgeql

@@ -0,0 +1,26 @@
+CREATE MIGRATION m13kr5hbnbuidyg3qtxulx7k53yqzb3sxcvacxryesnkgut3ntxtla
+    ONTO m1mbjrsuqwwklgbswbvdbryp4p7gpgevkd7eq2qx6hfelhjvipkyhq
+{
+  CREATE MODULE ProgressReport IF NOT EXISTS;
+  CREATE ABSTRACT TYPE ProgressReport::Child EXTENDING Engagement::Child {
+      CREATE ANNOTATION std::description := 'A type that is a child of a progress report. It will always have a reference to a single progress report and engagement that it is under.';
+      CREATE REQUIRED LINK report: default::ProgressReport {
+          ON TARGET DELETE DELETE SOURCE;
+          SET readonly := true;
+      };
+      CREATE TRIGGER enforceProgressReportEngagement
+          AFTER UPDATE, INSERT 
+          FOR EACH DO (std::assert((__new__.report.engagement = __new__.engagement), message := 'Given progress report must be for the same engagement as the given engagement'));
+  };
+  CREATE TYPE ProgressReport::VarianceExplanation EXTENDING ProgressReport::Child {
+      ALTER LINK report {
+          SET OWNED;
+          CREATE CONSTRAINT std::exclusive;
+      };
+      CREATE PROPERTY comments: default::RichText;
+      CREATE MULTI PROPERTY reasons: std::str;
+  };
+  ALTER TYPE default::ProgressReport {
+      CREATE SINGLE LINK varianceExplanation := (.<report[IS ProgressReport::VarianceExplanation]);
+  };
+};

dbschema/progress-report.esdl

@@ -2,5 +2,37 @@ module default {
   type ProgressReport extending PeriodicReport, Engagement::Child {
     overloaded container: LanguageEngagement;
     overloaded engagement: LanguageEngagement;
+    single varianceExplanation := .<report[is ProgressReport::VarianceExplanation];
+  }
+}
+
+module ProgressReport {
+   abstract type Child extending Engagement::Child {
+    annotation description := "\
+      A type that is a child of a progress report. \
+
+      It will always have a reference to a single progress report and engagement that it is under.";
+
+    required report: default::ProgressReport {
+      readonly := true;
+      on target delete delete source;
+    };
+
+    trigger enforceProgressReportEngagement after insert, update for each do (
+      assert(
+        __new__.report.engagement = __new__.engagement,
+        message := "Given progress report must be for the same engagement as the given engagement"
+      )
+    );
+  }
+
+  type VarianceExplanation extending ProgressReport::Child {
+    overloaded report {
+      constraint exclusive;
+    };
+
+    multi reasons: str; 
+
+    comments: default::RichText;
   }
 }