bootstrap/justfile at main · StardustXR/bootstrap · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
just := just_executable()
rootdir := ''
prefix := '/usr'
telescope_appdir := justfile_directory() / "Telescope.AppDir"

build:
    {{ just }} org.stardustxr.Armillary/build-release
    {{ just }} org.stardustxr.Atmosphere/build-release
    {{ just }} org.stardustxr.BlackHole/build-release
    {{ just }} org.stardustxr.Comet/build-release
    {{ just }} org.stardustxr.Flatland/build-release
    {{ just }} org.stardustxr.Gravity/build-release
    {{ just }} org.stardustxr.NonSpatialInput/build-release
    {{ just }} org.stardustxr.Protostar/build-release
    {{ just }} org.stardustxr.SolarSailer/build-release
    {{ just }} org.stardustxr.Server/build-release

install: build
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Atmosphere/install
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Armillary/install
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.BlackHole/install
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Comet/install
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Flatland/install
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Gravity/install
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.NonSpatialInput/install
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Protostar/install
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.SolarSailer/install
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Server/install

uninstall:
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Armillary/uninstall
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Atmosphere/uninstall
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.BlackHole/uninstall
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Comet/uninstall
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Flatland/uninstall
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Gravity/uninstall
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.NonSpatialInput/uninstall
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Protostar/uninstall
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.SolarSailer/uninstall
    {{ just }} rootdir="{{ rootdir }}" prefix="{{ prefix }}" org.stardustxr.Server/uninstall

appdir-telescope: build
    mkdir -p "{{ telescope_appdir }}"

    # Install all the stardust components
    {{ just }} rootdir="{{ telescope_appdir }}" prefix="/usr" install

    # xwayland-satellite
    if ! test -f "{{ telescope_appdir }}/usr/bin/xwayland-satellite"; then \
        cargo install --locked --git "https://github.com/Supreeeme/xwayland-satellite" --root "{{ telescope_appdir }}/usr" --force && \
        rm -f "{{ telescope_appdir }}/usr/.crates.toml" "{{ telescope_appdir }}/usr/.crates2.json"; \
    fi

    # Telescope stuff
    install -Dm755 "telescope/scripts/telescope" "{{ telescope_appdir }}/usr/bin/telescope"
    install -Dm755 "telescope/scripts/telescope_startup" "{{ telescope_appdir }}/usr/libexec/telescope_startup"
    install -Dm755 "telescope/scripts/AppRun" "{{ telescope_appdir }}/AppRun"
    install -Dm644 "telescope/data/org.stardustxr.Telescope.desktop" "{{ telescope_appdir }}/org.stardustxr.Telescope.desktop"
    install -Dm644 "telescope/data/org.stardustxr.Telescope.png" "{{ telescope_appdir }}/org.stardustxr.Telescope.png"

test-telescope: appdir-telescope
    APPDIR="{{ telescope_appdir }}" "{{ telescope_appdir }}/AppRun"

update:
    git submodule foreach 'git checkout main && git pull'

prefix-install:
    {{ just }} rootdir="{{ justfile_directory() / 'prefix' }}" install
    [ -e "{{ justfile_directory() }}/startup.sh" ] || install -Dm755 "telescope/scripts/telescope_startup" "{{ justfile_directory() }}/startup.sh"

[no-exit-message]
prefix-run *args:
    PATH="{{ justfile_directory() / 'prefix' / 'usr' / 'bin' }}:{{ env('PATH') }}" {{ justfile_directory() / 'prefix' / 'usr' / 'bin' / 'stardust-xr-server' }} -o 6 -e {{ justfile_directory() / 'startup.sh' }} {{ args }}

clean:
    rm -rf org.stardustxr.Armillary/target
    rm -rf org.stardustxr.Atmosphere/target
    rm -rf org.stardustxr.BlackHole/target
    rm -rf org.stardustxr.Comet/target
    rm -rf org.stardustxr.Flatland/target
    rm -rf org.stardustxr.Gravity/target
    rm -rf org.stardustxr.NonSpatialInput/target
    rm -rf org.stardustxr.Protostar/target
    rm -rf org.stardustxr.SolarSailer/target
    rm -rf org.stardustxr.Server/target