asap7/ethmac_lvt: study placement densities and grt

Signed-off-by: Øyvind Harboe <[email protected]>

Author: oharboe

flow/designs/asap7/ethmac_lvt/BUILD.bazel

@@ -0,0 +1,85 @@
+load("@bazel-orfs//:sweep.bzl", "orfs_sweep")
+load("@orfs-pip//:requirements.bzl", "requirement")
+
+# Format densities, rounding to 2 decimal places.
+SWEEPS = {
+    "PLACE_DENSITY": [str(0.60 + x * 0.01 + 0.005)[:4] for x in range(20)],
+    "CORE_UTILIZATION": [str(40 + x * 5) for x in range(4)],
+}
+
+SWEEP = "PLACE_DENSITY"
+
+orfs_sweep(
+    name = "ethmac_lvt",
+    arguments = {
+        # Faster builds
+        "SKIP_INCREMENTAL_REPAIR": "1",
+        "GPL_TIMING_DRIVEN": "0",
+        # Various
+        "SDC_FILE": "$(location :constraint.sdc)",
+        "ABC_AREA": "1",
+        "CORE_UTILIZATION": "40",
+        "CORE_ASPECT_RATIO": "1",
+        "CORE_MARGIN": "2",
+        "PLACE_DENSITY": "0.60",
+        "ASAP7_USELVT": "1",
+        "RECOVER_POWER": "1",
+        "ADDITIONAL_LIBS": "$(LIB_DIR)/asap7sc7p5t_AO_RVT_FF_nldm_211120.lib.gz \
+                                $(LIB_DIR)/asap7sc7p5t_INVBUF_RVT_FF_nldm_220122.lib.gz \
+			        $(LIB_DIR)/asap7sc7p5t_OA_RVT_FF_nldm_211120.lib.gz \
+			        $(LIB_DIR)/asap7sc7p5t_SIMPLE_RVT_FF_nldm_211120.lib.gz \
+			        $(LIB_DIR)/asap7sc7p5t_SEQ_RVT_FF_nldm_220123.lib",
+        "ADDITIONAL_GDS": "$(PLATFORM_DIR)/gds/asap7sc7p5t_28_R_220121a.gds",
+        "ADDITIONAL_LEFS": "$(PLATFORM_DIR)/lef/asap7sc7p5t_28_R_1x_220121a.lef",
+    },
+    other_variants = {"base": {}},
+    sources = {
+        "SDC_FILE": [":constraint.sdc"],
+    },
+    sweep = {
+        value: {
+            "arguments": {
+                SWEEP: value,
+            },
+            "previous_stage": {
+                "floorplan": "ethmac_lvt_synth",
+            },
+        }
+        for value in SWEEPS[SWEEP]
+    },
+    top = "ethmac",
+    verilog_files = ["//:ethmac_lvt_src"],
+)
+
+[filegroup(
+    name = "ethmac_lvt_{value}_congestion".format(value = value),
+    srcs = [":ethmac_lvt_{value}_grt".format(value = value)],
+    output_group = "congestion.rpt",
+) for value in SWEEPS[SWEEP]]
+
+filegroup(
+    name = "congestion",
+    srcs = [":ethmac_lvt_{value}_congestion".format(value = value) for value in SWEEPS[SWEEP]],
+)
+
+py_binary(
+    name = "plot_congestion",
+    srcs = ["plot_congestion.py"],
+    main = "plot_congestion.py",
+    deps = [requirement("matplotlib")],
+)
+
+genrule(
+    name = "plot_pdf",
+    srcs = [":congestion"],
+    outs = ["congestion.pdf"],
+    cmd = "$(execpath :plot_congestion) {value} $@ $(locations :congestion)".format(value = SWEEP),
+    tools = [":plot_congestion"],
+)
+
+sh_binary(
+    name = "plot",
+    srcs = [":open_plots.sh"],
+    args = ["$(location :plot_pdf)"],
+    data = [":plot_pdf"],
+)

flow/designs/asap7/ethmac_lvt/open_plots.sh

@@ -0,0 +1,2 @@
+#!/bin/bash
+xdg-open $1

flow/designs/asap7/ethmac_lvt/plot_congestion.py

@@ -0,0 +1,30 @@
+import matplotlib.pyplot as plt
+import numpy as np
+import sys
+import re
+import os
+
+
+sweep = sys.argv[1]
+output = sys.argv[2]
+files = sys.argv[3:]
+
+# count lines in each file and divide by 3 and create a list of those
+# numbers
+congestion = []
+for file in files:
+    with open(file, "r") as f:
+        lines = f.readlines()
+        print(file)
+        density = re.search(r"(\d+\.?\d+)", file).group(1)
+        congestion.append((float(density), len(lines) // 4))
+
+# xy plot of density vs DRC errors
+x, y = zip(*congestion)
+plt.plot(x, y, "o-")
+plt.xlabel(sweep)
+plt.ylabel("DRC Errors")
+plt.title(sweep + " vs DRC Errors")
+plt.grid()
+plt.yscale("log")
+plt.savefig(output)