Implement departmentId assignment

Author: CarsonF

dbschema/migrations/00036.edgeql

@@ -0,0 +1,26 @@
+CREATE MIGRATION m1ydhle3dwjru34saeiidf5dyepbesugdwttrvnsyxhezpme5bfqga
+    ONTO m13bndkbclxwviy3uj4eskx56bd2chw2xbvfn5pae557oslmbz2ssa
+{
+  ALTER TYPE default::Project {
+      ALTER PROPERTY departmentId {
+          CREATE REWRITE
+              UPDATE 
+              USING ((IF ((NOT (EXISTS (.departmentId)) AND (.status <= Project::Status.Active)) AND (.step >= Project::Step.PendingFinanceConfirmation)) THEN (WITH
+                  fa := 
+                      std::assert_exists(__subject__.primaryLocation.fundingAccount, message := 'Project must have a primary location')
+                  ,
+                  existing := 
+                      (SELECT
+                          (DETACHED default::Project).departmentId
+                      FILTER
+                          (default::Project.primaryLocation.fundingAccount = fa)
+                      )
+                  ,
+                  available := 
+                      (std::range_unpack(std::range(((fa.accountNumber * 10000) + 11), ((fa.accountNumber * 10000) + 9999))) EXCEPT existing)
+              SELECT
+                  std::min(available)
+              ) ELSE .departmentId));
+      };
+  };
+};

dbschema/project.esdl

@@ -14,6 +14,27 @@ module default {
       constraint exclusive;
       constraint min_value(10000);
       constraint max_value(99999);
+      rewrite update using (
+        if (
+          not exists .departmentId and
+          .status <= Project::Status.Active and
+          .step >= Project::Step.PendingFinanceConfirmation
+        ) then ((
+          with
+            fa := assert_exists(
+              __subject__.primaryLocation.fundingAccount,
+              message := "Project must have a primary location"
+            ),
+            existing := (
+              select detached Project.departmentId filter Project.primaryLocation.fundingAccount = fa
+            ),
+            available := (
+              range_unpack(range(fa.accountNumber * 10000 + 11, fa.accountNumber * 10000 + 9999))
+              except existing
+            )
+          select min(available)
+        )) else .departmentId
+      );
     };
 
     required step: Project::Step {

src/components/project/handlers/set-department-id.handler.ts

@@ -4,17 +4,29 @@ import {
   ServerException,
   UnsecuredDto,
 } from '../../../common';
-import { DatabaseService, EventsHandler, IEventHandler } from '../../../core';
+import {
+  ConfigService,
+  DatabaseService,
+  EventsHandler,
+  IEventHandler,
+} from '../../../core';
 import { Project, ProjectStep } from '../dto';
 import { ProjectUpdatedEvent } from '../events';
 
 type SubscribedEvent = ProjectUpdatedEvent;
 
 @EventsHandler(ProjectUpdatedEvent)
 export class SetDepartmentId implements IEventHandler<SubscribedEvent> {
-  constructor(private readonly db: DatabaseService) {}
+  constructor(
+    private readonly db: DatabaseService,
+    private readonly config: ConfigService,
+  ) {}
 
   async handle(event: SubscribedEvent) {
+    if (this.config.databaseEngine === 'edgedb') {
+      return;
+    }
+
     const shouldSetDepartmentId =
       event.updates.step === ProjectStep.PendingFinanceConfirmation &&
       !event.updated.departmentId;