Move to a prebuilt protoc

Author: shs96c

.bazelrc

@@ -57,7 +57,17 @@ query --@aspect_rules_ts//ts:default_to_tsc_transpiler
 
 build --incompatible_strict_action_env
 
+# Required for prebuilt protoc to be used
+common --incompatible_enable_proto_toolchain_resolution
+
+# Ensure that we don't accidentally build protobuf or gRPC
+common --per_file_copt=external/.*protobuf.*@--PROTOBUF_WAS_NOT_SUPPOSED_TO_BE_BUILT
+common --host_per_file_copt=external/.*protobuf.*@--PROTOBUF_WAS_NOT_SUPPOSED_TO_BE_BUILT
+common --per_file_copt=external/.*grpc.*@--GRPC_WAS_NOT_SUPPOSED_TO_BE_BUILT
+common --host_per_file_copt=external/.*grpc.*@--GRPC_WAS_NOT_SUPPOSED_TO_BE_BUILT
+
 # Required to get `protobuf` compiling, which is required for `rules_closure`
+common --incompatible_enable_proto_toolchain_resolution
 build --incompatible_enable_cc_toolchain_resolution
 build --cxxopt=-std=c++17
 build --host_cxxopt=-std=c++17

MODULE.bazel

@@ -12,6 +12,9 @@ bazel_dep(name = "buildifier_prebuilt", version = "8.2.1.1")
 bazel_dep(name = "contrib_rules_jvm", version = "0.31.1")
 bazel_dep(name = "platforms", version = "1.0.0")
 
+# If you update this, also update the prebuilt version of `protoc` we use below
+bazel_dep(name = "protobuf", version = "32.1")
+
 # Required for rules_rust to import the crates properly
 bazel_dep(name = "rules_cc", version = "0.2.16", dev_dependency = True)
 
@@ -27,20 +30,29 @@ bazel_dep(name = "rules_python", version = "1.7.0")
 bazel_dep(name = "rules_proto", version = "7.1.0")
 bazel_dep(name = "rules_ruby", version = "0.21.1")
 bazel_dep(name = "rules_rust", version = "0.68.1")
+bazel_dep(name = "toolchains_protoc", version = "0.6.0")
 
 # Provide mechanisms to group javadocs together.
 single_version_override(
     module_name = "rules_jvm_external",
     patch_strip = 1,
-    patches = ["//java:rules_jvm_external_javadoc.patch"],
+    patches = ["//third_party/bazel:rules_jvm_external_javadoc.patch"],
 )
 
 # Work around `contrib_rules_jvm` not properly handling non-iterable
 # items in lists.
 single_version_override(
     module_name = "contrib_rules_jvm",
     patch_strip = 1,
-    patches = ["//java:contrib_rules_jvm_select_fix.patch"],
+    patches = ["//third_party/bazel:contrib_rules_jvm_select_fix.patch"],
+)
+
+# Patch protobuf to use toolchain resolution for internal_gen_well_known_protos_java
+# instead of hardcoding //:protoc dependency, enabling prebuilt protoc usage.
+single_version_override(
+    module_name = "protobuf",
+    patch_strip = 1,
+    patches = ["//third_party/bazel:protobuf_toolchain_resolution.patch"],
 )
 
 multitool = use_extension("@rules_multitool//multitool:extension.bzl", "multitool")
@@ -396,6 +408,13 @@ crate.from_cargo(
 )
 use_repo(crate, "crates")
 
+# Override the toolchain registration from the protobuf module
+protoc = use_extension("@toolchains_protoc//protoc:extensions.bzl", "protoc")
+protoc.toolchain(version = "v32.1")
+use_repo(protoc, "toolchains_protoc_hub")
+
+register_toolchains("@toolchains_protoc_hub//:all")
+
 selenium_manager_artifacts = use_extension("//common:selenium_manager.bzl", "selenium_manager_artifacts")
 use_repo(
     selenium_manager_artifacts,

third_party/bazel/BUILD.bazel

@@ -0,0 +1,91 @@
+diff --git a/protobuf.bzl b/protobuf.bzl
+index 283c85850..ad91faba6 100644
+--- a/protobuf.bzl
++++ b/protobuf.bzl
+@@ -1,7 +1,9 @@
+ load("@bazel_skylib//lib:versions.bzl", "versions")
+ load("@rules_cc//cc:defs.bzl", "objc_library")
+ load("@rules_python//python:defs.bzl", "py_library")
++load("//bazel/common:proto_common.bzl", "proto_common")
+ load("//bazel/common:proto_info.bzl", "ProtoInfo")
++load("//bazel/private:toolchain_helpers.bzl", "toolchains")
+
+ def _GetPath(ctx, path):
+     if ctx.label.workspace_root:
+@@ -71,6 +73,26 @@ def _CsharpOuts(srcs):
+         for src in srcs
+     ]
+
++_PROTOC_ATTRS = toolchains.if_legacy_toolchain({
++    "_proto_compiler": attr.label(
++        cfg = "exec",
++        executable = True,
++        allow_files = True,
++        default = configuration_field("proto", "proto_compiler"),
++    ),
++})
++_PROTOC_FRAGMENTS = ["proto"]
++_PROTOC_TOOLCHAINS = toolchains.use_toolchain(toolchains.PROTO_TOOLCHAIN)
++
++def _protoc_files_to_run(ctx):
++    if proto_common.INCOMPATIBLE_ENABLE_PROTO_TOOLCHAIN_RESOLUTION:
++        toolchain = ctx.toolchains[toolchains.PROTO_TOOLCHAIN]
++        if not toolchain:
++            fail("Protocol compiler toolchain could not be resolved.")
++        return toolchain.proto.proto_compiler
++    else:
++        return ctx.attr._proto_compiler[DefaultInfo].files_to_run
++
+ ProtoGenInfo = provider(
+     fields = ["srcs", "import_flags", "deps"],
+ )
+@@ -310,7 +332,7 @@ def _internal_gen_well_known_protos_java_impl(ctx):
+             args.add_all([src.path[offset:] for src in dep.direct_sources])
+
+     ctx.actions.run(
+-        executable = ctx.executable._protoc,
++        executable = _protoc_files_to_run(ctx),
+         inputs = descriptors,
+         outputs = [srcjar],
+         arguments = [args],
+@@ -334,12 +356,9 @@ internal_gen_well_known_protos_java = rule(
+         "javalite": attr.bool(
+             default = False,
+         ),
+-        "_protoc": attr.label(
+-            executable = True,
+-            cfg = "exec",
+-            default = "//:protoc",
+-        ),
+-    },
++    } | _PROTOC_ATTRS,
++    fragments = _PROTOC_FRAGMENTS,
++    toolchains = _PROTOC_TOOLCHAINS,
+ )
+
+ def _internal_gen_kt_protos(ctx):
+@@ -373,7 +392,7 @@ def _internal_gen_kt_protos(ctx):
+             args.add_all([src.path[offset:] for src in dep.direct_sources])
+
+     ctx.actions.run(
+-        executable = ctx.executable._protoc,
++        executable = _protoc_files_to_run(ctx),
+         inputs = descriptors,
+         outputs = [srcjar],
+         arguments = [args],
+@@ -397,12 +416,9 @@ internal_gen_kt_protos = rule(
+         "lite": attr.bool(
+             default = False,
+         ),
+-        "_protoc": attr.label(
+-            executable = True,
+-            cfg = "exec",
+-            default = "//:protoc",
+-        ),
+-    },
++    } | _PROTOC_ATTRS,
++    fragments = _PROTOC_FRAGMENTS,
++    toolchains = _PROTOC_TOOLCHAINS,
+ )
+
+ def internal_objc_proto_library(