engagement workflow schema and engagement schema revisions

Author: Andre Turner

dbschema/engagement-workflow.esdl

@@ -0,0 +1,66 @@
+module Engagement {
+  type WorkflowEvent extending ContextAware {
+    required engagement: default::Engagement {
+      readonly := true;
+      on target delete delete source;
+    };
+    required who: default::Actor {
+      readonly := true;
+      default := global default::currentActor;
+    };
+    required at: datetime {
+      readonly := true;
+      default := datetime_of_statement();
+    };
+    transitionKey: uuid {
+      readonly := true;
+    };
+    required to: Status {
+      readonly := true;
+    };
+    notes: default::RichText {
+      readonly := true;
+    };
+
+    trigger setEngagementStatus after insert for all do (
+      update default::Engagement
+      filter default::Engagement in __new__.engagement
+      set {
+        status := default::Engagement.latestWorkflowEvent.to ?? Engagement::Status.InDevelopment
+      }
+    );
+    trigger refreshEngagementStatus after delete for all do (
+      update default::Engagement
+      filter default::Engagement in __old__.engagement
+      set {
+        status := default::Engagement.latestWorkflowEvent.to ?? Engagement::Status.InDevelopment
+      }
+    );
+  }
+
+  scalar type Status extending enum<
+    InDevelopment,
+    DidNotDevelop,
+    Rejected,
+    
+    Active,
+    
+    DiscussingTermination,
+    DiscussingReactivation,
+    DiscussingChangeToPlan,
+    DiscussingSuspension,
+    
+    FinalizingCompletion,
+    ActiveChangedPlan,
+    Suspended,
+    
+    Terminated,
+    Completed,
+    
+    # deprecated / legacy
+    Converted,
+    Unapproved,
+    Transferred,
+    NotRenewed,
+  >;
+}

dbschema/engagement.esdl

@@ -3,6 +3,15 @@ module default {
     required status: Engagement::Status {
       default := Engagement::Status.InDevelopment;
     }
+    latestWorkflowEvent := (select .workflowEvents order by .at desc limit 1);
+    workflowEvents := .<engagement[is Engagement::WorkflowEvent];
+    trigger assertMatchingLatestWorkflowEvent after insert, update for each do (
+      assert(
+        __new__.latestWorkflowEvent.to ?= __new__.status,
+        or (not exists __new__.latestWorkflowEvent and __new__.status = Engagement::Status.InDevelopment),
+        message := "Engagement status must match the latest workflow event"
+      )
+    );
     statusModifiedAt: datetime {
       rewrite update using (datetime_of_statement() if .status != __old__.status else .statusModifiedAt);
     }
@@ -141,31 +150,6 @@ module default {
 }
 
 module Engagement {
-  scalar type Status extending enum<
-    InDevelopment,
-    DidNotDevelop,
-    Rejected,
-    
-    Active,
-    
-    DiscussingTermination,
-    DiscussingReactivation,
-    DiscussingChangeToPlan,
-    DiscussingSuspension,
-    
-    FinalizingCompletion,
-    ActiveChangedPlan,
-    Suspended,
-    
-    Terminated,
-    Completed,
-    
-    # deprecated / legacy
-    Converted,
-    Unapproved,
-    Transferred,
-    NotRenewed,
-  >;
 
   scalar type InternPosition extending enum<
     ConsultantInTraining,