Switch task runner

Migrate from task to just

Author: bkis

.dockerignore

@@ -16,7 +16,7 @@
 **/compose.yml
 **/.coverage
 **/.dockerignore
-**/Taskfile.yml
+**/.justfile
 docs/
 dev/
 assets/

Tekst-API/.env.test

@@ -4,10 +4,10 @@ TEKST_LOG_LEVEL=debug
 TEKST_AUTO_MIGRATE=true
 
 # database (MongoDB)
-TEKST_DB__NAME=tekst_testing
+TEKST_DB__NAME=tekst_test
 
 # search server (Elasticsearch)
-TEKST_ES__PREFIX=tekst_testing
+TEKST_ES__PREFIX=tekst_test
 
 # auth
 TEKST_SECURITY__ENABLE_JWT_AUTH=true

Tekst-API/.justfile

@@ -0,0 +1,88 @@
+alias test := tests
+
+# print list of available recipes
+list:
+  @just --list
+
+# print API version
+version:
+  @echo "Test-API version: $(uv run python3 -c "from tekst import __version__ as v; print(v, end='')")"
+
+# install dependencies
+install:
+  uv sync
+
+# format code base, fix linting errors
+fix:
+  uv run ruff format .
+  uv run ruff check . --fix
+
+# check code formatting and style
+check:
+  uv run ruff format . --check
+  uv run ruff check . --extend-select N
+
+# run tests
+tests ARGS="": install (services-up "test") && (services-down "test")
+  -TEKST_CUSTOM_ENV_FILE=.env.test uv run pytest {{ARGS}}
+
+# run dev environment
+dev: (services-up "dev") && (services-down "dev")
+  -TEKST_DEV_MODE=true uv run python3 -m tekst bootstrap
+  @printf "\n\
+    ╭───────────────────────────────────────────────────────╮\n\
+    │ 🌐 Tekst-Web Dev Server ... http://127.0.0.1          │\n\
+    │ 🐍 Tekst-API .............. http://127.0.0.1/api      │\n\
+    │ 📖 API Docs ............... http://127.0.0.1/api/docs │\n\
+    │ 📬 MailPit ................ http://127.0.0.1:8025     │\n\
+    │ 📂 MongoExpress ........... http://127.0.0.1:8081     │\n\
+    ╰───────────────────────────────────────────────────────╯\n\
+    \n\
+    "
+  -TEKST_DEV_MODE=true uv run fastapi dev tekst/app.py
+
+# export OpenAPI schema to openapi.json
+schema:
+  TEKST_DEV_MODE=true TEKST_LOG_LEVEL=warning uv run python3 -m tekst schema -f
+
+# run full pre-commit toolchain
+all:
+  just fix
+  just tests
+  just check
+  just schema
+
+# build updated container images in services stack
+services-build:
+  docker compose -f ../dev/compose.yml --profile dev --profile test build
+
+# run services stack
+services-up SCOPE="test": gen-smtp-ssl-cert && wait-for-mongodb wait-for-elasticsearch
+  docker compose -f ../dev/compose.yml --profile {{SCOPE}} -p tekst-{{SCOPE}} up --detach
+
+# kill services stack
+services-down SCOPE="test":
+  docker compose -f ../dev/compose.yml --profile {{SCOPE}} -p tekst-{{SCOPE}} down --volumes
+
+# clean up generated files
+cleanup:
+  uv run ruff clean
+  rm -rf \
+    */**/__pycache__ \
+    */**/.pytest_cache \
+    .ruff_cache \
+    .coverage \
+    dist \
+    htmlcov \
+
+[private]
+wait-for-mongodb:
+  @printf "Waiting for MongoDB service"; sleep 2; printf "\n"
+
+[private]
+wait-for-elasticsearch:
+  @printf "Waiting for Elasticsearch service"; while ! $(curl -f 127.0.0.1:9200 > /dev/null 2>&1); do sleep 1; printf "."; done; printf "\n"
+
+[private]
+gen-smtp-ssl-cert:
+  @cd ../dev/smtp-ssl && ./generate.sh

Tekst-API/README.md

@@ -13,5 +13,5 @@ For general information on Tekst, visit the [Tekst repository](https://github.co
 3. Install the project and its dependencies (from the `Tekst-API/` project directory): `uv sync`
 4. Run the development environment
    - `uv run fastapi dev tekst/app.py` to run the dev server ([...and so on](https://docs.astral.sh/uv/reference/cli/))
-   - Local development also needs all the services running (MongoDB, Elasticsearch + some optional extras). The easiest way is to use the development compose stack in `../dev/compose.yml`. This also contains a Caddy (web server) that manages routing of requests to the client dev server and the API. See [this](Taskfile.yml) for reference.
-5. The project has some *very* convenient tasks configured that can be run with [Task](https://taskfile.dev/) (a task runner). This is optional, but it helps *a lot*. You can install it form [here](https://taskfile.dev/installation/). Tasks can then be run via `task <taskname>`. You'll get a commented overview of the configured tasks if you run `task` without any arguments (or look [here](Taskfile.yml)).
+   - Local development also needs all the services running (MongoDB, Elasticsearch + some optional extras). The easiest way is to use the development compose stack in `../dev/compose.yml`. This also contains a Caddy (web server) that manages routing of requests to the client dev server and the API. See [this](.justfile) for reference.
+5. The project has some _very_ convenient recipes configured that can be run with [just](https://just.systems/man/en/packages.html) (a task runner). This is optional, but it helps _a lot_. Recipes can then be run via `just <recipe name>`. You'll get a commented overview of the configured recipes if you run `just` without any arguments (or look [here](.justfile)).

Tekst-API/Taskfile.yml

@@ -5,4 +5,4 @@ node_modules/
 
 Dockerfile
 .dockerignore
-Taskfile.yml
+.justfile

Tekst-Web/.dockerignore

@@ -0,0 +1,49 @@
+# print list of available recipes
+list:
+  @just --list
+
+# print web client version
+version:
+  @echo "Test-Web version: $(npx -c 'node -p "process.env.npm_package_version"')"
+
+# install dependencies
+install:
+  npm install
+
+# format code
+format:
+  npm run format
+
+# lint code
+lint:
+  npm run lint
+
+# format and lint code
+fix:
+  npm run format
+  npm run lint
+
+# run dev server
+dev:
+  -npm run start
+
+# build distribution files
+build: install
+  npm run build
+
+# generate TypeScript types from OpenAPI schema
+types:
+  npm run types
+
+# generate translation assets
+translations:
+  npm run translations
+
+# run full pre-commit toolchain
+all:
+  just fix
+  npm run build
+
+# visualize bundle
+visualize:
+  npx vite-bundle-visualizer

Tekst-Web/.justfile

@@ -14,7 +14,7 @@ For general information on Tekst, visit the [Tekst repository](https://github.co
 3. You can now use
    - `npm run dev` to run the [Vite](https://vitejs.dev/) dev server
    - `npm run build` to build the project
-   - `npm run api-schema` to generate types from the Tekst-API OpenAPI schema
+   - `npm run types` to generate types from the Tekst-API OpenAPI schema
    - `npm run translations` to generate translation modules from the translation files
    - [...and so on](package.json)
-4. The project has some _very_ convenient tasks configured that can be run with [Task](https://taskfile.dev/) (a task runner). This is optional, but it helps _a lot_. You can install it form [here](https://taskfile.dev/installation/). Tasks can then be run via `task <taskname>`. You'll get a commented overview of the configured tasks if you run `task` without any arguments (or look [here](Taskfile.yml)).
+4. The project also has some _very_ convenient recipes configured that can be run with [just](https://just.systems/man/en/packages.html) (a task runner). This is optional, but it helps _a lot_. Recipes can then be run via `just <recipe name>`. You'll get a commented overview of the configured recipes if you run `just` without any arguments (or look [here](.justfile)).