Require successful transfer on external contract

Author: bweick

contracts/core/TransferProxy.sol

@@ -18,8 +18,8 @@ pragma solidity 0.4.24;
 
 
 import { Authorizable } from "../lib/Authorizable.sol";
-import { ERC20 } from "zeppelin-solidity/contracts/token/ERC20/ERC20.sol";
 import { SafeMath } from "zeppelin-solidity/contracts/math/SafeMath.sol";
+import { TokenInteract } from "./lib/TokenInteract.sol";
 
 
 /**
@@ -80,17 +80,25 @@ contract TransferProxy is
         onlyAuthorized
     {
         // Retrieve current balance of token for the vault
-        uint existingVaultBalance = ERC20(_tokenAddress).balanceOf(vaultAddress);
+        uint existingVaultBalance = TokenInteract.balanceOf(
+            _tokenAddress,
+            vaultAddress
+        );
 
         // Call specified ERC20 contract to transfer tokens from user to Vault (via proxy).
-        ERC20(_tokenAddress).transferFrom(
+
+        TokenInteract.transferFrom(
+            _tokenAddress,
             _from,
             vaultAddress,
             _quantity
         );
 
         // Verify transfer quantity is reflected in balance
-        uint newVaultBalance = ERC20(_tokenAddress).balanceOf(vaultAddress);
+        uint newVaultBalance = TokenInteract.balanceOf(
+            _tokenAddress,
+            vaultAddress
+        );
         require(newVaultBalance == existingVaultBalance.add(_quantity));
     }
 }

contracts/core/Vault.sol

@@ -20,6 +20,7 @@ pragma solidity 0.4.24;
 import { Authorizable } from "../lib/Authorizable.sol";
 import { ERC20 } from "zeppelin-solidity/contracts/token/ERC20/ERC20.sol";
 import { SafeMath } from "zeppelin-solidity/contracts/math/SafeMath.sol";
+import { TokenInteract } from "./lib/TokenInteract.sol";
 
 
 /**
@@ -92,16 +93,23 @@ contract Vault is
         isValidDestination(_to)
     {
         // Retrieve current balance of token for the vault
-        uint existingVaultBalance = ERC20(_tokenAddress).balanceOf(this);
+        uint existingVaultBalance = TokenInteract.balanceOf(
+            _tokenAddress,
+            this
+        );
 
         // Call specified ERC20 token contract to transfer tokens from Vault to user
-        ERC20(_tokenAddress).transfer(
+        TokenInteract.transfer(
+            _tokenAddress,
             _to,
             _quantity
         );
 
         // Verify transfer quantity is reflected in balance
-        uint newVaultBalance = ERC20(_tokenAddress).balanceOf(this);
+        uint newVaultBalance = TokenInteract.balanceOf(
+            _tokenAddress,
+            this
+        );
         require(newVaultBalance == existingVaultBalance.sub(_quantity));
     }
 
@@ -154,7 +162,7 @@ contract Vault is
     }
 
     /* ============ Getter Functions ============ */
-    
+
     /*
      * Get balance of particular contract for owner.
      *

contracts/core/lib/TokenInteract.sol

@@ -0,0 +1,109 @@
+/*
+    Copyright 2018 Set Labs Inc.
+    Licensed under the Apache License, Version 2.0 (the "License");
+    you may not use this file except in compliance with the License.
+    You may obtain a copy of the License at
+    http://www.apache.org/licenses/LICENSE-2.0
+    Unless required by applicable law or agreed to in writing, software
+    distributed under the License is distributed on an "AS IS" BASIS,
+    WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+    See the License for the specific language governing permissions and
+    limitations under the License.
+*/
+
+pragma solidity 0.4.24;
+
+import { GeneralERC20 } from "../../lib/GeneralERC20.sol";
+
+
+/**
+ * @title TokenInteract
+ * @author Set Protocol
+ *
+ * This library contains functions for interacting wtih ERC20 tokens
+ */
+library TokenInteract {
+    function balanceOf(
+        address token,
+        address owner
+    )
+        internal
+        view
+        returns (uint256)
+    {
+        return GeneralERC20(token).balanceOf(owner);
+    }
+
+    function transfer(
+        address token,
+        address to,
+        uint256 amount
+    )
+        internal
+    {
+
+        GeneralERC20(token).transfer(to, amount);
+
+        require(
+            checkSuccess(),
+            "TokenInteract#transfer: Transfer failed"
+        );
+    }
+
+    function transferFrom(
+        address token,
+        address from,
+        address to,
+        uint256 amount
+    )
+        internal
+    {
+
+        GeneralERC20(token).transferFrom(from, to, amount);
+
+        require(
+            checkSuccess(),
+            "TokenInteract#transferFrom: TransferFrom failed"
+        );
+    }
+
+    // ============ Private Helper-Functions ============
+
+    /**
+     * Checks the return value of the previous function up to 32 bytes. Returns true if the previous
+     * function returned 0 bytes or 32 bytes that are not all-zero.
+     */
+    function checkSuccess(
+    )
+        private
+        pure
+        returns (bool)
+    {
+        uint256 returnValue = 0;
+
+        /* solium-disable-next-line security/no-inline-assembly */
+        assembly {
+            // check number of bytes returned from last function call
+            switch returndatasize
+
+            // no bytes returned: assume success
+            case 0x0 {
+                returnValue := 1
+            }
+
+            // 32 bytes returned: check if non-zero
+            case 0x20 {
+                // copy 32 bytes into scratch space
+                returndatacopy(0x0, 0x0, 0x20)
+
+                // load those bytes into returnValue
+                returnValue := mload(0x0)
+            }
+
+            // not sure what was returned: dont mark as success
+            default { }
+        }
+
+        return returnValue != 0;
+    }
+}

contracts/lib/GeneralERC20.sol

@@ -0,0 +1,47 @@
+/*
+    Copyright 2018 Set Labs Inc.
+    Licensed under the Apache License, Version 2.0 (the "License");
+    you may not use this file except in compliance with the License.
+    You may obtain a copy of the License at
+    http://www.apache.org/licenses/LICENSE-2.0
+    Unless required by applicable law or agreed to in writing, software
+    distributed under the License is distributed on an "AS IS" BASIS,
+    WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+    See the License for the specific language governing permissions and
+    limitations under the License.
+*/
+
+pragma solidity 0.4.24;
+
+
+/**
+ * @title GeneralERC20
+ * @author Set Protocol
+ *
+ * Interface for using ERC20 Tokens. We have to use a special interface to call ERC20 functions so
+ * that we dont automatically revert when calling non-compliant tokens that have no return value for
+ * transfer(), transferFrom(), or approve().
+ */
+interface GeneralERC20 {
+
+    function balanceOf(
+        address who
+    )
+        external
+        view
+        returns (uint256);
+
+    function transfer(
+        address to,
+        uint256 value
+    )
+        external;
+
+
+    function transferFrom(
+        address from,
+        address to,
+        uint256 value
+    )
+        external;
+}