openmeteo progress update

up

Author: mtoldi

examples/Inkplate6COLOR/Projects/Inkplate6_OpenMeteo_Weather_Station/Inkplate6_OpenMeteo_Weather_Station.ino

@@ -0,0 +1,111 @@
+/*
+  Inkplate6 OpenMeteo Weather Station Example
+  Compatible with Soldered Inkplate 6
+
+  Getting Started:
+  For setup and documentation, visit: https://inkplate.readthedocs.io/en/latest/
+
+  Overview:
+  This example demonstrates how to fetch and display weather data from the OpenMeteo API
+  using the Inkplate 10 e-paper display.
+
+  Before You Start:
+  - Enter your WiFi credentials carefully (they are case-sensitive).
+  - Update the following variables for accurate local weather data:
+      • timeZone
+      • latitude
+      • longitude
+  Set your username and city with `myUsername` and `myCity` (for display only, not essential for the API).
+
+  Units:
+  By default, the app uses the metric system.
+  To switch to Imperial units, change the metricUnits to "bool metricUnits = false;"
+*/
+#include "src/includes.h" // Include necessary libraries and dependencies for Inkplate and networking
+
+// --- WiFi Configuration ---
+const char *ssid = "Soldered-testingPurposes";
+const char *password = "Testing443";
+
+// --- User and Location Info ---
+String myUsername = "Username"; // User's name to be displayed on screen
+String myCity = "Osijek";       // City name for weather data
+int timeZone =
+    2; // timeZone is the number in (UTC + number) in your time zone UTC + 2 for Osijek, UTC - 4 for New York City
+float latitude =  45.5550;  // Latitude of the city
+float longitude = 18.6955; // Longitude of the city
+
+bool metricUnits = true;  // set this to false if you wish to use Imperial units
+
+const char* ntpServer = "pool.ntp.org";  // in case you want to use a different one
+
+// --- Device and Data Objects ---
+Inkplate inkplate; // Create Inkplate display object (3-bit mode for partial grayscale)
+Network network;                  // Network utility for weather fetching
+Network::UserInfo userInfo;       // Structure to hold user and device info (battery, last updated, etc.)
+WeatherData weatherData;          // Structure to hold fetched weather data
+Gui gui(inkplate);                // Drawing visuals and info
+
+// --- Deep Sleep Configuration ---
+#define uS_TO_S_FACTOR 1000000 // Convert microseconds to seconds
+#define TIME_TO_SLEEP  1800    // Sleep time: 1800 seconds = 30 minutes
+
+// --- Main Setup: Runs Once on Boot ---
+void setup()
+{
+    Serial.begin(115200);    // Initialize serial monitor for debugging
+    inkplate.begin();        // Start the Inkplate display
+    inkplate.clearDisplay(); // Clear the screen
+    inkplate.setRotation(0);
+
+    // Attempt to connect to WiFi
+    const unsigned long timeout = 30000;
+    unsigned long startTime = millis();
+    bool connected = false;
+
+    while (!connected && (millis() - startTime) < timeout)
+    {
+        connected = inkplate.connectWiFi(ssid, password, 10, true);
+    }
+
+    // If WiFi failed, display error message
+    if (!connected)
+    {
+        gui.wifiError();
+    }
+    else
+    {
+        configTime(timeZone * 3600, 0, ntpServer); // Set local time via NTP server
+        // Gather battery and city info
+        userInfo.voltage = inkplate.readBattery();
+        userInfo.city = myCity;
+        userInfo.username = myUsername;
+        userInfo.useMetric = metricUnits;
+
+        // Fetch weather data for specified coordinates
+        network.fetchWeatherData(&weatherData, &userInfo, &latitude, &longitude);
+
+        // Display if weather API call fails
+        if (userInfo.apiError)
+        {
+            gui.apiError();
+        }
+        else
+        {
+            // Success: draw UI and data
+            gui.drawBackground();
+            gui.displayWeatherData(&weatherData, &userInfo);
+        }
+    }
+
+    // Sleep to save power; wakes every 30 minutes
+    esp_sleep_enable_timer_wakeup(TIME_TO_SLEEP *
+                                  uS_TO_S_FACTOR); // Activate wake-up timer -- wake up after 30mins here
+    esp_deep_sleep_start();                        // Put ESP32 into deep sleep.
+}
+
+void loop()
+{
+    // Nothing to do here - main logic runs once in setup()
+}
+