Use browser as viewer on Mac

[zsiegel92]

Hi,

Using your browser as a viewer on a Mac is as easy as changing the settings to

"viewer": "command",
"viewer_settings": {
		// Platform-specific settings:
		"osx" : {
			"view_command":"open -a 'Google Chrome' $pdf_file"
		}
	}

But this, unfortunately, always opens a new tab with the pdf (on every build!), which is not remotely similar to the experience of using a dedicated Tex builder/viewer.

I propose instead using the following command:

"osx" : {
			"view_command":"osascript /Users/username/Library/Scripts/OpenFileInChrome.applescript $pdf_file"
		}

where /Users/username/Library/Scripts/ is your preferred applescripts folder, containing the following script OpenFileInChrome.applescript:

on run argv
	set theFile to item 1 of argv
	set pdfName to theFile
	tell application "Google Chrome"
		activate
		set found to false
		set windowList to every window
		repeat with aWindow in windowList
			set tabList to every tab of aWindow
			set tabIndex to 0
			repeat with atab in tabList
				set tabIndex to tabIndex + 1
				if (URL of atab contains pdfName) then
					set found to true
					tell atab to reload
					set aWindow's active tab index to tabIndex
					set index of aWindow to 1
				end if
			end repeat
		end repeat
		if not found then
			set str to "open -a 'Google Chrome' " & pdfName
			do shell script str
		end if
	end tell
end run

This script makes sure to open the file in the tab it is already open in, and to reload it to reflect built changes. If the file is not open, it simply opens it in a new tab/window (per your default Chrome settings).

This script is the feature that allows me to use LaTeXTools as opposed to TeXShop.

If it were possible for a Chrome extension to achieve bi-directional, sync, that would be great...

[zsiegel92]

If it is possible to somehow make this possible via a setting directly, that would be cool. I know it is fairly niche, but I doubt I'm the only one who might want this!

[idr4n]

I just tried this feature in VSCode's latex-workshop and it is actually really nice to have the browser as your viewer and it also supports forward and inverse sync with the browser.

I would be great if this feature is also added to latextools!

[zsiegel92]

Hi there,

I have implemented forward-sync for a browser viewer, and I derive so much satisfaction from this workflow that I would like to help others achieve the same.

Chrome can sync to a given page (not a given line) by appending, e.g., #page=3 to the end of a pdf URL. Here's how you make that happen from Latextools:

1. First, you need a script that takes the source (.tex) filename, the pdf filename, and the current source line and column numbers, and outputs the augmented URL (with #page=3):

#!/bin/zsh
theTexFile=$1
thePDFFile=$2
theLineNumber=$3
theColNumber=$4
syncinfo=$(synctex view -i $theLineNumber:$theColNumber:$theTexFile -o $thePDFFile)
[[ $syncinfo =~ 'Page:([0-9]+)' ]]
pageNumber=$match
echo "file://$thePDFFile#page=$pageNumber"

I stored this in my home directory at ~/.get_synctex_line_number.sh.

2. Create an applescript that takes the same parameters and opens a Chrome tab with the correct file path, appending the page number. This is a common pattern that searches for a tab whose URL contains the filename. If no such tab exists, it creates one. Note that it uses the Chrome executable script within the Chrome application bundle, which executes much better from the command line, in my experience, than open -a "Google Chrome".

on run argv
	set pdfName to item 1 of argv
	set theTexFile to item 2 of argv
	set theLineNumber to item 3 of argv
	set theColNumber to item 4 of argv
	set finalDestination to do shell script "/Users/Zach/.get_synctex_line_number.sh " & theTexFile & " " & pdfName & " " & theLineNumber & " " & theColNumber
	tell application "Google Chrome"
		activate
		set found to false
		set windowList to every window
		repeat with aWindow in windowList
			set tabList to every tab of aWindow
			set tabIndex to 0
			repeat with atab in tabList
				set tabIndex to tabIndex + 1
				if (URL of atab contains pdfName) then
					set found to true
					set aWindow's active tab index to tabIndex
					set index of aWindow to 1
					set URL of atab to finalDestination
					tell application "System Events"
						tell application process "Google Chrome"
				            keystroke return
				        end tell
					end tell
					tell atab to reload
					exit repeat
				end if
			end repeat
			if found then
				exit repeat
			end if
		end repeat
	end tell
	if not found then
		set str to "/Applications/Google\\ Chrome.app/Contents/MacOS/Google\\ Chrome " & finalDestination
		do shell script str
	end if
end run

I saved this as ~/Libary/Scripts/OpenFileInChrome_Page_Number.applescript

3. In LaTeXTools.sublime-settings, set the viewer property and the forward_sync_command property of viewer_settings:

	"viewer": "command",
	"viewer_settings": {
		"osx" : {
			"forward_sync_command": "osascript /Users/Zach/Library/Scripts/OpenFileInChrome_Page_Number.applescript $pdf_file $src_file $line $col",
		},
	},
	"open_pdf_on_build": true,

Note you can (and I do) also have a view_command in there with a more basic browser viewer command (as I described in my comment from last year).

Note that the absolute paths of the ~/.get_synctex_line_number.sh, OpenFileInChrome_Page_Number.applescript, and the Chrome executable are in the applescript and the Latextools command.

Also note that you need synctex on your PATH. If you can build LaTeX from Sublime Text's LaTeXTools (this repository), then you probably already have this. If not, you can install it.

Future Goal: If/when Chrome's Javascript API for PDF viewing becomes easier to access, we will be able to jump to a given line by telling the applescript to execute to execute Javascript to jump to the correct line number, which synctex also provides. This current strategy only takes the page number from the output of synctex, but it gives much more.

[zsiegel92]

@duranivan